'Designed to knock out any poisonous bot
def badarea 57

cond
*.robage 0 =
start
140 .eye6width store
280 .eye7width store
280 .eye8width store
280 .eye9width store
-68 .eye1dir store
-68 .eye2dir store
-68 .eye3dir store
-68 .eye4dir store
-68 .eye5dir store
-140 .eye6dir store
317 .eye7dir store
634 .eye8dir store
970 .eye9dir store
-2 .focuseye store
.shoot .ploc store
2 .strpoison store
.deltie inc
stop

cond
*.eye1 *.eye2 *.eye3 *.eye4 *.eye5 add add add add 0 =
*.badarea 16 <=
start
157 .aimdx store
.badarea inc
stop

cond
*.myeye *.refeye =
start
.badarea inc
7 .aimdx store
stop

cond
*.eye3 0 =
*.eye4 0 !=
start
34 .aimdx store
stop
cond
*.eye3 0 =
*.eye2 0 !=
start
-34 .aimdx store
stop
cond
*.eye3 0 =
*.eye5 0 !=
start
68 .aimdx store
stop
cond
*.eye3 0 =
*.eye1 0 >
start
-68 .aimdx store
stop

cond
*.badarea 16 >
start
*.maxvel .up store
.badarea dec
stop

cond
*.nrg 1000 >
*.robage 2 >
start
100 .strbody store
stop

cond
*.body 1000 >=
start
100 .fdbody store
stop

cond
*.nrg 2000 >
start
37 .repro store
.deltie inc
stop

cond
*.waste 100 >
start
*.waste .shootval store
-4 .shoot store
stop


cond
*.myeye *.refeye !=
or
*.numties 0 =
*.eyef 0 >
start
*.refxpos *.refypos angle .setaim store
*.velsx .dx store
*.refvelup 15 add *.maxvel ceil 0 floor .up store
.tie inc
0 .badarea store
stop

cond
*.myeye .trefeye = 
start
*.tiepres .deltie store
stop

cond
*.eyef 0 >
*.myup *.refup !=
start
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos angle *.aim sub .aimshoot store
*.refxpos *.refypos dist 700 div *.maxvel mult *.refvel add 0 floor *.maxvel ceil .up store
*.veldx .sx store
*.eyef 50 >
-6 .shoot store
*.nrg 50 div 20 floor 1000 ceil .shootval store
*.in1 16 =
*.tin10 16 =
.shootval .shoot store
31900 .shootval store
dropbool
clearbool
0 .badarea store
stop

cond
*.paralyzed 0 >
*.poisoned 0 >
or
start
99 .repro store
stop

start
*.tiepres .deltie store
*.pain .badarea store
*.shoot -2 sub sgn abs -- abs .shoot mult store
stop