Show Posts

This section allows you to view all posts made by this member. Note that you can only see posts made in areas you currently have access to.


Messages - irishguy

Pages: [1]
1
Interesting behaviour bots / Devious Eraticatorus (MB)(irishguy) - 06.28.07
« on: September 20, 2006, 04:48:19 PM »
Quote from: Jez
Cool! That works well.

I thought virus's could be added anywhere in the dna, except gene 1? That bot has an efficient way of dealing with any virus's added to end of dna though.

well im using 2.42.7, and it seems as tho viruses are just slapped onto the end here.

2
Interesting behaviour bots / Devious Eraticatorus (MB)(irishguy) - 06.28.07
« on: September 18, 2006, 08:37:56 PM »
'Devious eraticatorus - by irishguy

'extremely effective tie-feeder, kills tie-destroyers with relative ease, and
'eraticates alot of other bots in about 100-300 cycles


'uses MB ties to leach nrg like no other. consequently, he "shares" with his
'conspecs, but this is by accident, as you will notice sometimes he will reproduce
'and his children will either die, or he will die. if alga is fixed, growth seems
'to be much more linear in the first 500 cycles. however, if alga roams free,
'he'll have a much more exponential growth. this is easy to see if the enemy
'is very aggressive. if not, he'll flourish too quickly.

'much of his super effectiveness was discovered on accident. I.e. his Antivirus.
'his AV simply prevents extra genes from forming. that was a problem I had when
'he would infect his friends, creating bots with over 80 genes sometimes. later
'I realized this stops all viruses that get appended.

'his ability to uber-leech make it possible to kill tie-destroyers, with ties.
'he'll superleech them and then kill them with the standard tie-feeding.

'his virus is also more efficent than those that randomly delete genes. it takes
'less time to create a virus, thus because my bots able to propagate quickly, the
'virus does not spread, easily dodging Antivirus genes looking for "mkvirus" to have
'been altered.

Code: [Select]
'start gene
cond
  *.robage 0 =
start
  256 41 store
  *.genes .mkvirus store
stop

'virus launcher
cond
*.eye5 50 >
*.refeye 8 !=
*.refeye 0 !=
*.eye5 77 !=
*.vtimer 1 =
start
100 .vshoot store

stop

'tie-maker
cond
*.eye5 50 >
*.refeye 0 =
*.eye5 77 !=
start
1 .tie store
stop

'virus production
cond
*.vtimer 0 =
start
  *.genes .mkvirus store
stop

'tie-bots eye system
cond
*.eye4 *.eye6 !=
start
*.eye4 *.eye6 sub .aimsx store
stop

'speed control
cond
*.vel 30 <
start
30 *.vel sub .up store
stop

'actual feeding routine
cond
*.numties 0 >
start
-1 .tieloc store
-1000 .tieval store
*.tiepres .tienum store
stop

'birth-tie kill
cond
*.robage 1 >
*.robage 50 <
start
0 .deltie store
stop

'never get fixed
cond
*.fixed 0 !=
start
.fixpos dec
stop

'reproduction - I don't know what "mult 250" does. I saw it in some bot. I think it may just be
'there to slow reproduction. also because he needs 4000 to make kids, but only 2000 to add to
'his body, he'll rarely reproduce if he has no veggies.
cond
  *.nrg 4000 >
start
  20 .repro store
  mult 250
stop

'slime, so I can minimize viral infection
cond
  *.slime 100 <
start
  1000 .mkslime store
stop

'waste release, alot of times he just happens to hit his veggies
cond
*.waste 10 >
start
*.waste .shootval store
-4 .shoot store
stop

'the superleech, I don't know if trefage actually helps
cond
*.robage 30 >
*.trefage 30 >
*.multi 1 =
start
99 .sharenrg store
.sharewaste inc
stop

'nrg storage
cond
*.nrg 2000 >
start
100 .strbody store
stop

'nrg replenish
cond
*.nrg 500 <
start
100 .fdbody store
stop

'gene check
'this simple AV stops almost every infection I've seen. im so mad that I found this
'because it means other people will be able to easily stop viral attacks.
cond
*.genes 17 >
start
*.genes .delgene store
stop

'my virus - a.k.a. the down syndrome virus (lol)
'he doesn't replicate, because of the AVs that kill replicators.
'but his payload does 2 great things
'1. he make a extremely small child, which is is easy pickings for my other bots!!
'2. he deletes the first gene, over and over until all the genes, including the
'   the virus are gone. now the infected bot is free food for his attacker.
'   because he is reproducing, each child he makes, will be more retarded than the last!
cond
  *41 256 !=
start
1 .repro store
1 .delgene store
stop

end

3
Newbie / wierd code problem
« on: September 15, 2006, 07:44:55 PM »
ah it was silly.

for some reason vegs were just getting big and not reproducing. then, I realized I hadt the population control too low

also I had stated that I found DB thru wikipedia, and that I am going to study Computer science so im not so new the whole programming thing, just the language

4
Newbie / wierd code problem
« on: September 14, 2006, 02:36:43 PM »
EDIT


nvm I found the problem

Pages: [1]