Messages

91

Bot Tavern / Rabidus v1.1 (F1)(Googlyeyesultra)-15.07.07

« on: July 15, 2007, 08:53:58 PM »

I've cobbled together a little buggy cooperation code, but it honestly makes the bot buggier. If you want to see it, just copy and paste it into rabidus, replacing the section labeled "Spread out later".

Code: [Select]

'Spread out later
cond
*.eye5 0 !=
*997 *998 =
*.robage 20 >=
*.numties 0 =
*.robage 30 sub *.out3 >
*.out4 *.out5 dist 0 = or
start
*.refxpos *.refypos angle 628 add .setaim store
*.eye5 2 div .up store
stop

'Communicate locations
cond
*.eye5 0 >
*997 *998 !=
start
*.robage .out3 store
*.refxpos .out4 store
*.refypos .out5 store
*.robage 989 store
stop

'Recieve locations
cond
*.eye5 0 >
*998 *997 =
*.in4 0 !=
*.in5 0 !=
*.in4 *.out4 !=
*.in5 *.out5 !=
start
*.in3 .out3 store
*.in4 .out4 store
*.in5 .out5 store
*.robage 989 store
stop

'Travel to location
cond
*.out4 0 !=
*.out5 0 !=
*998 *997 =
*.robage 30 sub *.out3 <
*.numties 0 =
*.out4 *.out5 add *.refxpos *.refypos add !=
start
*.out4 *.out5 angle .setaim store
*.out4 *.out5 dist 2 div *.velup sub .up store
*.veldx -1 mult .dx store
stop

92

F1 bots / Rabidus (F1)(Vir)(Googlyeyesultra)-01.07.07

« on: July 15, 2007, 07:30:10 PM »

Just enter version 1.1. This one gets stomped by caliduss's leaching (which I've corrected). Hopefully I can get a better release in a little while, though.

93

Bot Tavern / Rabidus v1.1 (F1)(Googlyeyesultra)-15.07.07

« on: July 15, 2007, 08:17:15 AM »

Dopplepost!

I figured out why Aura vs Rabidus takes so long. Apparently, Aura has no eye commands, no shoot commands, or really any other refvar that I could use to distinguish it from a veggie. So, my bot assumes it's a harmless little plant and doesn't use things like venom on it.

Well, at least I made my conspec a bit more secure. Now it adds 3 values instead of two (I'll wait until I can get a fairly different version before I post a v. 1.2)

94

Bot Tavern / Rabidus v1.1 (F1)(Googlyeyesultra)-15.07.07

« on: July 15, 2007, 06:09:53 AM »

I tried some very simple code (just a little modification of the swarming code in the wiki), but they tend to get close enough together so that they block each other's vision. I'm thinking about transmitting coordinates of food and enemy bots through .out4 and .out5, so that anything without a target would look for coordinates in other nearby Rabiduses (Rabidii?). I still need to work out the specifics, though, and bugtest it.

95

Bot Tavern / Rabidus v1.1 (F1)(Googlyeyesultra)-15.07.07

« on: July 15, 2007, 04:55:37 AM »

I still can't figure out how to beat Etch. The only improvement I've been able to make involves them spreading out a little more, so they end up clumping a lot less... Aside from duo-geneing it (SG + virus), anybody got any suggestions on how to make an upcoming Rabidus 1.2 far better?

96

Evolution and Internet Sharing Sims / Zerobot evolution prize for conditional logic

« on: July 15, 2007, 01:12:56 AM »

It's tempting to just use the program to generate a bunch of randomize dna's, and see if any of them are remotely close to conditional logic. Then just evolve those. Still, that would probably be considered cheating as well...

I'm a lot better at finding ways around the rules than actually doing the challenge.

97

Bot Tavern / Rabidus v1.1 (F1)(Googlyeyesultra)-15.07.07

« on: July 14, 2007, 07:57:10 PM »

In my own personal runs, this one was able to beat the entire F1 league EXCEPT for Etch. Curse you, Etch! Some of 'em take a little while, though.

Code: [Select]

'Rabidus: A bot by googlyeyesultra.

cond
start
'Conspec, Self-Virus Protection, Set Eyewidth
*.myeye *.myshoot add 998 *.robage sgn 1 sub -1 mult mult store
65 999 *.robage sgn 1 sub -1 mult mult store
1221 .eye5width *.robage sgn 1 sub -1 mult mult store

'Targeting/Movement
*.refxpos *.refypos angle .setaim
*.eye5 sqr dup div
*997 *998 sub dup div mult mult store

*.refveldx *.veldx sub .dx
*.eye5 sqr dup div
*997 *998 sub dup div mult mult store

*.refxpos *.refypos dist 2 div *.refvelup add *.velup sub .up
*.eye5 sqr dup div
*997 *998 sub dup div mult mult store

'Sharefeed if multi
99 .sharenrg *.multi mult store
.sharewaste *.multi mult inc
stop

'Reproduce
cond
*.nrg 850 >
*.body 50 >=
start
100 .strbody store
49 .repro store
stop

'Conspec
cond
*.refeye *.refshoot add *997 !=
start
*.refeye *.refshoot add 997 store
stop

'Birthie cut
cond
*.robage 2 <
start
.tie *.robage -1 mult 1 add mult inc
.deltie inc
11 990 store
stop

'Spread out when born
cond
*.eye5 0 !=
*997 *998 =
*.robage 20 <
*.robage 2 >
start
*.refxpos *.refypos angle 628 add .setaim store
*.eye5 .up store
stop

'Shoot feed
cond
*.eye5 30 >
*997 *998 !=
*.refpoison *.refshell >=
start
-6 .shoot store
stop

cond
*.eye5 30 >
*997 *998 !=
*.refpoison *.refshell <
start
-1 .shoot store
stop

'Making venom
cond
*.nrg 300 >
*.body 40 >
*.nrg 2 div 100 75 *.venom sub >
start
75 *.venom sub .strvenom store
stop

'Firing venom
cond
*.eye5 30 >
*997 *998 !=
*997 0 !=
*.venom 25 >
*.robage 10 sub *990 >
start
.setaim .vloc store
*.aim .venval store
*.venom 25 sub rnd 25 add .shootval store
-3 .shoot store
*.robage 990 store
stop

'Deltie enemy ties/conspec ties
cond
*.numties 0 >
*.tiepres *996 !=
*.trefshoot *.trefeye add *998 = or
start
*.tiepres .deltie store
stop

'Tie
cond
*.eye5 30 >
*997 *998 !=
*.numties 0 =
start
999 rnd 996 store
*996 .tie store
stop

'Tiefeed/Counter leach
cond
*.numties 0 >
*.trefshoot *.trefeye add *998 !=
start
*996 .tienum store
*.tieval sgn .tieloc store
-1000 .tieval store
stop

'Body to Energy Conversion
cond
*.nrg 850 <
*.body 50 >
start
*.body 50 sub 100 ceil 10 mult .fdbody store
stop

'Energy to Body Conversion
cond
*.nrg 250 >
*.body 50 <
start
*.body 50 sub 100 ceil .strbody store
stop

'Waste Removal
cond
*.waste 100 >=
start
-4 .shoot store
*.waste .shootval store
stop

'Shoot Virii
cond
*.eye5 15 >
*.nrg 150 >
*.vtimer 1 =
start
50 .vshoot store
stop

'Make Virii
cond
*.vtimer 0 =
start
*.thisgene 1 add .mkvirus store
stop

'Virus
cond
65 *999 !=
start
*.thisgene .mkvirus store
*.myeye *.myshoot add 31999 mult 50 floor .vshoot store
.delgene dec
stop

'Chameleon genes
cond
*.in1 0 !=
*.in1 *.out1 !=
start
*.in1 .out1 store
stop

cond
*.in2 0 !=
*.in2 *.out2 !=
start
*.in2 .out2 store
stop

'Some various code defenses
cond
*.fixed 0 !=
start
0 .fixpos store
stop

cond
*.delgene 0 !=
start
0 .delgene store
stop

cond
*.shoot -2 =
start
0 .shoot store
stop

cond
*.mrepro 0 !=
start
0 .mrepro store
stop

cond
*.sexrepro 0 !=
start
0 .sexrepro store
stop

cond
*.repro 49 !=
*.repro 0 !=
start
0 .repro store
stop

'End of Program
end

98

F1 bots / Rabidus (F1)(Vir)(Googlyeyesultra)-01.07.07

« on: July 14, 2007, 05:44:40 PM »

Don't bother. I'm working on a new edition. It can already beat callidus, but I'm waiting until I can beat animalis supremus before I release it.

99

F1 bots / Rabidus (F1)(Vir)(Googlyeyesultra)-01.07.07

« on: July 13, 2007, 09:57:24 PM »

If I'm not mistaken, you also have to press "use F1 costs" in another panel. I could be wrong, though.

100

F1 bots / Rabidus (F1)(Vir)(Googlyeyesultra)-01.07.07

« on: July 13, 2007, 12:14:46 PM »

I didn't have the latest league, but I'll re-run it now to test. I'll edit this post when I've got some results.

Edit: Mine still seems to be doing quite well. Same results as before. I'm running 2.43 and downloaded the newest league table. Here, lemme attach a sim of it beating DIN2 to let you look at the settings.

101

Evolution and Internet Sharing Sims / Zerobot evolution prize for conditional logic

« on: July 13, 2007, 12:03:41 AM »

Can we make it start like this?

cond
A bunch of random numbers.
start
A bunch of random numbers.
stop

cond
A bunch of random numbers.
start
A bunch of random numbers.
stop

...

end

It'd probably evolve quite a bit faster.

102

F1 bots / Rabidus (F1)(Vir)(Googlyeyesultra)-01.07.07

« on: July 12, 2007, 11:05:45 PM »

This thing is ownin' most of the league in my own run. Try it out, please, for F1 league. I suspect it'll get fairly far.

Edit: Holy cow, using F1 defaults and a simple 5 round per contest on my own machine, mine ended up number 3! Holy cow, it's number three!

Code: [Select]

'Rabidus: A bot by googlyeyesultra.
 
 cond
 start
 'Conspec, Self-Virus Protection, Set Eyewidth
 *.myeye *.myshoot add 92 add 998 *.robage sgn 1 sub -1 mult mult store
 65 999 *.robage sgn 1 sub -1 mult mult store
 1221 .eye5width *.robage sgn 1 sub -1 mult mult store
 stop
 
 'Reproduce
 cond
 *.nrg 850 >
 start
 100 .strbody store
 49 .repro store
 stop
 
 'Conspec
 cond
 *.refeye *.refshoot add 92 add *997 !=
 start
 *.refeye *.refshoot add 92 add 997 store
 stop
 
 'Spread out when born
 cond
 *.eye5 0 !=
 *997 *998 =
 *.robage 20 <
 start
 *.refxpos *.refypos angle 628 add .setaim store
 *.eye5 .up store
 stop
 
 'Targeting/Movement
 cond
 *.eye5 0 >
 *997 *998 !=
 start
 *.refxpos *.refypos angle .setaim store
 *.refveldx *.veldx sub .dx store
 *.refxpos *.refypos dist *.refvelup add *.velup sub 10 sub .up store
 stop
 
 'Shootfeed
 cond
 *.eye5 30 >
 *997 *998 !=
 start
 -6 .shoot store
 stop
 
 'Del ties not made by me
 cond
 *.numties 0 >
 *.tiepres *996 !=
 start
 *.tiepres .deltie store
 stop
 
 'Tie
 cond
 *.eye5 30 >
 *997 *998 !=
 *.numties 0 =
 start
 999 rnd 996 store
 *996 .tie store
 stop
 
 'Tiefeed
 cond
 *.numties 0 >
 start
 996 *.numties sub rnd 996 *.numties add * .tienum store
 -1 .tieloc store
 -1000 .tieval store
 stop
 
 'Sharefeed if multi
 cond
 *.multi 0 >
 start
 99 .sharenrg store
 stop
 
 'Body to Energy Conversion
 cond
 *.nrg 850 <
 *.body 50 >
 start
 *.body 50 sub 100 ceil 10 mult .fdbody store
 stop
 
 'Energy to Body Conversion
 cond
 *.nrg 250 >
 *.body 50 <
 start
 *.body 50 sub 100 ceil .strbody store
 stop
 
 'Waste Removal
 cond
 *.waste 50 >=
 start
 -4 .shoot store
 *.waste .shootval store
 stop
 
 'Shoot Virii
 cond
 *.eye5 15 >
 *.nrg 150 >
 *.vtimer 1 =
 start
 50 .vshoot store
 stop
 
 'Make Virii
 cond
 *.vtimer 0 =
 start
 *.thisgene 1 add .mkvirus store
 stop
 
 'Virus
 cond
 65 *999 !=
 start
 *.thisgene .mkvirus store
 *.myeye *.myshoot add 32000 mult 50 add 32000 ceil .vshoot store
 .delgene dec
 stop
 
 'Chameleon genes
 cond
 *.in1 0 !=
 *.in1 *.out1 !=
 start
 *.in1 .out1 store
 stop
 
 cond
 *.in2 0 !=
 *.in2 *.out2 !=
 start
 *.in2 .out2 store
 stop
 
 'Some various code defenses
 cond
 *.fixed 0 !=
 start
 0 .fixpos store
 stop
 
 cond
 *.delgene 0 >
 start
 0 .delgene store
 stop
 
 cond
 *.shoot -6 !=
 *.shoot -1 !=
 *.shoot 0 !=
 *.shoot -4 !=
 start
 0 .shoot store
 stop
 
 cond
 *.mrepro 0 !=
 start
 0 .mrepro store
 stop
 
 cond
 *.sexrepro 0 !=
 start
 0 .sexrepro store
 stop
 
 cond
 *.repro 49 !=
 *.repro 0 !=
 start
 0 .repro store
 stop
 
 'End of Program
 end
 

103

Bot Challenges / Challenge #2: The Maze

« on: July 12, 2007, 02:58:18 PM »

Can I assume that we just use the built in "horizontal maze" function?

Also, can I also assume that we aren't allowed to delgene the immobilizing gene?

104

F1 bots / SmartShooter (F1)(googleyesultra) - 01.07.07

« on: July 02, 2007, 03:04:19 PM »

I understand how to do most of it, and have all of the f1 league bots stored, as well as the league table. What I don't understand how to do is have my bot be the challenger (it defaults as I-Flamma, I believe).

Edit: D'oh, that was simple! Nevermind.

Edit #2: When I change my code, should I repost it or edit this?

105

The Gene depository / Nasty self-replicating virus

« on: July 02, 2007, 02:51:46 PM »

Ya, it'll beat any antivirus if this gets a chance to run.

Essentially, veggies will spread the virus but won't die from it. Non-veggies will use hideous amounts of energy to fire uber-ranged virii, either killing or crippling themselves in the process.