Darwinbots Forum

Bots and Simulations => Bestiary => Veggies => Topic started by: MacadamiaNuts on October 25, 2014, 08:55:47 AM

Title: Carnivore_Ivy(Veggie)(F1)(MacadamiaNuts)-25.10.14
Post by: MacadamiaNuts on October 25, 2014, 08:55:47 AM
It may be broken in the newer versions, but I don't plan to update it.

Code: [Select]
'name: Carnivore Ivy
'description: Do not eat!

@
def red 213
def green 190
def blue 22

cond
*.robage 2 >
start
*.thisgene .mkvirus *.vtimer 1 sub abs mult store
.vshoot *.vtimer mult inc
942 .setaim *.ypos 20000 sub 0 floor sgn mult store
*13 .delgene *.thisgene *13 sub abs 0 floor mult store
*.thisgene 13 store
stop

cond
*.ypos 12000 >
start
*.tiepres .deltie store
stop

cond
*.ypos 9000 >
start
900 20 rnd add .setaim store
100 .dn store
stop

cond
*.ypos 10000 <
start
.shoot .ploc store
0 .pval store
0 .fixpos store
*.tiepres .tienum store
.tieval .tieloc store
.aimsx .tieloc 10 rnd 9 sub 0 floor mult store
614 .tieval store
914 .setaim store
850 .tielen store
90 .stifftie store
.tie *.eye5 sgn mult inc
50 .sharenrg store
*.tout7 1 sub 0 floor .tout7 store
*.aim *14 add .setaim store
*.nrg 100 div .mkchlr 30000 *.chlr sub sgn 0 floor mult store
*.body 11 sub *.nrg 4 div sub .fdbody *.body 25 sub sgn 0 floor mult store
*.nrg 4 div *.body 11 add sub .strbody *.nrg 200 sub sgn 0 floor mult store
0 -1 store
stop

cond
*.refeye *.myeye =
start
*14 sgn 100 rnd mult -1 mult 14 *.refeye *.myeye sub sgn abs 1 sub abs store
stop

cond
*.tin7 *.tout7 >
start
*.tin7 5 sub 0 floor .tout7 store
stop

cond
*.tout7 0 >
*.nrg 200 >
start
*.nrg 25 div .strpoison store
*.nrg 300 div .mkshell store
stop

cond
*.nrg 200 >
*.body 20 >
start
286 56 rnd add .setaim store
100 .dn store
80 .repro store
stop

cond
*.hit 0 >
start
100 .tout7 store
*.nrg 20 div .mkshell store
*.nrg 5 div .strpoison store
stop

cond
*.refeye *.myeye !=
*.refeye 0 >
*.eye5 10 >
start
10 .shotval store
-6 .shoot store
stop
end
Title: Re: Carnivore_Ivy(Veggie)(F1)(MacadamiaNuts)-25.10.14
Post by: spike43884 on October 25, 2014, 04:02:49 PM
Can you release more veggies...
Heres one idea for a special caniverous veggie (if possible)
No eyes but fires ties completely randomly for a extra feeding source, and unlucky bots get eaten.
Title: Re: Carnivore_Ivy(Veggie)(F1)(MacadamiaNuts)-25.10.14
Post by: Botsareus on October 26, 2014, 11:09:52 AM
Maca, not much has changed for the vegys, the only big one was the size change. You should consider it. It is my last internal change.