Messages

106

Bugs and fixes / Some Bugs

« on: April 08, 2005, 01:43:24 PM »

Ok example. When im working on bots I lke to have my half working version in a settings file for ease of testing. But if I rename the bot to something else the setting file would still be pointed to the old filename and I would get the message

ATTENZIONE!! FILE DNA NON TROVATO:
PROVARE A SOSITUIRLO O CERCARLO NELLA DIR ROBOTS

But if I start the sim anyway it asks where the dna file is but wont accept it when pointed to it.

107

Old Suggestions Awaiting Programming / Offline FTP thingy

« on: April 08, 2005, 10:53:34 AM »

Id like to suggest an option that saves and introduces random bots to/from your own HD similar to the FTP internet sharing except offline and more reliable :)

 IMO very useful for Evolution sims and should be fairly easy to implement since half the stuff needed is already availiable from the Net sharing.

108

Bugs and fixes / Some Bugs

« on: April 08, 2005, 10:51:35 AM »

Renaming or deleting a Bot used in the current or loaded settings then starting the sim causes the program to ask for the location but doesnt accept it and needs a three finger salute. Fairly serious

The species starting position grid doesnt save properly. Sometimes not at all sometimes one of the corners is misplaced causing wierdness. Annoying for ant bots.

New mutation panel. In the mutation tab the 'Cycles at 16x' button increases the 'Cycles at 1/16th'. Also 1/16th bit only says 'Cycles at'. Manualy typing in the cycles wanted works though.

109

Bot Tavern / My new bot

« on: April 05, 2005, 07:26:59 AM »

Just wanted to make a quick post boasting about my new bot. Check out Callidus and run in fear puny mortals!

110

F1 bots / Callidus (F1)(Shen)-05.04.05

« on: April 05, 2005, 07:23:10 AM »

Code: [Select]

' Callidus by Shen
' Venom dissolves shells
' Uses strong shots with .shootval
' Basic antivirus gene

def Turn 50
def RefSet 51
def VenomTimer 52
def MyTie 53
def Tied 54


' -->> Initialise <--
' *******************

' Gene 1
' - Tie to Parent -
cond
    *.robage 0 =
start
  *.myeye .refeye store
  .tie inc
  .mkshell .vloc store
  999 rnd 1 add .MyTie store
stop

' Gene 2
' - Break Birth Tie -
cond
    *.robage 1 =
start
  .deltie inc
  .Turn inc
stop


' -->> Navigation <<--
' ********************

' Gene 3
' - Left Eye -
cond
    *.eye2 0 >
    *.refeye *.myeye !=
    *.eye5 0 =
start
  *.aim 105 add .setaim store
stop

' Gene 4
' - Right Eye -
cond
    *.eye8 *.eye2 >
    *.refeye *.myeye !=
    *.eye5 0 =
start
  *.aim -105 add .setaim store
stop

' Gene 5
' - Move -
cond
    *.refeye *.myeye !=
    *.eye5 0 =
    *.eye5 0 =
start
  *.maxvel *.vel sub 0 floor .up store
stop

' Gene 6
' - Approach Enemies -
cond
    *.refeye *.myeye !=
    *.eye5 0 >
    *.eye5 40 <
start
  *.refvelup *.maxvel *.vel sub add 0 floor .up store
  *.refveldx .dx store
  *.refxpos *.refypos angle .setaim store
stop

' Gene 7
' - Avoid Friends -
cond
    *.refeye *.myeye =
    *.robage 0 !=
start
  *.aim 200 add .setaim store
stop


' -->> Shots <<--
' ***************

' Gene 7
' - Alga -
cond
    *.eye5 40 >=
    *.refeye 0 =
start
  *.refvelup 0 floor .up store
  *.refveldx .dx store
  *.refxpos *.refypos angle .setaim store
  -1 .shoot store
  10 .shootval store
stop

' Gene 8
' - Bots -
cond
    *.eye5 40 >=
    *.refeye *.myeye !=
    *.refeye 0 !=
    *.VenomTimer 4 <
start
  *.refvelup 0 floor .up store
  *.refveldx .dx store
  *.refxpos *.refypos angle .setaim store
  -6 .shoot store
  30 .shootval store
  .VenomTimer inc
stop

' Gene 9
' - Venom Shot -
cond
    *.eye5 40 >=
    *.refeye *.myeye !=
    *.refeye 0 !=
    *.VenomTimer 4 =
start
  *.refvelup 0 floor .up store
  *.refveldx .dx store
  *.refxpos *.refypos angle .setaim store
  -3 .shoot store
  *.venom .shootval store
  -100 .venval store
  0 .VenomTimer store
stop


' --->> Tie <<---
' ***************

' Gene 10
' - Reset Tie -
cond
    *.Tied 1 >
    *.numties 0 =
start
  0 .Tied store
stop

' Gene 11
' - Drain -
cond
    *.Tied 0 >
start
  *.MyTie .tienum store
  -1 .tieloc store
  -1000 .tieval store
  .Tied inc
stop

' Gene 12
' - Tie -
cond
    *.eye5 40 >=
    *.Tied 2 <
    *.refeye 0 =
start
  *.MyTie .tie store
  1 .Tied store
stop


' -->> Stuff <<--
' ***************

' Gene 13
' - Refeye Timer -
cond
    *.refeye *.myeye =
start
  .RefSet inc
stop

' Gene 14
' - Reset Refeye -
cond
    *.RefSet 25 >
    *.eye5 0 =
start
  0 .refeye store
  0 .RefSet store
stop

' Gene 15
' - Store Body -
cond
    *.body 500 <
    *.nrg 1000 >
    *.robage 50 >
start
  100 .strbody store
stop

' Gene 16
' - Feed Body -
cond
    *.body 250 >
    *.robage 50 < and
    *.body 1000 > or
    *.nrg 500 < or
start
  100 .fdbody store
stop

' Gene 17
' - Shell -
cond
    *.shell 200 <
start
  200 *.shell sub 0 floor 200 ceil .mkshell store
stop

' Gene 18
' - Venom -
cond
    *.venom 10 <
start
  10 *.venom sub 0 floor 10 ceil .strvenom store
stop

' Gene 19
' - Delete Tie -
cond
    *.numties 0 >
    *.tiepres *.MyTie !=
start
  *.tiepres .deltie store
stop

' Gene 20
' - Waste -
cond
    *.waste 100 >
    *.eye5 40 <
start
  1 .backshot store
  -4 .shoot store
  *.waste .shootval store
stop


' -->> Reproduction <<--
' **********************

' Gene 21
' - Repro Turn -
cond
    *.Turn 1 =
start
  *.aim 628 add .setaim store
  .Turn dec
stop

' Gene 22
' - Reproduce -
cond
    *.nrg 2000 >
    *.body 250 >
    *.eye5 50 <
start
  *.aim 628 add .setaim store
  50 .repro store
  .Turn inc
stop


' Gene 23
' - Anti Virus -
' **************
cond
    *.genes 24 >
    *.robage 0 !=
start
  0 .mkvirus store
  0 .vshoot store
  0 .repro store
stop

end

111

Off Topic / New Forum

« on: February 22, 2005, 03:54:35 AM »

Hy Folks. If I could make a few suggestions. Firstly, having so many forums with a relatively small community is counter productive, people rarely check the lesser used forums resulting in unanswered posts. I suggest merging a few of the forums into each other.

What is DarwinBots, DNA Help, Whats This Do could be merged into a Help Forum catch all. The Announcement Forum could be replaced by well administered Sticky topics in the General Forums. Also you need a MB League forum :)

Other than that how are you going to promote this board? The old Website is oooold and hasnt been updated for years. I know it would actually cost money but perhaps a new site is in order? It would definately help get more people interested in DB