An modification on the SWARM bot, using tie feeding and viruses to be nasty to most stuffs.
'NecroticSwarm
'Virus
cond
*.thisgene 1 >
*.vtimer 0 =
start
*.thisgene .mkvirus store
*.thisgene 1 rnd 2 mult -1 add add .delgene store
100 .vshoot store
*.thisgene 1 add .delgene store
*.thisgene 1 sub .delgene 1 rnd mult store
*.thisgene .delgene *55 *.myeye 1 floor sub sgn abs 1 sub abs mult store
stop
' Delete birthtie and move
cond
start
.tie 1 *.robage sub 0 floor mult inc
.deltie inc
*.maxvel *.vel sub .up store
stop
' Set eye5
cond
*.robage 0 =
start
1220 .eye5width store
stop
' Swarm
cond
*.robage 5 mod 0 =
*.eye5 0 >
*.refeye *.myeye =
start
*.refaim .setaim *.robage sgn mult store
stop
' eat food
cond
*.eye5 0 >
*.refeye *.myeye !=
*.maxvel 5 sub *.refvelup
start
*.refvelup 50 add .up store
*.refveldx .dx *.robage sgn mult store
*.refxpos *.refypos angle .setaim *.robage sgn mult store
stop
cond
*.eye5 50 >
*.refeye *.myeye !=
*.maxvel 5 sub *refvelup
start
*.refvelup .up store
*.refveldx .dx *.robage sgn mult store
*.refxpos *.refypos angle .setaim *.robage sgn mult store
stop
cond
*.eye6 34 >
*.refeye *.myeye !=
start
-6 .shoot store
16 .shootval store
stop
cond
*.vtimer 0 =
*.nrg 2000 >
start
10 .vshoot store
1 .mkvirus store
stop
' Slurp Energy
cond
*.eye5 0 >
*.refeye *.myeye !=
start
*.refveldx .dx store
*.refvelup 30 add .up store
stop
cond
*.robage 0 =
start
31999 rnd 1 add 50 store
.tie inc
stop
cond
*.refeye *.myeye !=
*.eye5 45 >
start
*50 .tie *.robage sgn mult *.refage sgn mult store
stop
cond
start
*.myeye 55 store
stop
cond
*.tiepres 0 >
start
.tieval .tieloc store
1000 .tieval store
stop
cond
*.tiepres 0 >
start
*.tiepres .tienum store
stop
cond
*.tienum *50 =
start
-1000 .tieval store
*.tieval sgn .tieloc store
stop
cond
*.tiepres *50 !=
*.tiepres 0 >
start
*.tiepres .deltie store
stop
cond
start
99. sharewaste *.multi mult inc
stop
' Reproduce
cond
*.body 700 >
start
30 .repro store
314 rnd .aimdx store
stop
' Feed on and store body
cond
*.nrg 2000 >
start
10 .strbody store
stop
cond
*.nrg 500 <
start
*.body 0 floor .fdbody *.body sgn mult store
stop
end
