Topics

16

Multi-Bots / Triangulus Versabundus (MB)(Shen)-12.08.04

« on: April 23, 2005, 05:41:39 AM »

Code: [Select]

'Topic: I found something cool 
'Shen
' Triangulus Versabundus
'
' An example of custom variables
' Based on PYs Hexagonis
' Making a Custom Variable is easy.
' At the start of the DNA type 'def VarName MemoryLocation'.
' To address it use normal label syntax.
' *.VarName for the value and .VarName for the Memory location it represents
' It will show as the MemLoc number in game though, so remember what you assign it to!
' - Custom Variable -
' *.State is to tell a bot what stage of building the MB its at.
def State 50


' -=- Nav -=-

' - Spin -
cond
*.State 2 =
start
40 .aimdx store
stop

' - Move Towards Food -
cond
*.eye5 0 >
*.eye5 50 <
*.refeye *.myeye !=
*.State 2 =
*.multi 1 =
start
5 .up store
stop

' - Avoid Freinds -
cond
*.eye5 30 >
*.refeye *.myeye =
*.State 2 =
*.multi 1 =
start
-5 .up store
stop

' - Eat -
cond
*.eye5 20 >
*.refeye *.myeye !=
*.State 2 =
*.multi 1 =
start
-1 .shoot store
stop

' - Share Nrg -
cond
*.multi 1 =
*.nrg 100 >
*.trefnrg *.nrg !%=
start
50 .sharenrg store
stop

' -=- Reproduction Loop -=-

' - Bad Bot -
cond
*.multi 1 =
*.numties 2 <
start
1 .deltie store
20 .up store
stop

' - Lone Bot - (This might be screwing up)
cond
*.numties 0 =
*.vel 0 =
*.State 2 =
*.eye5 30 <
start
0 .State store
1 .fixpos store
stop

' - Set Angle - (Cant turn this gene off or it screws up, its a big drain on nrg, any ideas? )
cond
*.multi 1 =
*.State 2 =
start
1 .tienum store
120 .fixlen store
628 .fixang store
35 .stifftie store
'3 .State store
0 .fixpos store
stop

' - Tie to Child -
cond
*.State 1 =
start
1 .tie store
1 .readtie store
2 .State store
stop

' - Repro -
cond
*.State 0 =
'*.nrg 200 >
start
33 .repro store
210 .aimdx store
1 .State store
stop

' - Start Repro Loop -
cond
*.State 2 =
*.nrg 15000 >
start
1 .deltie store
stop

- End DNA -
end

17

Multi-Bots / Vermis Ettinus v0.1 (MB)(Eight)-27.08.04

« on: April 23, 2005, 05:40:45 AM »

Code: [Select]

'Topic: New Bots
'Vermis Ettinus Ettin Worm (guest) (aka Eight)
' Vermis Ettinus v0.1 (my first MB)
'
' Ettin Worm ___ by Eight (eightland.com)
' "two heads are better than one"
'
' - each head can eat and see, and when one sees something
' it tells the other head through the tie so they can coordinate
' their efforts.
' - has a nasty reproduction tie bug, making some children misaligned
' and useless, however if the deformed baby gets enough food or has
' its head blown off, there is a good chance it will redevelop properly.

' timer
cond
*44 0 >
start
44 dec
stop

cond
*44 0 =
start
5 44 store
stop

' energy share
cond
*44 1 =
*.multi 1 =
*.tiepres 1 =
start
1 .tienum store
50 .sharenrg store
50 .sharewaste store
stop

' waste management
cond
*.waste 100 >
start
*.waste .shootval store
-4 .shoot store
stop

' no head
cond
*.numties 0 =
start
0 45 store
stop

' grow head
cond
*45 0 =
*.numties 0 =
*.nrg 500 >
start
50 .repro store
2 45 store
stop

' make a tie
cond
*.robage 0 =
*.eye5 70 >
start
1 .tie store
3 45 store
stop

cond
*.numties 1 =
*45 3 =
start
628 .fixang store
160 .fixlen store
40 .stifftie store
628 .tieval store
.fixang .tieloc store
1 .tienum store
4 45 store
stop

cond
*.numties 1 =
*45 2 =
start
628 .fixang store
5 45 store
stop

' which is closer
cond
*.robage 3 >
*.multi 1 =
*45 4 =
*.eye5 0 >
*.refeye *.myeye !=
start
46 .eye5 store
.eye5 .tieval store
46 .tieloc store
1 .tienum store
stop

cond
*.robage 3 >
*.multi 1 =
*45 5 =
*.eye5 0 >
*.refeye *.myeye !=
start
47 .eye5 store
.eye5 .tieval store
47 .tieloc store
1 .tienum store
stop

'move
cond
*.robage 3 >
*.multi 1 =
*45 5 =
*.eye5 *46 >
*.refeye *.myeye !=
start
5 .up store
5 .tieval store
.dn .tieloc store
1 .tienum store
stop

cond
*.robage 3 >
*.multi 1 =
*45 4 =
*.eye5 *47 >
*.refeye *.myeye !=
start
5 .up store
5 .tieval store
.dn .tieloc store
1 .tienum store
stop

' search
cond
*.multi 1 =
*47 0 =
*46 0 =
*.sun 1 =
*.vel 0 =
start
30 .up store
30 .tieval store
.dn .tieloc store
1 .tienum store
stop

cond
*47 0 =
*46 0 =
*.multi 1 =
*.vel 0 =
start
5 .dx store
stop

' turn
cond
*.multi 1 =
*.eye1 *.eye3 >
*.refeye *.myeye !=
start
30 .sx store
30 .tieval store
.sx .tieloc store
1 .tienum store
stop

cond
*.multi 1 =
*.eye3 *.eye5 >
*.refeye *.myeye !=
start
15 .sx store
15 .tieval store
.sx .tieloc store
1 .tienum store
stop

cond
*.multi 1 =
*.eye7 *.eye5 >
*.refeye *.myeye !=
start
15 .dx store
15 .tieval store
.dx .tieloc store
1 .tienum store
stop

cond
*.multi 1 =
*.eye9 *.eye7 >
*.refeye *.myeye !=
start
30 .dx store
30 .tieval store
.dx .tieloc store
1 .tienum store
stop

cond
*.multi 1 =
*.eye4 *.eye6 >
*.refeye *.myeye !=
start
5 .sx store
5 .up store
stop

cond
*.multi 1 =
*.eye6 *.eye4 >
*.refeye *.myeye !=
start
5 .dx store
5 .up store
stop

' eat
cond
*.multi 1 =
*.eye5 30 >
*.refeye *.myeye !=
start
15 .tie store
stop

cond
*.multi 0 =
*.robage 3 >
*.numties 0 =
*.eye5 30 >
*.refeye *.myeye !=
start
15 .tie store
stop

' sabotage attack ties/feed
cond
*.multi 1 =
*.numties 1 >
*.tiepres 2 >
*.tiepres 1 !=
start
-1000 .tieval store
-1 .tieloc store
*.tiepres .tienum store
stop

' divide
cond
*.numties 1 =
*.nrg 8000 >
start
0 .tieval store
45 .tieloc store
1 .tienum store
1 .deltie store
0 45 store
stop

end

18

Multi-Bots / Vermis Ettinus 0.15 (MB)(Eight)-28.08.04

« on: April 23, 2005, 05:39:46 AM »

Code: [Select]

'Topic: New Bots
'Eight
' Vermis Ettinus 0.15 (rebuild3) by Eight
' (Ettin Worm) "two heads are better than one"
'
' - this version is a simplified example of VE, which eats
' plants with ties and fixes enemy bots in place to shoot
' them normally.
' - basic, no slime or bodybuilding. just serves as an example
' of a quick, simple multibot.
' - once active, each head has a different number (45)
' which is either 0 or 2.


' idle
cond
*45 2 =
*.vel 0 =
start
5 .dx store
5 .tieval store
.sx .tieloc store
1 .tienum store
stop

' sun
cond
*.sun 1 =
*.vel 0 =
start
30 .up store
30 .tieval store
.dn .tieloc store
1 .tienum store
stop

' share
cond
*.numties 1 =
*.multi 1 =
*.trefnrg *.nrg !%=
start
50 .sharenrg store
stop

' single
cond
*.numties 0 =
start
0 45 store
stop

' grow head
cond
*45 0 =
*.multi 0 =
*.nrg 500 >
start
45 inc
50 .repro store
stop

' parent ties to its own child
cond
*45 1 =
*.eye5 70 >
*.refeye *.myeye =
start
1 .tie store
1 .readtie store
45 inc
stop

' angle - this gene stays active until the tie hardens so it's
' the first thing that kicks in. this -ensures- perfect angles.
cond
*.multi 0 =
*.numties 1 =
start
628 .fixang store
stop

' turn
cond
*.eye1 *.eye5 >
*.refeye *.myeye !=
start
5 .sx store
stop

cond
*.eye9 *.eye5 >
*.refeye *.myeye !=
start
5 .dx store
stop

cond
*.eye3 *.eye5 >
*.refeye *.myeye !=
start
2 .sx store
stop

cond
*.eye7 *.eye5 >
*.refeye *.myeye !=
start
2 .dx store
stop

' tiefeed on vegs
cond
*.multi 1 =
*.numties 1 =
*.eye5 30 >
*.refeye *.myeye !=
*.refshoot 0 =
start
3 .tie store
stop

' tiefeed/sabotage tiefeeders
cond
*.numties 1 >
*.tiepres 1 !=
start
*.tiepres .tienum store
-1000 .tieval store
-1 .tieloc store
stop

' freeze gun
cond
*.reffixed 0 =
*.multi 1 =
*.numties 1 =
*.eye5 30 >
*.refeye *.myeye !=
*.refup 0 >
start
1 .shootval store
216 .shoot store
stop

' shoot
cond
*.reffixed 1 =
*.multi 1 =
*.numties 1 =
*.eye5 30 >
*.refeye *.myeye !=
*.refup 0 >
start
-1 .shoot store
stop

' unfix
cond
*.fixpos 1 =
start
0 .fixpos store
stop

' what's closest
cond
*.multi 1 =
*.eye5 0 >
*.refeye *.myeye !=
start
.eye5 .tmemloc store
stop

' move
cond
*.multi 1 =
*.eye5 *.tmemval >
*.refeye *.myeye !=
*.eye5 60 <
start
100 *.eye5 sub 5 div .up store
100 *.eye5 sub 5 div .tieval store
.dn .tieloc store
1 .tienum store
stop

' make sure you've only got one tie when you split
cond
*.numties 1 =
*.eye5 30 <
*.nrg 10000 >
start
0 45 store
1 .deltie store
stop

end

19

Multi-Bots / Gaesum (MB)(Shen)-29.07.04

« on: April 23, 2005, 05:38:06 AM »

Code: [Select]

'Topic: Another MultiBot 
'Shen

' Gaesum
' Two celled Multi-bot


'--| Reproduction loop |--

' Unmake slime
cond
*.slime 0 >
*.numties 0 =
start
*.slime *.slime *.slime add sub .mkslime store
stop

' Child ties to parent
cond
*.robage 0 =
*.eye5 70 >
start
1 .tie store
3 50 store
stop

' Lone bot repros its head
cond
*.numties 0 =
*.eye5 40 <
*.nrg 500 >
start
50 .repro store
2 50 store
stop

' Child aligns as head
cond
*.multi 1 =
*50 3 =
start
1 .tienum store
628 .fixang store
240 .fixlen store
35 .stifftie store
0 50 store
stop

' Parent aligns as tail
cond
*.multi 1 =
*50 2 =
start
1 .tienum store
0 .fixang store
1 50 store
stop

' Rescue Lost single bot
cond
*.vel 2 <
*.tiepres 0 =
start
20 .aimdx store
stop

' ---------------------
' Navigation genes

' Cant see anything, search pattern
cond
*50 0 =
*.vel 20 <
*.eye5 10 <
start
5 .up store
30 rnd 30 rnd sub .aimdx store
stop

'Can see freind in distance, continue search
cond
*50 0 =
*.vel 20 <
*.eye5 10 >
*.eye5 50 <
*.refeye *.myeye =
start
5 .up store
30 rnd 30 rnd sub .aimdx store
stop

'Can see food in distance, approach it
cond
*50 0 =
*.vel 20 <
*.eye5 9 >
*.eye5 50 <
*.refeye *.myeye !=
start
5 .up store
stop

' Can see freind close in front, avoid him
cond
*50 0 =
*.eye5 30 >
*.refeye *.myeye =
start
10 .up rnd store
*.eye4 *.eye6 sub .aimdx store
*.eye4 *.eye6 sub 10 div .dx store
stop

' Can see Food Close in front, eat it
cond
*.eye5 40 >
*50 0 =
*.refeye *.myeye !=
*.multi 1 =
start
-1 .shoot store 4 .dn store
stop

' Nothing in front, something to the sides, turn towards it
cond
*.eye2 *.eye8 !=
*.eye5 10 <
*50 0 =
*.multi 1 =
start
*.eye8 *.eye2 sub .dx store
stop

' Freind was in front, something to the sides, probably freind avoid him
cond
*.eye2 *.eye8 !=
*.eye5 10 <
*.refeye *.myeye =
*50 0 =
*.multi 1 =
start
5 .up rnd store *.eye2 *.eye8 sub 2 div .aimdx store
*.eye2 *.eye8 sub 10 div .dx store
stop

' Enemy was in front something to sides, turn towards it
cond
*.eye2 *.eye8 !=
*.eye5 10 <
*.refeye *.myeye !=
*50 0 =
*.multi 1 =
start
*.eye8 *.eye2 sub .dx store
stop

' Enemy in front, refine aim
cond
*.eye4 *.eye6 !=
*.eye5 10 >
*.refeye *.myeye !=
*.multi 1 =
start
*.eye6 *.eye4 sub .aimdx store
*.eye6 *.eye4 sub 5 div .dx store
stop

' Nothing in front, something to side, last saw an enemy so turn to it
cond
*.eye4 *.eye6 !=
*.eye5 10 <
*.refeye *.myeye !=
*.multi 1 =
start
*.eye6 *.eye4 sub .aimdx store
*.eye6 *.eye4 sub 5 div .dx store
stop

' Tail stuck, wiggle free
cond
*.vel 15 <
*50 1 =
*.eye5 70 >
start
*.eye2 *.eye8 sub 10 div .dx store
stop

'------------------
' Other stuff

' Waste disposal
cond
*.waste 200 >
start
-4 .shoot store
*.waste .shootval store
stop

' Share energy with tail
cond
*.nrg *.trefnrg !%=
*.multi 1 =
*50 0 =
start
50 .sharenrg store
stop

' Make body if your not feeding
cond
*.nrg 5000 >
*.body 1000 <
*.eye5 30 <
start
100 .strbody store
stop

' Feed from body if you need energy
cond
*.nrg 2000 <
*.body 50 >
start
100 .fdbody store
stop

' Make slime
cond
*.nrg 1000 >
*.slime 190 <
*.multi 1 =
start
50 .mkslime store
stop

' Make shell
cond
*.pain 50 >
*.nrg 4000 >
*.shell 50 <
*.multi 1 =
start
20 .mkshell store
stop

' Start Repro loop
cond
*.multi 1 =
*.nrg 8000 >
*.eye5 30 <
start
1 .deltie store
stop

end

20

Multi-Bots / Dimacheri (MB)(Shen)-28.08.04

« on: April 22, 2005, 01:46:08 PM »

Code: [Select]

'Topic: New Bots
'Shen
' --==-- Dimacheri --==--

' MultiBot
' Tie feeder
' Uses both heads
' Venomous
' Custom labels for ease of reading
' Robust repro genes. Uses .fixpos to ensure tie. 99% success rate.


' -=- Custom Labels -=-
' *.Head is the primary bot
' *.Temp is used for tie aligning
' *.BotTie is the tie joining the MB
' *.EatTie is feeding tie
' *.VenShot is for timing venom shots
' *.ID is a non-corruptable conspecific ID
' *.Tied is to time the feeding tie

def Head 50
def Temp 51
def BotTie 52
def EatTie 53
def VenShot 54
def RefSet 55
def ID 56
def Tied 57



' --==-- Navigation --==--

' - Switch Heads -
cond
*.refeye *.ID =
*.numties 1 =
*.multi 1 =
*.Head 1 =
*.Tied 0 =
start
*.BotTie .tienum store
.refeye .tmemloc store
stop

cond
*.tmemval *.ID !=
*.refeye *.ID =
*.numties 1 =
*.multi 1 =
*.Head 1 =
*.Tied 0 =
start
2 .Head store
*.BotTie .tienum store
.Head .tieloc store
1 .tieval store
stop

' - Reset Refeye -
cond
*.eye5 0 =
*.refeye *.ID =
*.multi 1 =
*.Head 1 =
start
.RefSet inc
stop

cond
*.RefSet 20 =
start
0 .refeye store
0 .RefSet store
stop


' -=- Head Nav -=-

' - Approach Enemy -
cond
*.eye5 0 >
*.eye5 35 <
*.refeye *.ID !=
*.vel *.maxvel <
*.multi 1 =
*.Head 1 =
start
*.maxvel *.vel sub .up store
stop

' - Search -
cond
*.eye5 0 =
*.refeye *.ID !=
*.eye3 *.eye 7 =
*.vel *.maxvel <
*.multi 1 =
*.Head 1 =
start
*.maxvel *.vel sub .up store
100 rnd 100 rnd sub .aimdx store
*.aimdx 10 div .dx store
stop


' -=- Distant Tracking -=-

' - Wide -
cond
*.eye3 30 <
*.eye3 *.eye7 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
-80 .aimdx store
-15 .dx store
stop

' - Wide -
cond
*.eye7 30 <
*.eye7 *.eye3 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
80 .aimdx store
15 .dx store
stop

' - Narrow -
cond
*.eye4 30 <
*.eye4 *.eye6 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
-40 .aimdx store
-10 .dx store
stop

' - Narrow -
cond
*.eye6 30 <
*.eye6 *.eye4 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
40 .aimdx store
10 .dx store
stop


' -=- Close Tracking -=-


' - Narrow -
cond
*.eye4 30 >
*.eye4 *.eye6 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
-30 .aimdx store
-20 .dx store
stop

' - Narrow -
cond
*.eye6 30 >
*.eye6 *.eye4 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
30 .aimdx store
20 .dx store
stop

' - Wide -
cond
*.eye3 30 >
*.eye3 *.eye7 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
-50 .aimdx store
-30 .dx store
stop

' - Wide -
cond
*.eye7 30 >
*.eye7 *.eye3 >
*.refeye *.ID !=
*.multi 1 =
*.Head 1 =
start
50 .aimdx store
30 .dx store
stop


' -=- Conspecifics -=-

' - Avoid Close Friend -
cond
*.eye5 30 >
*.refeye *.ID =
*.multi 1 =
*.Head 1 =
start
*.eye4 *.eye6 sub .aimdx store
10 rnd 10 rnd sub *.eye4 *.eye6 sub 5 div add .dx store
stop

' - Ignore Distant Friend -
cond
*.eye5 30 <
*.refeye *.ID =
*.vel *.maxvel <
*.multi 1 =
*.Head 1 =
start
*.maxvel *.vel sub .up store
100 rnd 100 rnd sub .aimdx store
*.aimdx 10 div .dx store
stop


' -=- Tail Nav -=-

' - Narrow -
cond
*.eye6 *.eye4 !=
*.refeye *.ID !=
*.multi 1 =
*.Head 2 =
start
*.eye6 *.eye4 sub .aimdx store
*.eye6 *.eye4 sub 4 div .dx store
stop

' - Wide -
cond
*.eye7 *.eye3 !=
*.refeye *.ID !=
*.multi 1 =
*.Head 2 =
start
*.eye7 *.eye3 sub .aimdx store
*.eye7 *.eye3 sub 4 div .dx store
stop



' --==-- Defence --==--


' -=- Shot/Venom -=-

' - Body Shot -
cond
*.eye5 20 >
*.refeye *.ID !=
*.refeye 0 !=
*.VenShot 3 <
*.multi 1 =
start
-6 .shoot store
.VenShot inc
stop

' - Eat Alga -
cond
*.eye5 20 >
*.refeye 0 =
*.multi 1 =
start
-6 .shoot store
stop

' - Venom Attack -
cond
*.eye5 20 >
*.refeye *.ID !=
*.refeye 0 !=
*.VenShot 3 =
*.multi 1 =
start
8 .strvenom store
-3 .shoot store
8 .shootval store
.mkslime .vloc store
-200 .venval store
0 .VenShot store
stop


' -=- Tie Feed -=-

' - Sever Feeding Tie -
cond
*.Tied 2 =
start
*.EatTie .deltie store
0 .Tied store
stop

' - Drain Energy -
cond
*.Tied 0 >
start
*.EatTie .tienum store
-1 .tieloc store
-1000 .tieval store
.Tied inc
stop

' - Tie to Enemy -
cond
*.eye5 35 >
*.refeye *.ID !=
*.numties 1 =
*.multi 1 =
*.Head 0 !=
*.Tied 2 !=
start
*.EatTie .tie store
.Tied inc
stop

' - Leech -
cond
*.tiepres *.BotTie !=
*.tiepres *.EatTie !=
*.numties 1 >
start
*.tiepres .tienum store
1000 .tieval store
.tieval .tieloc store
stop


' -=- Shields -=-

' - Make shell -
cond
*.maxvel 40 >
*.multi 1 =
*.nrg 2000 >
start
5 .mkshell store
stop

' - Lighten Shell -
cond
*.maxvel 35 <
*.multi 1 =
*.nrg 2000 >
start
-1 .mkshell store
stop

' - Make slime -
cond
*.nrg 500 >
*.slime 190 <
*.numties 1 =
start
200 *.slime sub .mkslime store
stop

' - Make Body -
cond
*.body 500 <
*.nrg 2000 >
start
100 .strbody store
stop

' - Feed from Body -
cond
*.nrg 1500 <
start
100 .fdbody store
stop



' --==-- Other Stuff --==--


' - Sharing -
cond
*.nrg *.trefnrg !%=
*.numties 1 =
*.multi 1 =
*.Tied 0 =
start
50 .sharenrg store
50 .shareslime store
50 .shareshell store
50 .sharewaste store
stop

' - Unfix -
cond
*.fixed 1 =
*.multi 1 =
start
0 .fixpos store
stop

' - Chameleon -
cond
*.out1 0 =
*.in1 0 !=
start
*.in1 .out1 store
*.in2 .out2 store
stop

' - Waste -
cond
*.waste 400 >
*.Tied 0 >
start
*.EatTie .tienum store
-4 .tieloc store
*.waste .tieval store
stop



' --==-- Reproduction loop --==--
' Using *.Head for final role assignment
' 0 is lone bot, 1 is Head, 2 is Tail
' Using *.Temp for tie aligning
' 0 is aligned, 1 is align Head, 2 is align Tail
' *.BotTie is the tie joining the MB

' - Unmake slime -
cond
*.slime 0 >
*.Temp 0 =
*.multi 0 =
start
-200 .mkslime store
stop

' - Spin Lone Bots -
cond
*.numties 0 =
*.robage 10 >
start
30 .aimdx store
stop

' - Child ties to parent and becomes Temp Head -
cond
*.robage 0 =
start
*.myeye .ID store
1000 rnd 1 add .BotTie store
1000 rnd 1 add .EatTie store
*.BotTie .tie store
1 .Temp store
stop

' - Lone bot repros its Head and becomes Temp Tail -
cond
*.numties 0 =
*.eye2 30 <
*.eye5 30 <
*.eye8 30 <
*.nrg 500 >
start
50 .repro store
1 .fixpos store
2 .Temp store
stop

' - Temp Head aligns and becomes Head -
cond
*.multi 1 =
*.Temp 1 =
start
*.BotTie .readtie store
*.BotTie .tienum store
628 .fixang store
150 .fixlen store
35 .stifftie store
1 .Head store
0 .Temp store
stop

' - Temp Tail aligns and becomes Tail -
cond
*.multi 1 =
*.Temp 2 =
start
*.tiepres .BotTie store
*.BotTie .readtie store
*.BotTie .tienum store
628 .fixang store
2 .Head store
0 .Temp store
stop

' - Start Repro Loop -
cond
*.multi 1 =
*.nrg 4000 >
*.numties 1 =
*.eye2 20 <
*.eye5 20 <
*.eye8 20 <
*.Head 1 =
start
*.BotTie .deltie store
1 .fixpos store
0 .Head store
stop



' -=- End DNA -=-
end

21

Multi-Bots / Multi-Bots League

« on: April 22, 2005, 01:14:20 PM »

Link for: Running the leagues yourself
Link for: Error reporting (bugs with league or errors with links and bot DNA or problems running the league yourself.)

• League: Multi-Bots
• Last update: 08.07.07
• Multi-Bot League Rules
• This league was run on DB v2.43

(March 05 dates or April 05 dates mean the bot was probably designed earlier.)

Top Bots in Multi-Bot league:

#MB
1 - Helios (MB)(Light)-18.12.04
2 - Inchworm (MB)(PY)-18.10.04
3 - Dimacheri (MB)(Shen)-22.04.05
4 - Inchworm2 (MB)(PY)-26.10.04
5 - Cerberus (MB)(Eight)-25.02.05
6 - Gaesum (MB)(Shen)-23.04.05
7 - Vermis Ettinus v0.1 (MB)(Eight)-23.04.05
8 - Hed Wig (MB)(Ark)-07.03.06
9 - Symbioticus 2.5 (MB)(SY)(Shen/Elite)-02.11.06 -Not sure of author
10- Triangulus Versabundus (MB)(Shen)-23.04.05
11- Vermis Ettinus 0.15 (MB)(Eight)-23.04.05
12- Symboticus (Elite) -missing from bestiary
13- Octopus (MB)(Welwordian)-12.10.05
14- Batavus Minimalis (Henk) -missing from bestiary
15- Shen3 (MB)(Shen)-23.04.05
16- Botumor (MB)(Spoonkiny)-08.09.05
17- Originaloc (F1)(Welwordian)-10.10.05
18- Hexagonis (MB)(PY)-25.02.05
19- Inchy (MB)(Endy)-19.04.05
20- Vermis P (MB)(Carlo)-2002
21- EMPTY
22- EMPTY
23- EMPTY
24- EMPTY
25- EMPTY
26- EMPTY
27- EMPTY
28- EMPTY
29- EMPTY
30- EMPTY

Multibotleaguetable.txt and Multibotleague.zip available below for download.

22

Multi-Bots / Multi-Bot League Rules

« on: April 22, 2005, 12:52:13 PM »

Here are the rules and settings that will be used to establish the league order.

Settings!

• Field size 9237 X 6928. If you can't figure out how to get this (non standard size), just click the "Restart and Leagues" tab from the options window then check the "Use F1 conditions" box. If you don't want to run the leagues, simply uncheck it again and the size setting will stay the same.
• Starting chloroplasts = 16000
• Veggie feeding rate = 30
• Maximum veggies = 25
• Respawn veggies = 10
• Kill distant Vaggies = OFF
• Corpses = OFF
• Pond mode = OFF
• Day Night cycles = OFF
• Bouyancy = OFF
• Friction = 3
• Gravity = zero
• Brownian Motion = zero
• Mutations = ALL Disabled
• Internet sharing = OFF

Selecting the "Set F2/F3/MB settings" button will automatically set these.
You can set league restrictions from global settings.

Rules!

• Please make sure you have MB kill restrictions enabled
• Weather = ON
• Costs = F1 Default

23

Short bots / Furiae (6G)(Light)-21.04.05

« on: April 22, 2005, 07:39:24 AM »

Code: [Select]

'Little Furiae
'6 gene bot
'designed for db 2.36 (3.0)
'by Light
'21/4/05

'deletes all viruses from its genome, although I know its only a matter of time before you lot manage to break it :)

'Gene 1 - Movement
cond
  *.robage 5 >
  *.eye5 1 > and
  *.myeye *.refeye != and
  *.genes 6 != or
start
  *.genes 6 sub 2 mult 950 store
  *.refxpos *.refypos angle .setaim store
  *.refvelup *.refxpos *.refypos dist *.body 20 div 100 add sub 10 div add .up store
  *.refveldx .dx store
  -6 .shoot store
  -5 .shootval store
stop

'Gene 2 - Rotation
cond
  *.eye5 0 =
  *.refeye *.myeye = or
  *950 0 != or
start
  1 *.thisgene *950 sub 1 add div *950 add 950 store
  300 .aimsx store
  1 *.velscalar 1 add div 25 mult .up store
stop

'Gene 3
cond
  *.nrg 1000 >
  *950 0 != or
start
  1 *.thisgene *950 sub 1 add div *950 add 950 store
  1 *.genes 5 sub div *.nrg 1500 sub mult .strbody store
  1 *.genes 5 sub div 200 *.shell sub mult .mkshell store
  1 *.genes 5 sub div 200 *.slime sub mult .mkslime store
stop

'Gene 4 - waste
cond
  *.waste 100 >
  *950 0 != or
start
  1 *.thisgene *950 sub 1 add div *950 add 950 store
  *.waste .shootval store
  -4 .shoot store
stop

'Gene 5 - Reproduction
cond
  *.nrg 3500 >
  *.eye5 0 = and
  *950 0 != or
start
  1 *.thisgene *950 sub 1 add div *950 add 950 store
  1 *.genes 5 sub div 40 mult .repro store
  628 .aimdx store
stop

'gene 6
cond
  *.delgene 0 !=
  *950 0 != or
  *.genes 6 != or
start
  1 *.thisgene *950 sub 1 add div *950 add 950 store
  *950 .delgene store
  0 950 store
  0 .shoot store
  0 .repro store
  0 .mrepro store
  0 .sexrero store
  0 .mkvirus store
stop
end

24

Bugs and fixes / *.myeye

« on: April 07, 2005, 08:58:45 PM »

when you insert a bot whilest running a simulation its *.myeye value is allways 0

25

Off Topic / Search

« on: April 04, 2005, 09:33:07 AM »

Why is the search on the forum not working? It says it has been taking offline by the administrator, any particular reason for this?

26

The Gene depository / Tie defences

« on: March 03, 2005, 03:15:33 PM »

When a robot ties to you give him a nasty shock with this gene, it will delete his genes B)

Code: [Select]

cond
  *.numties 0 >
  *.robage 2 >
start
  *.tiepres .tienum store
  .delgene .tieloc store
  1 .tieval store
stopYou can also try changing the .delgene to something else, the possibilities are endless, poor tie feeders  :bigginangel: although these genes can be used in reverse as a weapon for tie feeders

27

Bot Tavern / Excalibur

« on: March 01, 2005, 08:08:43 PM »

I created a new bot, Kicks most other bots into touch, leaving them crying on the floor asking there cruel masters not to put them in the ring again

:shoot:  :help:   :help:  :help:  :help:

get it in the bestiary or at the database

MWHAHAAHAHAA!!!!  :bigginangel:

28

F2 bots / Excalibur (F2)(Light)-26.02.05

« on: March 01, 2005, 07:49:43 PM »

Code: [Select]

'Excalibur
'designed for db 2.35
'by Light
'26/2/05

'***********
' * Targeting *
'***********

cond
  *.robage 2 >
  *.eye5 20 <
  *.refaimsx *.myaimsx !=
  *.eye9 *.eye5 > or
  *.eye1 *.eye5 > or
  *.eye8 *.eye5 > or
  *.eye7 *.eye5 > or
start
  *.eye9 *.eye8 add *.eye1 sub *.eye2 sub .aimdx store
stop

cond
  *.refaimsx *.myaimsx !=
  *.robage 5 >
  *.eye5 0 >
start
  *.refxpos *.refypos angle .setaim store
stop

cond
  *.eye9 0 =
  *.eye8 0 =
  *.eye5 5 <
  *.eye2 0 =
  *.eye1 0 =
start
  200 .aimsx store
stop

cond
  *.refaimsx *.myaimsx =
start
  200 .aimsx store
stop

cond
  *.vel *.maxvel <
  *.numties 0 =
  *.robage 2 >
  *.eye5 0 >
  *.fixed 0 =
  *.refaimsx *.myaimsx !=
start
  *.refxpos *.refypos dist 300 sub 5 div .up store
  *.refveldx .dx store
stop

cond
  *.vel 0 =
  *.refaimsx *.myaimsx =
start
  10 .up store
stop

'****************
'* Reproduction *
'****************

cond
  *50 1 =
start
  628 .aimsx store
  0 50 store
stop

cond
  *.nrg 2000 >
  *.body 4000 >
  *.eye5 50 <
start
  628 .aimsx store
  51 .repro store
  1 50 store
stop

'cond
'  *.robage 1 >
'  *.robage 3 <
'  *.nrg 2000 >
'start
'  51 .repro store
'  150 .aimsx store
'stop

cond
  *.robage 0 =
start
  .tie inc
  0 .out1 store
  .shoot .ploc store
  .shoot .vloc store
stop

cond
  *.robage 1 =
start
  .deltie inc
  628 .aimsx store
stop

'********
'* Body *
'********

cond
  *.body 20 >
  *.nrg 500 <
start
  100 .fdbody store
stop

cond
  *.body *.nrg <
  *.nrg 1000 >
  *.robage 2 >
start
  100 .strbody store
stop

'****************
'* Adaptive Armour *
'****************
'1 poison
'2 shell
'3 + 4 slime

cond
  *.in1 *.out1 !=
  *.in1 0 !=
  *.out1 3 <
  *.myeye *.refeye =
start
  *.in1 .out1 store
stop

cond
  *.shflav -1 =
  *.out1 1 !=
start
  1 .out1 store
stop

cond
  *.shflav -6 =
  *.out1 2 !=
start
  2 .out1 store
stop

cond
  *.numties 0 >
  *.out1 3 <
  *.out1 0 >
  *.pain 100 >
  *.genes 28 < or
start
  *.out1 2 add .out1 store
stop

cond
  *.nrg 900 >
  *.poison 1000 <
  *.out1 1 =
  *.out1 3 = or
  *.robage 10 < or
start
  100 .strpoison store
stop

cond
  *.nrg 900 >
  *.shell 190 <
  *.out1 2 =
  *.out1 4 = or
  *.robage 2 < or
start
  200 *.shell sub .mkshell store
stop

cond
  *.nrg 900 >
  *.slime 190 <
  *.out1 3 =
  *.out1 4 = or
start
  200 *.slime sub .mkslime store
stop

cond
  *.numties 0 >
  *.robage 2 >
start
  *.tiepres .tienum store
  .tieval .tieloc store
  3000 .tieval store
  *.tiepres .deltie store
  *.tieval 3000 div .tieloc store
  .sharewaste inc
stop

'**********
'* Shooting *
'**********
cond
  *.waste 100 >
start
  *.waste .shootval store
  -4 .shoot store
stop

cond
  *.shdn 0 <
  *.shdn -2 !=
start
  .backshot inc
stop

'cond
'  *.fixed 0 >
'start
'  .fixpos dec
'stop

'cond
'  *.eye5 20 >
'  *.robage 2 >
'  *.refeye *.myeye !=
'  *.fixed 0 =
'  *. vel 0 >
'start
'  1 .fixpos store
'stop

cond
  *.refaimsx *.myaimsx !=
  *.eye5 5 >
  *.refnrg 1500 <
  *.refshell 50 > or
  *.refpoison 0 = or
start
  -1 .shoot store
  10 .shootval store
stop

cond
  *.refaimsx *.myaimsx !=
  *.eye5 5 >
  *.refnrg 1500 >
  *.refshell 50 < or
  *.refpoison 0 > or
start
  -6 .shoot store
  10 .shootval store
stop

cond
    *.venom 10 <
start
  10 *.venom sub 0 floor 10 ceil .strvenom store
stop

cond
  *.shflav 0 <
  *.shflav -2 !=
start
  *.shang .setaim store
  -3 .shoot store
  *.venom .shootval store
  -2 .venval store
  0 .shflav store
stop

cond
  *.genes 28 !=
  *.sexrepro 0 != or
  *.mrepro 0 != or
start
  0 .repro store
  0 .sexrepro store
  0 .mrepro store
stop

cond
  *.delgene 0 !=
  *.shoot -2 = or
start
  0 .delgene store
  0 .shoot store
stop
end

29

DNA - General / Randomness

« on: February 26, 2005, 11:48:24 AM »

I want to get a random number between say -20 and 20, I thought

20 rnd 40 rnd sub

but this doesn't seem to work, am I being a bit dense?