Messages

16

Simulation Emporium / Re: So I thought I'd try running a King of the Hill sim...

« on: October 25, 2014, 03:38:46 PM »

Multiply4 is out on cycle 91, and all bots except Fruit Flies, Etch and EyeOfTheBeholder are now under threat.

17

Simulation Emporium / Re: So I thought I'd try running a King of the Hill sim...

« on: October 25, 2014, 03:31:46 PM »

The first entrants are:

Fruit Flies v0.21
Etch Mk II
EyeOfTheBeholder
Detonator v1.2
Callidus
Locust
Martian Tank 3
Catapiller
Multiply4
Blue on blue

Plus Alga_Minimalis_Chloroplastus as veggie.

First one out is Blue on blue on cycle 65. Fruit Flies and Etch are way ahead with more than a thousand each, then there's a pack with EyeOfTheBeholder, Detonator, Callidus, Locust and Martian Tank 3. Catapiller and Multiply4 are below 10 units already.

18

Simulation Emporium / Re: So I thought I'd try running a King of the Hill sim...

« on: October 25, 2014, 03:23:11 PM »

It gets (slowly) worse...

19

Simulation Emporium / So I thought I'd try running a King of the Hill sim...

« on: October 25, 2014, 03:19:51 PM »

So I thought I'd try run some rounds of first species to die gets eliminated, with 10 species plus algae, 30 bots per species, 30000 starting energy each and... F1 settings.

I made a huge mistake.

20

Interesting behaviour bots / Miller(IBB)(MacadamiaNuts)-25.10.14

« on: October 25, 2014, 01:55:01 PM »

Just another funky bot that may or may not work.

Code: [Select]

'name: Miller
'description: Turning veggies into yummies!
@
def red 255
def green 227
def blue 0

' DEFAULTS {
cond
start
.shoot .ploc store
-2 .pval store
0 .fixpos store
*.tiepres .tienum store
.tieloc .tieloc store
100 .tielen store
90 .stifftie store
0 .tieval store
*.myeye 14 store
0 .out6 store
99 .out1 store
460 .eye9width store
520 .eye9dir store
460 .eye1width store
-520 .eye1dir store
0 999 store
stop

cond
*.robage 1 =
start
333 .out1 store
stop

cond
*.tiepres 33 =
start
33 .out5 store
stop
' } END DEFAULTS

' VIRUS {
cond
start
*.thisgene .mkvirus store
1 .vshoot store
0 .repro *.totalmyspecies 100 sub 0 floor sgn mult *14 *.myeye sub abs sgn mult store
33 .tie *.myeye 2 sub 0 ceil abs sgn mult store
2 .sharenrg *.myeye 2 sub 0 ceil abs sgn mult store
*13 .delgene *.thisgene *13 sub abs 0 floor mult store
*.thisgene 13 store
stop
' } END VIRUS

' RESOURCES {
cond
*.venom 200 <
start
100 .strvenom store
stop

cond
*.poison 400 <
*.nrg 50 >
start
*.nrg 100 div .strpoison store
stop

cond
*.shell 250 <
*.nrg 500 >
*999 0 >
*.hit 0 >
or
start
100 .mkshell store
stop

cond
start
-2 .venval store
.shoot .vloc store
stop

cond
*.waste 50 >
*.numties 0 >
start
1 .sharewaste store
stop

cond
*.waste 100 >
start
*.waste .shootval store
-4 .shoot store
stop
' } END RESOURCES

' COMMS {
cond
*.in1 333 =
*.in7 0 >
*.out7 0 =
start
*.in6 5 sub .out6 store
*.in7 .out7 store
*.in8 .out8 store
*.in7 972 store
*.in8 973 store
*.in6 5 sub 974 store
stop

cond
*.tiepres 33 =
start
33 .out5 store
*.velup .dn store
*.velsx .dx store
stop

cond
*.tiepres 33 !=
start
0 .out5 store
stop
' } END COMMS

' MOVEMENT {
cond
*972 0 =
*974 0 =
*.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9
add add add add add add add add 0 =
start
*.aim 100 rnd 50 sub add .setaim store
store

cond
*972 0 >
*974 0 >
*972 *.xpos sub abs
*973 *.ypos sub abs add 1000 >
*.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9
add add add add add add add add 0 =
*.tiepres 33 !=
start
*972 *973 angle .setaim store
*974 1 sub 0 floor 974 store
*974 .out6 store
stop

cond
*.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9
add add add add add add add add 0 =
*974 0 =
*.tiepres 33 !=
start
100 rnd 50 sub .aimdx store
*.maxvel .up store
stop

cond
*.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9
add add add add add add add add 0 >
*.tiepres 33 !=
start
215
*.eye6 *.eye7 add *.eye8 add *.eye9 add
*.eye4 *.eye3 add *.eye2 add *.eye1 add sub sgn mult
.aimdx store
*.maxvel 2 div .up store
stop

cond
*.eye5 25 >
*.refeye *.myeye !=
*.refshoot *.myshoot !=
or
start
100 974 store
33 .out5 store
*.refxpos .out7 store
*.refypos .out8 store
*.refxpos 972 store
*.refypos 973 store
*.refxpos *.refypos angle .setaim store
stop

cond
*974 180 >
*.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9
add add add add add add add add 0 =
*.tiepres 33 !=
start
1200 rnd .setaim store
stop
' } END MOVEMENT

' REPRODUCTION {
cond
*.eye5 0 =
*.nrg 2000 *.totalbots *.totalmyspecies div div 500 floor >
*.robage 5 >
start
314 .aimdx store
50 .repro store
stop
' } END REPRODUCTION

' SHOOTING {
cond
*.refeye 1 >
*.refeye *.myeye !=
*.refshoot *.myshoot !=
or
*.refpoison 0 >
*.eye5 0 >
start
24 .shootval store
-6 .shoot store
stop

cond
*.refeye 1 >
*.refeye *.myeye !=
*.refshoot *.myshoot !=
or
*.refpoison 0 =
*.eye5 0 >
start
24 .shootval store
-1 .shoot store
stop

cond
*.eye5 5 >
*.refeye *.myeye !=
*.refshoot *.myshoot !=
or
4 rnd 1 =
start
.aimsx .shoot store
614 .shotval store
stop
' } END SHOOTING

' MILLING {
cond
*.eye5 0 >
*.refeye 2 <
*.refeye *.myeye !=
*.refshoot *.myshoot !=
or
start
33 .tie store
33 .out5 store
stop

cond
*.eye5 0 >
*.in5 33 =
start
33 .tie store
33 .out5 store
stop

cond
*.tiepres 33 =
start
33 .out5 store
33 .tienum store
*.trefxpos *.trefypos angle 614 add .setaim store
75 .sharenrg store
1 .sharewaste store
stop
' } END MILLING

' BODY {
cond
*.nrg *.body 2 mult >
start
100 .strbody store
stop

cond
*.nrg *.body mult <
start
100 .fdbody store
stop
' } END BODY

' PANIC {
cond
*.eye5 5 >
*.refeye *.myeye !=
*.refshoot *.myshoot !=
*.vtimer 1 =
start
16 .vshoot store
stop

cond
*.tiepres 33 !=
start
*.tiepres .deltie 1 rnd mult store
stop

cond
*.in7 0 =
*.refeye *.myeye =
start
160 .aimsx store
stop

cond
*.eye5 80 >
*.tiepres 33 =
start
0 .up store
5 .dn store
stop

cond
*.paralyzed 10 >
*.poisoned 10 > or
*.pwaste 20 > or
start
314 .aimsx store
99 .repro store
stop

cond
*.tiepres 33 =
start
*.aim 400 rnd 200 sub .aimshoot store
-3 .shoot store
stop

cond
*.shflav 0 >
*.shflav -1 =
*.shflav -6 =
or
start
*.shang *.aim add .aimshoot store
-3 .shoot store
100 .shotval store
100 .dx store
stop
' } END PANIC


21

Short bots / Capsule(SB)(SS-ish)(MacadamiaNuts)-25.10.14

« on: October 25, 2014, 01:52:30 PM »

It becomes a Single Store bot one cycle after spawning, but I don't know if that still qualifies for SS league. Took me a long while to code this one.

Code: [Select]

'name: Capsule
'class: Hatching Single Store
'author: Capsule Corp. (MN)
'description: It's magic!

start
9 rnd dup dup dup 10 div swap 12 div add sub 971 add * * swap dup 6 div sub 979 add * store
stop

start
987 971 store
988 972 store
990 973 store
.eye1 974 store
.eye2 975 store
989 976 store
.eye8 977 store
.eye9 978 store
.mkchlr 979 store
.strbody 980 store
.shoot 981 store
.aimsx 982 store
.sharenrg 983 store
.up 984 store
.sexrepro 985 store
.aimdx 986 store
2 987 store
1 988 store
90 989 store
-8 990 store
*.thisgene .delgene store
stop


22

Interesting behaviour bots / Yojimbo(IBB)(MacadamiaNuts)-25.10.14

« on: October 25, 2014, 01:47:03 PM »

Not a very competitive bot, just an attempt to amusing behaviour.

Code: [Select]

'name: Yojimbo
'description: Baka!

@
def red 213
def green 0
def blue 0

cond
start
*.tiepres .tienum store
.sharenrg .tieloc store
1 .tieval store
99 .sharenrg store
99 .shareshell store
99 .shareslime store
*.myeye 14 store
stop

cond
start
0 .in1 store
*.thisgene .mkvirus *.vtimer sgn 1 sub abs mult store
.vshoot *.vtimer 1 sub sgn 1 sub abs mult inc
16000 16000 angle .setaim *14 *.myeye sub sgn abs mult store
10 .up store
*13 .delgene *.thisgene *13 sub abs 0 floor mult store
*.thisgene 13 store
0 .shoot *14 *.myeye sub sgn abs mult store
1 .sharenrg *14 *.myeye sub sgn abs mult store
1000 .tieval *14 *.myeye sub sgn abs mult store
100 .rmchlr store
stop

cond
*.in1 98 =
start
*.in2 *.in3 angle .setaim store
*.in2 .out2 store
*.in3 .out3 store
stop

cond
start
*.totalmyspecies 25 add *971 24 mult add 25 div 971 store
stop

cond
*971 0 =
start
250 971 store
stop

cond
*.robage 4000 mod 500 <
*.xpos 16000 sub abs
*.ypos 16000 sub abs add 4000 >
*.eye5 0 =
start
460 .eye9width store
520 .eye9dir store
460 .eye1width store
-520 .eye1dir store
16000 16000 angle .setaim store
stop

cond
*.eye5 0 =
start
135
*.eye6 *.eye7 add *.eye8 add *.eye9 add
*.eye4 *.eye3 add *.eye2 add *.eye1 add sub sgn mult
.aimdx store
stop

cond
*.eye5 5 >
*.refeye *.myeye !=
start
*.refxpos .out2 store
*.refypos .out3 store
-6 .shoot store
1 .tie store
.sharenrg .vloc store
1 .venval store
10 .mkpoison store
-3 .shoot 1 rnd mult store
*.refxpos *.refypos angle .setaim store
stop

cond
*.eye5 5 >
*.refeye *.myeye !=
4 rnd 1 =
start
.fdbody .shoot store
100 .shotval store
stop

cond
*.refeye *.myeye =
start
314 .aimsx store
0 .tie store
stop

cond
*.eye5 40 <
start
100 rnd 50 sub .aimsx store
*.maxvel .up store
stop

cond
*.eye5 80 >
start
0 .up store
stop

cond
*.nrg 1000 >
*.totalmyspecies *971 <
start
50 .repro store
stop

cond
*.nrg 30 >
*.body 6 mult *.nrg <
start
10 .strbody store
stop

cond
*.body 2 >
*.body 5 mult *.nrg >
start
1 .fdbody store
stop

cond
*.hit 0 >
start
50 .mkshell store
.shoot .ploc store
-2 .pval store
50 .strpoison store
*.shang 614 add .setaim store
stop


23

Veggies / Diatomea(Veggie)(MacadamiaNuts)-25.10.14

« on: October 25, 2014, 08:58:34 AM »

I just wanted diverse looking veggies with shell. Usually ran this with very high species mutation rates for the pretty colors.

Code: [Select]

' Diatomea

cond
*.robage 1 =
*971 0 =
start
100 rnd 971 store
60 rnd 30 sub 972 store
1000 rnd 973 store
32000 rnd 974 store
99 rnd 975 store
stop

cond
*.chlr rnd 1 =
start
*971 .mkchlr store
stop

start
*972 .aimdx store
*.totalmyspecies rnd .setboy store
*.nrg *973 div .mkshell store
stop

cond
*.nrg *974 >
start
*975 .mrepro store
stop
end


24

Veggies / Carnivore_Ivy(Veggie)(F1)(MacadamiaNuts)-25.10.14

« on: October 25, 2014, 08:55:47 AM »

It may be broken in the newer versions, but I don't plan to update it.

Code: [Select]

'name: Carnivore Ivy
'description: Do not eat!

@
def red 213
def green 190
def blue 22

cond
*.robage 2 >
start
*.thisgene .mkvirus *.vtimer 1 sub abs mult store
.vshoot *.vtimer mult inc
942 .setaim *.ypos 20000 sub 0 floor sgn mult store
*13 .delgene *.thisgene *13 sub abs 0 floor mult store
*.thisgene 13 store
stop

cond
*.ypos 12000 >
start
*.tiepres .deltie store
stop

cond
*.ypos 9000 >
start
900 20 rnd add .setaim store
100 .dn store
stop

cond
*.ypos 10000 <
start
.shoot .ploc store
0 .pval store
0 .fixpos store
*.tiepres .tienum store
.tieval .tieloc store
.aimsx .tieloc 10 rnd 9 sub 0 floor mult store
614 .tieval store
914 .setaim store
850 .tielen store
90 .stifftie store
.tie *.eye5 sgn mult inc
50 .sharenrg store
*.tout7 1 sub 0 floor .tout7 store
*.aim *14 add .setaim store
*.nrg 100 div .mkchlr 30000 *.chlr sub sgn 0 floor mult store
*.body 11 sub *.nrg 4 div sub .fdbody *.body 25 sub sgn 0 floor mult store
*.nrg 4 div *.body 11 add sub .strbody *.nrg 200 sub sgn 0 floor mult store
0 -1 store
stop

cond
*.refeye *.myeye =
start
*14 sgn 100 rnd mult -1 mult 14 *.refeye *.myeye sub sgn abs 1 sub abs store
stop

cond
*.tin7 *.tout7 >
start
*.tin7 5 sub 0 floor .tout7 store
stop

cond
*.tout7 0 >
*.nrg 200 >
start
*.nrg 25 div .strpoison store
*.nrg 300 div .mkshell store
stop

cond
*.nrg 200 >
*.body 20 >
start
286 56 rnd add .setaim store
100 .dn store
80 .repro store
stop

cond
*.hit 0 >
start
100 .tout7 store
*.nrg 20 div .mkshell store
*.nrg 5 div .strpoison store
stop

cond
*.refeye *.myeye !=
*.refeye 0 >
*.eye5 10 >
start
10 .shotval store
-6 .shoot store
stop
end


25

F1 bots / EyeOfTheBeholder(F1)(MacadamiaNuts)-25.10.14

« on: October 25, 2014, 08:24:22 AM »

I never really saw it take a big advantage out of eye conspec stealthing, and it's not very resilient to cost spikes, but it does ok.

Code: [Select]

'name: EyeOfTheBeholder
'description: Eye See What You Did There!

cond
*.robage 1 =
start
99 .out8 store
460 .eye9width store
520 .eye9dir store
460 .eye1width store
-520 .eye1dir store
.shoot .ploc store
-2 .pval store
stop

' Lotsa stuff
start
200 rnd 100 sub .aimdx *.eye5 sgn 1 sub abs mult store
80 *.eye6 *.eye7 2 mult add *.eye8 3 mult add *.eye1 add *.eye4 *.eye3 2 mult add *.eye2 3 mult add *.eye9 add sub sgn mult .aimdx store
614 .aimdx *.in8 99 sub sgn abs 1 sub abs mult *.refbody *.body sub sgn 0 floor mult store
*.refveldx .dx *.eye5 sgn mult *.in8 99 sub sgn abs mult store
*.maxvel *.eye5 sgn 1 sub 20 mult add .up *.eye5 85 sub sgn 0 ceil abs mult store
*.eye5 5 div 10 ceil 1 floor .shootval store
-1 5 1 rnd mult sub .shoot *.eye5 30 sub sgn 0 floor mult *.in8 99 sub sgn abs mult *.refage sgn mult store
*.nrg 250 div .strpoison 100 *.poison sub sgn 0 floor mult *.hit mult store
*.nrg 250 div .mkshell 200 *.shell sub sgn 0 floor mult *.hit mult store
*.tiepres .deltie store
*.refxpos *.refypos angle .setaim *.in8 99 sub sgn abs mult *.refnrg sgn mult 15 *.refeye sub sgn 0 floor mult store
*.nrg 5 div .strbody *.nrg 12 div *.body sub sgn 0 floor mult store
*.body 5 div .fdbody *.body 10 mult *.nrg sub sgn 0 floor mult store
*.shang .aimshoot *.shang sgn mult store
*.waste .shootval *.waste 100 sub sgn 0 floor mult store
-4 .shoot *.waste 50 sub sgn 0 floor mult store
50 .repro *.nrg 25000 sub sgn 0 floor mult store
314 .aimdx *.nrg 25000 sub sgn 0 floor mult store
0 .shang store
stop

cond
*.in1 0 >
start
*.in1 .out1 store
*.in2 .out2 store
*.in3 .out3 store
*.in4 .out4 store
*.in5 .out5 store
*.in6 .out6 store
*.in7 .out7 store
stop

' Eeeeeee...
cond
*.refeye 16 >
*.ypos 500 >
*.in8 99 !=
*.robage 1 >
*.refage 1 >
*.genes 5 >
*.nrg 150 >
*.body 10 >
start
*.genes .delgene *.refeye *.myeye sub 0 ceil abs sgn mult store
*.maxvel -1 mult .up store
5 .repro store
stop

' Regrow eyes and mess with other bots
cond
*.nrg 100 >
*.pleas 10 >
start
*.eye5
*.thisgene .mkvirus store
1 .vshoot store
*.thisgene .delgene *.thisgene 5 ceil sgn 1 sub abs mult store
stop

' Disposable eyes
start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop

start
*.eye5
stop


26

Bugs and fixes / Re: Overflow - Maca's insane sim

« on: October 23, 2014, 03:32:43 PM »

Attached.

27

Bugs and fixes / Re: Overflow - Maca's insane sim

« on: October 23, 2014, 05:26:18 AM »

Oh wait --

"C:\Users\Owner\Documents\root\Darwinbots2\Robots\" is not a legit path on my wine install.

I think I loaded Diatomea, EyeOfTheBeholder and Spiderman on a previous version, then added the other ones on a newer one. Maybe it's crashing on the repopulation event.

28

Bugs and fixes / Re: Overflow - Maca's insane sim

« on: October 23, 2014, 05:23:57 AM »

No prob, I'll attach them after work.

Settings were from running a free-for-all sim will all bots set to repopulate. "Quake in ALife" I call it.

29

Announcements / Re: Darwinbots 2.48.23

« on: October 22, 2014, 02:34:50 PM »

Still getting a Runtime error 6 on Linux after a few cycles (granted, on somewhat freaky settings). This is the error window after the crash.

Code: [Select]

Error in ReadConsoleInput 0

  at System.WindowsConsoleDriver.ReadKey (Boolean intercept) [0x00000] in <filename unknown>:0
  at System.ConsoleDriver.ReadKey (Boolean intercept) [0x00000] in <filename unknown>:0
  at System.Console.ReadKey (Boolean intercept) [0x00000] in <filename unknown>:0
  at DarwinbotsCLIM.Program.Main (System.String[] args) [0x00000] in <filename unknown>:0

PS. Thanks a lot for all the bug fixing!

30

Internet Mode Commentary / Re: Who else is online?

« on: October 22, 2014, 05:51:28 AM »

.22 gives me "runtime error 6 overrun" after a while. Do we list somewhere which version is the oldest still compatible with IM and IM stats?