Show Posts

This section allows you to view all posts made by this member. Note that you can only see posts made in areas you currently have access to.


Topics - Jez

Pages: 1 2 [3] 4 5 ... 17
31
F1 bots / Ninja1 bot (F1)(vir)(Henk)-05.11.04
« on: February 02, 2007, 05:42:05 PM »
Code: [Select]
'Topic: New Bots
' Ninja 1 bot (F1)
' by Henk
' uses delgene-shot-weapon
' is immune to delgene virus
' most of the time

' Movement
cond
*.refeye *.myeye =
*.robage 3 >
start
-300 .aimsx store
stop

cond
*.eye1 *.eye5 >
*.eye1 *.eye9 >
*.robage 3 >
start
130 .aimsx store
-1 .dx store
stop

cond
*.eye9 *.eye5 >
*.eye9 *.eye1 >
*.robage 3 >
start
-130 .aimsx store
1 .dx store
stop

cond
*.refeye *.myeye !=
*.numties 0 =
*.robage 3 >
start
*.maxvel *.vel sub 2 div .up store
*.eye4 *.eye6 sub .aimsx store
stop

cond
*.hitdn 0 !=
*.nrg 4800 <
start
-628 .aimsx store
stop

' Reproduction
' ****************

cond
*60 0 >
start
471 .aimsx store
0 60 store
stop

cond
*.nrg 3500 >
*.robage 40 >
*.numties 0 =
start
-471 .aimsx store
50 .repro store
60 inc
stop

' INITIALISATION
' *********************
cond
*.robage 0 =
start
.tie inc
10 .dn store
1 .readtie store
.aimdx .ploc store
stop

cond
*.robage 1 =
start
.deltie inc
-314 .aimsx store
stop

' SPECIAL COMBAT GENES
' ***********************************

cond
*.fixed 0 !=
start
0 .fixpos store
stop

' activate gene scanner
' target is considered beaten when the number of genes is less
' then 10
cond
*.eye5 20 >
*.refeye *.myeye !=
start
.genes .memloc store
stop

' evil attack
cond
*.myeye *.refeye !=
*.refup 0 >
*.eye5 30 >
*.memval 10 >
start
.delgene .shoot store
*.memval 1 sub rnd 1 add .shootval store
stop

cond
*.myeye *.refeye !=
*.refup 0 >
*.eye5 30 >
*.memval 10 <
start
-1 .shoot store
stop

cond
*.myeye *.refeye !=
*.refup 0 =
*.eye5 30 >
start
1 .tie store
stop

cond
*.numties 0 >
*.trefeye *.myeye !=
*.trefup 0 =
start
1 .tienum store
-1 .tieloc store
-1000 .tieval store
10 .strbody store
-6 .shoot store
stop

cond
*.numties 0 >
*.trefup 0 >
start
1 .deltie store
stop

cond
*.numties 0 >
*.trefeye *.myeye !=
*.trefup 0 >
start
100 .sharenrg store
1 .fixang store
stop

cond
*.tiepres 1 !=
*.numties 0 >
start
*.tiepres .tienum store
.tieval .tieloc store
1000 .tieval store
stop

cond
*.slime 35 <
*.nrg 1000 >
start
40 *.slime sub .mkslime store
stop

cond
*.waste 25 >
start
.backshot inc
-4 .shoot store
*.waste .shootval store
stop

cond
*.shdn 0 <
*.shdn -2 !=
start
.backshot inc
-6 .shoot store
stop

' right reaction gene
cond
*.shdx -1 =
start
-314 .aimsx store
-1 .shoot store
stop

' Left reaction gene
cond
*.shsx -1 =
start
314 .aimsx store
-1 .shoot store
stop

' poison
cond
*.nrg 3000 >
*.poison 50 <
start
100 *.poison sub .strpoison store
stop

' delgene immune system. will cost energy, but will save my life
' only works when the virus is inserted before this gene
cond
*.genes 25 >
start
0 .delgene store
stop

' END
' ******
end

32
F1 bots / Mutchy 1 (F1)(PY mod)-31.08.04
« on: February 02, 2007, 05:41:31 PM »
Code: [Select]
'Topic: Ideas 
'Mutchy original mod by PY
'*****Movement Genes!*****

cond
*.eye4 *.eye5 >
start
-20 .aimdx store
stop

cond
*.eye6 *.eye5 >
start
20 .aimdx store
stop

cond
*.eye5 0 >
*.refeye *.myeye =
start
200 .aimdx store
stop

cond
*.vel 30 <
start
2 .up store
stop

'*****feeding*****

'cond
'*.numties 1 =
'start
'20 .tienum store
'0 .fixang store
'100 .fixlen store
'0 50 store
'stop

cond
*.numties 0 =
start
0 66 store
stop

cond
*.eye5 30 >
*.eye5 77 !=
*.refeye *.myeye !=
start
1 .tie store
-1 .tieloc store
-1000 .tieval store
1 .tienum store
66 inc
stop


'*****Reproduction genes!*****
cond
*.nrg 2500 >
start
50 .repro store
stop

cond
*.robage 0 =
start
.tie inc
stop

cond
*.robage 1 =
start
.deltie inc
stop

'*****Attempt at new venom genes!*****

'***Attack enemy Tie gene***

cond
*.venom 20 <
start
10 .strvenom store
stop

'cond
'*.numties 0 >
'*.refeye *.myeye !=
'*.refeye 0 %=
'start
'*.tiepres .tienum store
'20 .tieval store
'.repro .vloc store
'1 .venval store
'-3 .tieloc store
'stop

cond
*.tiepres 0 !=
*.numties 0 >
'*.refeye *.myeye !=
'*.refeye 1 !>
'activate the *66 0 = line to enable proper tie feeding
'and to disable venom attacks on veggies.
'*66 0 =
start
*.tiepres .tienum store
20 .tieval store
.repro .vloc store
1 .venval store
-3 .tieloc store
stop

'*****Slime and Other Stuff*****
cond
*.slime 100 <
start
50 .mkslime store
stop
end

33
F1 bots / Mutchy (F1)(Mutchy)-31.08.04
« on: February 02, 2007, 05:40:59 PM »
Code: [Select]
'Topic: Ideas 
'Mutchy
'*****Movement Genes!*****

cond
*.eye4 *.eye5 >
start
-20 .aimdx store
stop

cond
*.eye6 *.eye5 >
start
20 .aimdx store
stop

cond
*.eye5 0 >
*.refeye *.myeye =
start
200 .aimdx store
stop

cond
*.vel 30 <
start
2 .up store
stop

*****feeding*****

'cond
'*.numties 1 =
'start
'20 .tienum store
'0 .fixang store
'100 .fixlen store
'0 50 store
'stop

cond
*.eye5 30 >
*.eye5 77 !=
*.refeye *.myeye !=
start
1 .tie store
-1 .tieloc store
-1000 .tieval store
1 .tienum store
stop

*****Reproduction genes!*****
cond
*.nrg 2500 >
start
50 .repro store
stop

cond
*.robage 0 =
start
.tie inc
stop

cond
*.robage 1 =
start
.deltie inc
stop

*****Attempt at new venom genes!*****

***Attack enemy Tie gene***

cond
*.venom 20 <
start
10 .strvenom store
stop

cond
*.numties 0 >
*.refeye *.myeye !=
*.refeye 0 %=
start
*.tiepres .tienum store
20 .tieval store
.repro .vloc store
1 .venval store
-3 .tieloc store
stop

cond
*.tiepres 0
*.numties 0 >
*.refeye *.myeye !=
*.refeye 0 %=
start
*.tiepres .tienum store
20 .tieval store
.repro .vloc store
1 .venval store
-3 .tieloc store
stop

*****Slime and Other Stuff*****
cond
*.slime 100 <
start
50 .mkslime store
stop
end

34
F1 bots / James 4I (F1)(Mutchymod)-07.08.04
« on: February 02, 2007, 05:31:13 PM »
Code: [Select]
'Topic: New Bots 
'James 4I
'Made by Jez
'Moded by Mutchy

cond
*.eye5 *.eye5 =
*234 0 !=
start
0 234 store
stop

cond
*99 *.refeye =
*.myshoot *.refshoot =
*.myup *.refup =
*.mydx *.refdx =
*.myaimdx *.refaimdx =
*.myties *.refties =
*.eye5 0 >
start
1 234 store
stop

cond
*.robage 0 =
start
*.myeye 99 store
1 1000 rnd 567 store
*567 .tie store
stop

cond
*.robage 1 =
*.numties 0 >
start
*.tiepres .deltie store
stop

cond
*.nrg 2000 >
*.eye5 0 =
start
40 .repro store
stop

cond
*.eye1 *.eye5 >
start
mult 104
stop

cond
*.eye9 *.eye5 >
start
mult -104
stop

cond
*.eye3 *.eye5 >
start
mult 52
stop

cond
*.eye7 *.eye5 >
start
mult -52
stop

cond
*.refeye 0 !=
*.numties 0 =
*.eye5 0 >
*234 1 !=
start
*.nrg 99 div .up store
stop

cond
*.refeye 0 =
'*.numties 0 =
*.eye5 0 >
*234 1 !=
start
*.nrg 99 div 1 add .up store
stop

cond
*.eye5 0 =
start
mult 104
stop

cond
*234 1 =
*.eye5 0 >
start
mult 208
stop

cond
start
.aimdx store
100 *.slime sub .mkslime store
50 *.poison sub .mkpoison store
mult 0
stop

cond
*.refpoison 0 =
*.refeye 0 !=
*.eye5 30 >
*234 1 !=
start
-1 .shoot store
*567 .tie store
stop

cond
*.refpoison 0 =
*.refeye 0 =
*.eye5 30 >
*234 1 !=
start
'-1 .shoot store
*567 .tie store
stop

cond
*.refpoison 0 >
*.eye5 30 >
*234 1 !=
start
505 .shoot store
0 .shootval store
*567 .tie store
stop

cond
*.numties 0 >
start
*.tiepres .tienum store
-1 .tieloc store
-1000 .tieval store
stop

cond
*.eye5 *.eye5 =
*.pain 900 >
start
*.tiepres .deltie store
stop

cond
*.eye9 *.eye1 >
start
104 .aimdx store
stop

cond
*.eye1 *.eye9 >
start
-104 .aimdx store
stop

' Friend close in front, avoid him
cond
*.eye5 50 >
*.refeye *99 =
start
30 .dx store 250 .aimdx store
stop

'gene run away from friends
cond
*.refeye *99 =
start
-562 .aimdx store
stop

cond
*.eye5 *.eye5 =
*.pain 120 >
*.shup -1 !=
*.shup -3 !=
*.shell 50 <
start
100 *.shell sub .mkshell store
mult
628
stop

'Tie to an enemy
'********************
cond
*.eye5 50 >
*.eye6 *.eye4 %=
*.refeye *99 !=
*.robage 0 >
start
800 rnd 100 add 51 store
*51 .tie store
*51 .readtie store
mult mult 0 0
52 inc
stop

cond
*.trefeye *.99 !=
start
*912 .deltie store
stop

cond
*.body 20 <
*.nrg 1000 >
start
100 .strbody store
stop

cond
*.nrg 2500 >
*.body 800 <
start
100 .strbody store
stop

cond
*.nrg 5000 >
start
100 .strbody store
stop

cond
*.body 20 >
*.nrg 1000 <
start
100 .fdbody store
stop

cond
*.body 1000 >
*.robage 10 <
start
50 .fdbody store
stop

cond
*.body 200 >
start
100 .fdbody store
stop


cond
*.fixed 1 =
start
0 .fixpos store
stop

' Freeze enemy robots
cond
*.eye5 30 >
*.refeye *.myeye !=
*.reffixed 0 =
*.refeye 0 !=
start
216 .shoot store
0 .shootval store
stop
end

35
F1 bots / Efficient Bot (F1)(Shen)-01.09.04
« on: February 02, 2007, 05:30:35 PM »
Code: [Select]
' Topic: Proposed new league table
'Shen
' An Efficient Bot


' - Spin -
cond
*.refeye *.myeye =
start
100 .aimdx store
666 .deltie store
stop

' - Move -
cond
*.refeye *.myeye !=
start
*.eye6 *.eye4 sub .aimdx store
*.aimdx 5 div .dx store
*.maxvel *.vel sub .up store
stop

' - Tie -
cond
*.eye5 35 >
*.refeye *.myeye !=
start
-1 .shoot store
666 .tie store
stop

' - Drain Nrg -
cond
*.numties 0 >
start
666 .tienum store
.tieloc dec
-1000 .tieval store
stop

' - Feed Body -
cond
*.body 300 >
start
100 .fdbody store
stop

' - Slime -
cond
*.slime 95 <
start
100 .mkslime store
stop

' - Reproduce -
cond
*.nrg 1500 >
*.eye5 30 <
start
50 .repro store
stop

end

36
F1 bots / Combattente de Legame (F1)(Mutchy)-17.07.04
« on: February 02, 2007, 05:30:01 PM »
Code: [Select]
'Topic: F1, F2 and Short-Bots league tables 
'Mutchy

'initialize
cond
*.robage 0 =
start
50 rnd 55 store
14 56 store
1 .tie store
stop

cond
*.robage 1 =
start
1 .deltie store
stop

cond
*.eye2 *.eye8 !=
start
*.eye2 *.eye8 sub .aimsx store
stop

cond
*.eye4 *.eye6 !=
start
*.eye4 *.eye6 sub 2 div .aimsx store
stop

cond
*.refeye *56 =
start
200 .aimsx store
stop

cond
*.vel 40 <
*.refeye *.myeye
start
40 *.vel sub .up store
stop

cond
*.nrg 4000 >
*.eye5 30 <
start
50 .repro store
stop

cond
*.eye5 30 >
*.refeye *.myeye
*.eye5 77 !=
*.eye4 *.eye6 =
start
*55 .tie store
*55 .readtie store
stop

cond
*.numties 0 >
start
-1 .tieloc store
-1000 .tieval store
*55 .tienum store
stop

cond
*.trefeye *56 =
start
*55 .deltie store
stop

cond
*.slime 90 <
start
100 .mkslime store
stop

cond
*.eye5 50 >
start
-1 .shoot store
stop

gene 2
cond
*.eye1 *.eye5 >
start
mult -104
stop

'gene far right eye
cond
*.eye9 *.eye5 >
start
mult 104
stop

'gene middle left eye
cond
*.eye3 *.eye5 >
start
mult -52
stop

'gene middle right eye
cond
*.eye7 *.eye5 >
start
mult 52
stop

'gene fire!
cond
*.eye5 40 >
*.refeye *.myeye !=
start
-1 .shoot store
stop

'gene im not lazy?
cond
*.vel 30 <
*.refeye *.myeye !=
start
30 *.vel sub .up store
stop

'gene makin babies
cond
*.nrg 5000 >
start
50 .repro store
stop

cond
*.robage 0 =
start
1 .tie store
stop

'gene no tie
cond
*.numties 0 !=
'*.robage 1 =
start
1 .deltie store
stop

'gene run away from friends
cond
*.refeye *.myeye =
start
mult -90
stop

'gene mult
cond
start
.aimdx store
stop

end

37
Interesting behaviour bots / Gang bot (IB)(K0zm0)-01.10.04
« on: February 02, 2007, 05:29:01 PM »
'Topic: Interesting Group Behaviour
'K0zm0
'
'Gang Bot
'Made by k0zm0
'1.oct.2004
'Made for DBv2.33beta

cond
*.out1 0 =
start
*.xpos .out1 store
stop

cond
*.out2 0 =
start
*.ypos .out2 store
stop

cond
*.refeye *.myeye !=
*.eye5 0 >
*.kills 0 >
start
*.eye4 *.eye6 sub .aimsx store
stop

cond
*.nrg 6000 >
start
50 .repro store
stop

cond
*.nrg 500 <
start
6000 rnd 6000 rnd angle .setaim store
stop

cond
*.eye5 30 >
*.refeye *.myeye !=
start
-1 .shoot store
stop

cond
*.nrg 2000 >
*.eye5 0 >
*.refeye *.myeye =
*.out1 *.in1 !=
start
*.in1 .out1 store
stop

cond
*.nrg 2000 >
*.eye5 0 >
*.refeye *.myeye =
*.out2 *.in2 !=
start
*.in2 .out2 store
stop

cond
*.vel 10 <
start
1 .up store
stop

cond
*.out1 *.xpos !%=
*.out2 *.ypos !%=
start
*.out1 *.out2 angle .setaim store
stop

cond
*.eye5 0 >
*.refeye *.myeye =
*.out1 *.in1 =
*.out2 *.in2 =
*.out1 *.xpos %=
*.out2 *.ypos %=
start
*.refaim .setaim store
stop
end

38
Veggies / The Social Vegtable (Veg)(Tragos)-03.10.04
« on: February 02, 2007, 05:27:44 PM »
'Topic: Vegetable Bot
'Tragos (posted as guest)
'The social vegetable

'reproduction
'replicate
cond
*.nrg 1000 >
*.eye5 30 <
*.numties 4 <
start
80 .repro store
stop

'spore formation
cond
*.nrg 5000 >
*.eye5 30 <
*.numties 3 >
start
1 .mrepro store
stop

‘tie to parent
cond
*.robage 10 =
start
.tie inc
100 .tielen store
378 .fixang store
stop

'moving to make more bots
cond
*.nrg 1000 >
*20 100 <
start
300 .aimdx store
20 inc
stop

cond
*.numties 0 !=
start
.sharenrg inc
stop

cond
*.numties 4 <
*.nrg 100 <
start
.tie inc
stop

cond
*.numties 0 >
start
.sharewaste inc
stop
end

39
Interesting behaviour bots / CFB (IB)(K0zm0)-18.09.04
« on: February 02, 2007, 05:24:40 PM »
'Topic: Interesting Group Behaviour
'CFB
'Made by k0zm0
'18.aug.2004
'Made for DBv2.32
cond
*.eye5 0 >
*.refeye *.myeye !=
*.refeye 0 !=
start
1 .out2 store
stop

cond
*.eye5 0 >
*.refeye *.myeye !=
*.refshoot 0 >
*.reftie 0 =
start
1 .out1 store
stop

cond
*.eye5 0 >
*.refeye *.myeye !=
*.refshoot 0 =
*.reftie 0 >
start
2 .out1 store
stop


cond
*.eye5 0 >
*.refeye *.myeye !=
*.refshoot 0 >
*.reftie 0 >
start
3 .out1 store
stop


cond
*.myeye *.refeye =
start
0 .out1 store
0 .out2 store
stop

cond
*.eye5 0 >
*.refeye *.myeye =
*.in1 1 =
start
1 .out1 store
stop

cond
*.eye5 0 >
*.refeye *.myeye =
*.in1 2 =
start
2 .out1 store
stop

cond
*.out1 1 =
start
100 *.shell sub .mkshell store
stop

cond
*.out1 2 =
start
100 *.slime sub .mkslime store
stop

cond
*.out1 3 =
start
100 *.shell sub .mkshell store
100 *.slime sub .mkslime store
stop

cond
*.eye5 31 <
start
100 .aimdx store
stop

cond
*.in2 0 =
*.eye5 0 >
*.refeye *.myeye =
start
628 rnd .aimdx store
stop

cond
*.in2 1 =
*.eye5 0 >
*.refeye *.myeye =
start
1 .out2 store
*.refaim .setaim .aimdx store
stop

cond
*.eye5 25 >
*.refeye 0 !=
*.refeye *.myeye !=
start
-6 .shoot store
stop

cond
*.eye5 26 >
*.refeye 0 =
start
-1 .shoot store
stop

cond
*.eye5 0 >
*.nrg 6000 >
start
628 rnd .aimsx store
50 .repro store
stop

cond
*.eye5 0 !=
*.refeye *.myeye !=
*.nrg 7000 >
start
-2 .shoot store
stop
end

40
The Starting Gate / Tag your bots!!
« on: February 01, 2007, 08:14:00 PM »
Please read these instructions.  If you don't follow the rules, you make the moderators' lives harder.

All bots posted here will get put into the Bestiary and relevant leagues (if needed), please don't edit your post after it is moved. Rerelease it as a V1.1 bot by all means but changing the code after it is moved can cause problems that I don't really want to fix! If your bot hasn't been moved yet (it's still in the starting gate), please edit the first post in the thread to be the current version of the code, so that people surfing through the beastiary can easily download the "proper" version.  If you want to preserve the original code as well, then do:

blah blah blah

[Your current code]

blah blah blah

[Your original code]

And please clearly mark which is which, preferably with brightly colored text.

Also, if you post a (previously unreleased) working bot on the forum, do me a favour and post it here as well. The Bestiary is a fairly good history of bot evolution, help me help you keep it accurate!!

(If it means you have to post your bot code twice don't worry, it's better than losing the bot you posted..)

Please use this format for posting bots:
Your bot name (Most descriptive league/other tag)(Your screen name)-Date in European Format (DD.MM.YY)

For example:

Animal Minimals (SB)(Numsgil)-15.05.05

Most descriptive league should be the most limiting league your bot could compete for.  If you happen to make a multibot, single store, that doesn't use ties or viruses (that is, something that could qualify for every league), please put each league in its own parenthetical group.  ie: (MB)(SS)(F2).  Note that since it's a single store it does qualify as a short bot anyway.  Just list the leagues that don't necessarily imply each other.

Only list F1 as the league name if it doesn't fit in any other league.  All bots that are eligible for other leagues will automatically be eligible for F1.  SS bots are likewise automatically eligible for the SB league, so you don't have to specify that.

Here are the possible leagues:

SS - Single Store (1S is also acceptable)
SB - Short bot (1G - 6G is also acceptable, where you count the number of genes in your bot)
MB - Multibot
F2 - Bots that don't use ties or viruses.
F1 - Free for all.  Only use this tag if nothing else fits.

If your bot isn't for any of the leagues, use some other tag.  Like evobot for something that's been mutated, or something that's for mutating.  Use whatever tag you like, there aren't as many rules here.  Preferably something to indicate which forum it goes in.

Last, it's extremely helpful if you can attach a .txt of your bot to the end of the first post.  However, be 100% sure that it represents the bot in that first post.  If you edit the code for the bot in that first post, and the .txt attachment isn't up to date, it will cause confusion.  If you're not sure you can remember to keep things up to date like this, be safe and don't include a .txt attachment.  You can't name the .txt the same as the topic title for some reason (parenthesis are converted to _ for some reason), so just do the bot name.

If your robot does not fit in the post you can attach it as a .txt file. Please specify clearly in the post that the robot does not fit!

42
F2 bots / Borg (F2)(Zelos)-08.10.04
« on: January 31, 2007, 01:10:03 PM »
Code: [Select]
'Topic: the nex one zelos has made his first bot
'Zelos

' Borg
'This is my first bot, im gonna mke it hell better
'
'
'
def type 50
'
'

'

'Move Bot
cond
*.eye5 40 <
*.vel > 25
start
5 .up store
stop

'Move Bot when close to food
cond
*.eye5 30 >
*.vel > 10
*.refeye *.myeye !=
start
0,5 .up store
stop

'gene run away from friends
cond
*.refeye *.myeye =
*.eye5 0 >
start
-628 .aimdx store
stop

'gene run away from food whti less then 1000 energy
cond
*.refeye 0 =
*.eye5 0 >
*.refnrg 1000 <
start
-628 .aimdx store
20 .up store
stop

'Shoot Food
cond
*.eye5 40 >
*.refnrg 1000 >
*.hfh 0 =
*.in1 *.out1 =
*.refeye *.myeye !=
start
-6 .shoot store
stop

'Look Left
cond
*.eye1 *.eye5 >
start
-100 .aimdx store
stop

'Look Look Right
cond
*.eye9 *.eye5 >
start
100 .aimdx store
stop

'Reproduce
cond
*.nrg 6000 >
*.eye5 0 =
start
314 .aimdx store
40 .repro store
stop

end

43
F2 bots / Anubis Canis v2.0 (F2)(Firegem9)-08.09.04
« on: January 31, 2007, 01:08:31 PM »
Code: [Select]
'Topic: New Bots
'Firegem9
'anubis_canis 2.0
'***************

cond
*.aimdx *.aimdx !=
start
*.aimdx .aimdx store
stop

cond
*.nrg 2000 >
start
50 .repro store
stop

cond
*.body 200 >
start
100 .fdbody
stop

cond
*.robage 0 =
start
2 .tie store
stop

cond
*.refaimdx *.myaimdx !=
start
*.maxvel *.vel sub 2 div .up store
stop

'Brakes
'************
cond
*.eye5 45 >
*.refaimdx *.myaimdx !=
*.refaimdx 1 =
start
*.vel 2 div -1 mult .up store
stop
'*************
cond
*.eye5 40 >
*.refaimdx *.myaimdx !=
start
-6 .shoot store
stop

cond
*.eye2 0 >
start
100 .aimsx store
stop

cond
*.eye8 0 >
start
100 .aimdx store
stop

cond
*.eye4 0 >
start
50 .aimsx store
stop

cond
*.eye6 0 >
start
50 .aimdx store
stop

cond
*.refaimdx *.myaimdx =
start
239 .aimdx store
stop

cond
*.robage 1 =
start
2 .deltie store
stop

cond
*.waste 500 >
start
500 .shootval store
1 .backshot store
-4 .shoot store
stop

cond
*.fixed 0 !=
start
0 .fixpos store
stop

'venomous
'************
cond
*.nrg 1000 >
*.venom 150 <
start
5 .strvenom store
stop

cond
*.eye5 50 >
*.refaimdx 1 !=
*.refaimdx *.myaimdx !=
*.venom 50 >
start
50 .shootval store
-3 .shoot store
.refeye .vloc store
*.refeye .venval store
stop


end

44
F2 bots / Animalzar Cazador (5G)(F2)(Desesperate)-17.07.04
« on: January 31, 2007, 01:07:28 PM »
Code: [Select]
'Topic: CRITICAL POINT 
'Desesperate

'Animalzar
'Cazador
'Este cazador es mi segundo bot, asi que no esperen que sea perfecto
'Por Desesperate

'el primer gen especifica que se mueva para arriba
'el segundo especifica que si detecta algo, que dispare
'el tercero que se reproduzca
'el cuarto que se mueva si esta parado
'el quinto especifica que si le dan por atras se vuelva y dispare

cond
*.nrg >500
start
5 .up store
stop
cond
*.eye5
0
>
start
-1 .shoot store
stop
cond
*.nrg 3000
>
start
40 .repro store
1256 .aimsx store
stop
cond
*.up 1 <
start
5 .up store
stop
cond
*.hitup 1 =
start
1256 .aimsx store
-1 .shoot store
stop
end

45
F2 bots / Anubis Canis 1.1 (F2)(Firegem9)-29.07.04
« on: January 31, 2007, 01:06:30 PM »
Code: [Select]
'Topic: New Bots 
'Firegem9

'anubis_canis 1.1 ( a little different)
'My modified robo : )
'***************

cond
*.nrg 2000 >
start
50 .repro store
stop

cond
*.robage 0 =
start
2 .tie store
stop

cond
*.refaimdx *.myaimdx !=
start
*.maxvel *.vel sub 2 div .up store
stop

'Brakes
'************
cond
*.eye5 45 >
*.refaimdx *.myaimdx !=
*.refaimdx 1 =
start
*.vel 2 div -1 mult .up store
stop
'*************
cond
*.eye5 40 >
*.refaimdx *.myaimdx !=
start
-6 .shoot store
stop

cond
*.eye2 0 >
start
100 .aimsx store
stop

cond
*.eye8 0 >
start
100 .aimdx store
stop

cond
*.eye4 0 >
start
50 .aimsx store
stop

cond
*.eye6 0 >
start
50 .aimdx store
stop

cond
*.refaimdx *.myaimdx =
start
239 .aimdx store
stop

cond
*.robage 1 =
start
2 .deltie store
stop

cond
*waste 500 >
start
500 .shootval store
1 .backshot store
-4 .shoot store
stop

cond
*.eye5 30 >
*.refaimdx 1 !=
*.refaimdx *.myaimdx !=
*.nrg 2000 >
start
100 .strvenom
100 .shootval
-3 .shoot store
stop

end

Pages: 1 2 [3] 4 5 ... 17