Welcome To Darwinbots > Newbie

Very nice!

(1/4) > >>

Jez:
Hi all

Good job all round.  

It's been fun playing with some of the new additions you have added to the sim, could have done with a bit more info about the new operators? though, those bit thingies like ~ for instance I failed to find any info on.
I've probably worked out how to use And/Or now but think there was another one as well. Oh! Oh! And ceiling/floor? I saw in someones code? And a couple of operators I've seen some of you mathmagicians use that I still haven't found.  

I'm a bit worried my pc has tortured the installation of DB, wouldn't be the first time, so will enter a F2 bot into the lists just to check I'm getting the right results.  

DB V2.4+ just leaves all the bots motionless (for me) so I'm messing with V2.37.6 atm. Looks good though...

Jez:
Ok, didn't want to let me post in leagues or bestiary so I'll post it here and let someone move it!

You can see I've started to add things to combat Excalibur V1.1, couple of nice ideas in Excalibur that I'm going to use. Zebedee is undergoing a redesign atm to cope with Excalibur so I hope you'll forgive the messy code.  

Main reason I have for jumping the gun and releasing a 'beta bot' is that I get Excalibur beating Hunter V2.3 easily. Either Hunter is designed for DB V2.4+ or I'm getting the wrong results and it's not worth a major rehaul of Zebedee till I know.  

Anyway; of the top twenty bots in the F2 league that I could find code for my results give Zebedee as losing to/tieing with Excalibur only. Excalibur is by far the better bot and Zebedee only seems to win rounds through luck.

(Statistical anlysis of the results FTW! Except when I have to reset max rounds.)

'(C. Algificus) Zebedee V1.0
'F2 bot for V2.37.6
'Worst enemy Excalibur V1.1?
'Test bot
'Designed by Jez

'ID gene - Endy
cond
*.robage 0 =
start
.thisgene .memloc store
stop

'search for food
cond
*.eye5 0 =
'*.eye5 0 =
'*.aimsx 0 =
start
140 .aimsx store
stop

'move toward food/rival
cond
*.eye5 0 >
*.eye5 45 <
*.memval *.genes !=
start
*.refxpos *.refypos angle .setaim store
100 *.eye5 sub abs 10 div *.refvel abs add 2 add .up store
'*.mydx .sx store
stop

'shoot food/rival
cond
*.eye5 45 >=
*.eye5 80 <
*.memval *.genes !=
start
-1 .shoot store
20 .shootval store
*.refxpos *.refypos angle .setaim store
100 *.eye5 sub abs 10 div *.refvel abs add 1 add .up store
stop

'shoot rival with venom
cond
*.refshell 5 <
*.eye5 45 >=
*.venom 5 >
*.eye5 80 <
*.memval *.genes !=
*.refeye 0 >
start
-3 .shoot store
.shoot .vloc store
-2 .venval store
*.refxpos *.refypos angle .setaim store
100 *.eye5 sub abs 10 div *.refvel abs add 1 add .up store
stop

'shoot rival with shell
cond
*.refshell 5 >
*.eye5 45 >=
*.venom 5 >
*.eye5 80 <
*.memval *.genes !=
*.refeye 0 >
start
-3 .shoot store
.shoot .vloc store
-2 .venval store
*.refxpos *.refypos angle .setaim store
100 *.eye5 sub abs 10 div *.refvel abs add 1 add .up store
stop

'shoot food/rival
cond
*.shell 5 <
*.eye5 80 >=
*.memval *.genes !=
start
-6 .shoot store
20 .shootval store
*.refxpos *.refypos angle .setaim store
100 *.eye5 sub abs 10 div *.refvel abs add .up store
stop

'shoot food/rival with shell
cond
*.shell 5 >
*.eye5 80 >=
*.memval *.genes !=
start
-1 .shoot store
20 .shootval store
*.refxpos *.refypos angle .setaim store
100 *.eye5 sub abs 10 div *.refvel abs add .up store
stop

'avoid friend
cond
*.memval *.genes =
*.refage 1 >
*.eye5 0 >
start
280 .aimsx store
stop

'reproduce baby behind
cond
*.nrg 2900 >
start
50 .repro store
628 .aimsx store
.shoot dec
stop

'parent rotates back
cond
*.memval *.genes =
*.refage 1 =
start
628 .aimsx store
stop

'cut ties/ lengthen ties
cond
*.numties 0 !=
start
*.tiepres .deltie store
32000 .tielen1 store 'Endy's from Elite's post (not working in v 2.4?
stop

'energy to body
cond
*.nrg 1111 >
start
100 .strbody store
stop

'body to energy
cond
*.nrg 999 <
*.body 201 >
start
100 .fdbody store
stop

'poison/venom + attack avoidance
cond
*.poison 200 <
*.nrg 1000 >
start
10 .strpoison store
.shoot .ploc store
stop

'venom
cond
*.venom 200 <
*.nrg 1000 >
start
10 .strvenom store
stop

'counter attack (ty Elite)
cond
*.eye5 0 =
*.memval *.genes = or
*.refshoot 0 = or
*.shflav 0 !=
*.shflav -2 !=
start
*.shang .aimshoot store
32 .shootval store
-6 .shoot store
0 .shflav store
stop

'anti leach gene
cond
*.tiepres 0 >
start
.tieval .tieloc store
1000 .tieval store
stop

'ID gene - Endy
cond
start
' little constant viral defense gene doubles as ID gene
*.genes .delgene
 .fixpos *.fixed mult dec 'anti fixpos by Elite
*.thisgene *.genes sub dup div
mult *.robage sgn mult store
.genes inc
stop
end

Numsgil:
Hey Jez, been a long time.  Were you still around when I first joined?

You can find information on the bitwise commands here.  They're going to require DB 2.4+  Other commands can be found here.

Not all of the wiki entries for it are finished, if there's a need I could probably write them up real fast.

If you have a sim you think is acting wierd in 2.4+, post a save in the bugs and fixes forum for Eric to take a look at.

The Beastiary won't let you post replies, but I think you should be able to post new topics.

EricL:
Yes, I would be very interested in a sim that demonstrates something not working correctly in 2.4X...

Jez:
Was just testing the waters to see if it did work properly, was hoping someone would test it quickly V Hunter V2.3 and Excalibur V1.1 to check it got same result.

I would be happy to reinstall DB V2.4+ and post a save of the bots not moving but seeing as they are standard bots and if no-one else gets same problem I imagine it would be my install not the game.

Thanks for the links!

Anyway, I decided to poke Zebedees eye's out just to see if I could get rid of all of them. Nearly worked, not quite sure why I need to ref an eye to stop eye's reading 150 though.


'(C. Algificus) Zebedee V1.1
'Won't work without eye ref

def distance 990
'ID gene - Endy
cond
*.robage 0 =
start
.thisgene .memloc store
'************************************************
'*****Why does bot need to ref this eye?*****
'************************************************
*.eye5
'*****Eye will stick at 150 otherwise**********
stop


'search for food
cond
*.refnrg 0 =
*.memval *.genes = or
start
*.aim 280 add .setaim store
0 .distance store
stop

cond
*.refnrg 0 !=
*.memval *.genes !=
start
*.refxpos *.refypos dist .distance store
stop

'move toward food/rival
cond
*.distance 0 !=
*.distance 55 <
*.refnrg 0 !=
*.memval *.genes !=
start
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos dist 10 div *.refvel abs add .up store
stop

'shoot food/rival
cond
*.distance 55 >=
*.distance 20 <
*.memval *.genes !=
start
-1 .shoot store
20 .shootval store
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos dist 10 div *.refvel abs add .up store
stop

'shoot rival with venom
cond
*.refshell 5 <
*.distance 55 >=
*.venom 5 >
*.distance 20 <
*.memval *.genes !=
*.refeye 0 >
start
-3 .shoot store
.shoot .vloc store
-2 .venval store
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos dist 10 div *.refvel abs add .up store
stop

'shoot rival with shell
cond
*.refshell 5 >
*.distance 55 >=
*.venom 5 >
*.distance 20 <
*.memval *.genes !=
start
-3 .shoot store
.shoot .vloc store
-2 .venval store
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos dist 10 div *.refvel abs add .up store
stop

'shoot food/rival
cond
*.shell 5 <
*.distance 20 >=
*.memval *.genes !=
start
-6 .shoot store
20 .shootval store
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos dist 10 div *.refvel abs add .up store
stop

'shoot food/rival with shell
cond
*.shell 5 >
*.distance 20 >=
*.memval *.genes !=
start
-1 .shoot store
20 .shootval store
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos dist 10 div *.refvel abs add .up store
stop

'avoid friend
cond
*.memval *.genes =
*.refage 1 >
*.distance 0 >
start
280 .aimsx store
stop

'reproduce baby behind
cond
*.nrg 2900 >
start
50 .repro store
628 .aimsx store
.shoot dec
stop

'parent rotates back
cond
*.memval *.genes =
*.refage 1 =
start
628 .aimsx store
stop

'cut ties/ lengthen ties
cond
*.numties 0 !=
start
*.tiepres .deltie store
32000 .tielen1 store 'Endy's from Elite's post
stop



'energy to body
cond
*.nrg 1111 >
start
100 .strbody store
stop

'body to energy
cond
*.nrg 999 <
*.body 201 >
start
100 .fdbody store
stop

'poison/venom + attack avoidance
cond
*.poison 200 <
*.nrg 1000 >
start
10 .strpoison store
.shoot .ploc store
stop

'venom
cond
*.venom 200 <
*.nrg 1000 >
start
10 .strvenom store
stop

'counter attack (ty Elite)
cond
*.distance 0 =
*.memval *.genes = or
*.refshoot 0 = or
*.shflav 0 !=
*.shflav -2 !=
start
*.shang .aimshoot store
32 .shootval store
-6 .shoot store
0 .shflav store
stop

'ID gene - Endy
cond
start
' little constant viral defense gene doubles as ID gene
*.genes .delgene
 .fixpos *.fixed mult dec 'anti fixpos by Elite
*.thisgene *.genes sub dup div
mult *.robage sgn mult store
.genes inc
stop
end

Navigation

[0] Message Index

[#] Next page