Here's a couple simple genes which illustrate the new vision capabilities in 2.42.9c and beyond.
'If there is nothing in the focus eye, splay eyes 1-8 around the bot evenly. Each eye pans across the their own 1/8th of the 360 degree view.
'eye9 rotates through the full 360 degrees. The focus eye jumps from one eye to the next each cycle.
cond
*.eyef 0 =
start
*.robage 157 mod 140 sub .eye1dir store
*.robage 157 mod 105 sub 157 add .eye2dir store
*.robage 157 mod 70 sub 314 add .eye3dir store
*.robage 157 mod 35 sub 471 add .eye4dir store
*.robage 157 mod 0 sub 628 add .eye5dir store
*.robage 157 mod 35 add 785 add .eye6dir store
*.robage 157 mod 70 add 942 add .eye7dir store
*.robage 157 mod 105 add 1099 add .eye8dir store
*.robage 1256 mod -1 mult .eye9dir store
*.robage 9 mod 4 sub .focuseye store
stop
'If something comes into view in the focus eye, then turn to face it and bring all the eyes to bear in the normal configuration
cond
*.eyef 0 >
start
*.focuseye 525 add * *.focuseye -35 mult add *.aim add .setaim store
0 .eye1dir store
0 .eye2dir store
0 .eye3dir store
0 .eye4dir store
0 .eye5dir store
0 .eye6dir store
0 .eye7dir store
0 .eye8dir store
0 .eye9dir store
0 .focuseye store
stop
'Dummy gene that has an eye statement so the program knows to turn on the eyes
cond
start
*.eye5 > 0
stop