Topics

151

F1 bots / HDV4 (F1)(PY)-pre30.07.04

« on: February 21, 2005, 01:04:39 PM »

Code: [Select]

' H_Devincio_Venator 4
' HDV4
' *** Tie Hunter ***
' By PY
' The next generation for V2.13
' F1 robot second generation tie feeder
' Kinda old now but still kicks ass
'***********************



'reproduce
'***********
cond
    *.nrg 5000 >
    *.eye5 0 =
  start
    10 .repro store
    2 50 store
    150 .aimdx store
stop

'initialize
'*********
cond
    *.robage 0 =
  start
    8 rnd 2 add 51 store
    25 55 store
stop

' move forward
'****************
cond
    *50 10 >
    *.vel 20 <
  start
    5 .up store
 stop

cond
    *.eye5 0 >
  start
    20 .up store
stop

cond
    *50 100 <
  start
    50 inc
stop

'turn towards food
'*************************
cond
    *.eye1 *.eye9 !=
  start
    *.eye9 *.eye1 sub 4 mult .aimdx store
stop

cond
    *.eye2 *.eye8 !=
  start
    *.eye8 *.eye2 sub 3 mult .aimdx store
stop

cond
    *.eye3 *.eye7 !=
  start
    *.eye7 *.eye3 sub 2 mult .aimdx store
stop

cond
    *.eye4 *.eye6 !=
  start
    *.eye6 *.eye4 sub .aimdx store
stop


'avoid other conspecifics
'****************************
cond
    *.refeye *55 =
    *.eye5 20 >
  start
    180 .aimsx store
stop

' sever ties to conspecifics
' *****************************
cond
    *.trefeye *55 =
  start
    *51 .deltie store
stop

'Spin when attacked
'*************************
cond
    *.shdn 0 <
    *.pleas -10 <
  start
    620 .aimsx store
stop

cond
    *.hitdn 0 !=
  start
    620 .aimsx store
stop

'Tie to an enemy
'********************
cond
    *.eye5 30 >
    *.eye5 *.eye4 =
    *.eye5 *.eye6 =
    *.refeye *55 !=
  start
    *51 .tie store
    0 .aimdx store
stop

'Feed
'******
cond
   *.numties 0 >
  start
    *51 .tienum store
    -1000 .tieval store
    -1 .tieloc store
    *51 .readtie store
stop

cond
*.slime 100 <
start
50 .mkslime store
stop

cond
*.refeye *55 !=
*.eye5 50 >
start
-1 .shoot store
stop

cond
*.nrg 1000 >
*.poison 100 <
start
10 .strpoison store
stop

end

152

F1 bots / D. Scarab3 (F1)(Scarabdrowner)-14.04.04

« on: February 21, 2005, 01:02:01 PM »

Code: [Select]

'D. Scarab 3
'Modified by PY to run in V2.3
'
'F1 Bot
'ScarabDrowner 14 Apr 04


'***************************************1
' store numbers, tie with parent
cond
*.robage 0 =
start
21 51 store
500 rnd 1 add 53 store
*53 .readtie store
.tie inc
52 inc
stop

'******************2
' reproduce
cond
*.nrg 6000 >
start
33 .repro store
stop

' *******************3
' sever tie to parent
cond
*.robage 1 =
start
.deltie inc
stop

' *******************4
' look for food
cond
*.eye1 *.eye5 >
*.eye1 *.eye9 >
*.refeye *51 !=
*.numties 0 =
start
mult -110
52 inc
stop

'**********************5
cond
*.eye9 *.eye5 >
*.eye9 *.eye1 >
*.refeye *51 !=
*.numties 0 =
start
mult 110
52 inc
stop

'**********************6
cond
*.eye3 *.eye5 >
*.eye3 *.eye7 >
*.refeye *51 !=
*.numties 0 =
start
mult -70
52 inc
stop

'**********************7
cond
*.eye7 *.eye5 >
*.eye7 *.eye3 >
*.refeye *51 !=
*.numties 0 =
start
mult 70
52 inc
stop

'**********************8
cond
*.eye5 15 >
*.refeye *51 !=
start
52 inc
stop

'***************************************9
' attach to food or enemy
cond
*.eye5 30 >
*.eye4 *.eye6 =
*.refeye *51 !=
start
*53 .tie store
314 .tieang store
mult 0
*.vel -1 mult .up store
stop

'***************************************10
' spin while waiting
cond
*52 0 =
*.numties 0 =
start
mult 78
stop

'***************************************11
' actually make the turn
cond
start
.aimdx store
stop

'***************************************12
' drain energy from food or enemy
cond
*.numties 0 >
start
*53 .tienum store
-1000 .tieval store
.tieloc dec
stop

'***************************************13
' velocity, make the sucker move
cond
*52 0 >
*.vel 40 <
start
40 *.vel sub .up store
0 52 store
stop

'***************************************14
' maintain slime sheild against ties
cond
*.slime 100 <
start
10 .mkslime store
stop

'***************************************15
' degrade enemy's slime shield
cond
*.refeye *51 !=
*.eye5 40 >
start
820 .shoot store
0 .shootval store
stop

'***************************************16
' store poison for defense
cond
*.nrg 49 >
*.poison 50 <
start
50 .strpoison store
stop

'***************************************17
' detect a tie attack and counterattack
cond
*.tiepres *53 !=
*.numties 0 >
*.trefeye *51 !=
start
*.tiepres .tienum store
-1000 .tieval store
.tieloc dec
stop

'***************************************18
' if enemy hijacks tie, counterattack
cond
*.tiepres *53 =
*.trefeye *51 !=
*.pain 100 >
*.pain 2000 <
start
53 .deltie store
314 .aimdx store
-1 .shoot store
stop

end

153

F1 bots / Darth Shimazu (F1)(Henk)-04.03.04

« on: February 21, 2005, 01:00:49 PM »

Code: [Select]

' Darth Shimazu.
' "The Dark side has come.
' Muhahaha. Poor Shimazu, I knew
' that weakling would fall for
' the dark side..."
' This bot is the dark side version of
' Shimazu. It eats all but his friends
' By Henk

' ********************************* General Genes *********************************

'reset out1 when no-one is in sight
cond
*.eye5 0 =
*.in1 11 =
start
0 .in1 store
stop

'reproduce
cond
*.nrg 4500 >
*.robage 50 >
start
50 .repro store
628 .aimsx store
stop



' ***************************** Battle genes****************************************

' kill with standard shooting routine
cond
*.eye5 0 >
*.in1 11 !=
start
-1 .shoot store
stop

' ************************** nonsense genes to identify, so trefshoot=5**************

' Nonsense
cond
*.nrg 2 =
start
-3 .shoot store
stop

' Nonsense
cond
*.nrg 1 =
start
-3 .shoot store
stop

' Nonsense
cond
*.nrg 3 =
start
-1 .shoot store
stop

' Very important gene that controls the whole of the bot
cond
*.nrg 4 =
start
-1 .shoot store
stop

' **********************************TIE Genes****************************************

' Engage tie
cond
*.eye5 30 >
*.in1 11 !=
start
31 .tie store
stop

' Feed through tie
cond
*.numties 0 >
start
31 .tienum store
-1000 .tieval store
-1 .tieloc store
100 .sharenrg store
stop

' read the tie
cond
*.numties 0 >
start
31 .readtie store
stop

' ***************************************Move genes************************************
' Move.
cond
*.vel 30 <
start
10 .up store
stop

' ********************* Follow Genes **************************************************
' Follow gene 1
cond
*.eye1 *.eye9 !=
*.numties 0 =
start
*.eye9 *.eye1 sub 4 mult .aimdx store
stop

' Follow gene 2
cond
*.eye2 *.eye8 !=
*.numties 0 =
start
*.eye8 *.eye2 sub 3 mult .aimdx store
stop

' Follow gene 3
cond
*.eye3 *.eye7 !=
*.numties 0 =
start
*.eye7 *.eye3 sub 2 mult .aimdx store
stop

' Follow gene 4
cond
*.eye4 *.eye6 !=
*.numties 0 =
start
*.eye6 *.eye4 sub .aimdx store
stop

' ******************* Species genes ****************************************************

' turn away from other Darth Shimazu's
cond
*.in1 11 =
*.robage 20 >
start
314 .aimdx store
stop

'Identify as Darth Shimazu
cond
*.out1 11 !=
start
11 .out1 store
stop

' delete tie to fellow Darth Shimazu
cond
*.trefshoot 5 =
*.numties 0 >
start
31 .deltie store
stop

' *******************Reaction genes******************************************************

' right reaction gene
cond
*.shdx -1 =
start
314 .aimdx store
31 .tie store
stop

' Left reaction gene
cond
*.shsx -1 =
start
-314 .aimdx store
31 .tie store
stop

' Aft Reaction gene
cond
*.shdn -1 =
start
628 .aimdx store
31 .tie store
stop

' Forward reaction gene; Useless
' cond
' *.shup -1 =
' start
' 31 .tie store
' stop

' ****************/reaction genes********************************************************

‘ Tie to daddy on birth
cond
*.robage 0 =
start
31 .tie store
stop

‘ delete tie again. Bye daddy...
cond
*.robage 1 =
start
31 .deltie store
stop

' make small slime. Yuk
cond
*.slime 100 <
start
80 .mkslime store
stop

end

154

Announcements / The bestiary

« on: February 21, 2005, 11:25:19 AM »

As you have probably noticed, the bestiary is now under way. In this forum we will attempt to keep an archive of all robots ever made.

Each entry will carry an attachment with the full DNA file.

The Bestiary will be moderated by myself, Numsgil and Mighty Penguin.

Any submissions will have to be approved by one of the mods before it can be posted. This should stop arbitrary posts and keep the forum organized.

 :D  PY  :D

155

F1 bots / Devincio Eversor (F1)(PY)-pre 30.07.04

« on: February 21, 2005, 11:12:55 AM »

Code: [Select]

'Devincio_Eversor
' *** Tie Destroyer ***
'***********************
' Second generation tie feeder
' Not very good since V2.3 as
' his stearing is screwed up.
' At one time he OWNED DarwinBots
' PY

'initialize
'*********
cond
    *.robage 0 =
  start
    8 rnd 2 add 51 store
    45 55 store
    '*51 .tie store
    0 .deltie store
stop

' move forward
'****************
cond
    *.refeye *55 !=
  start
    30 *.vel sub .up store
 stop

cond
    *.refeye *55 !=
    *.refeye 0 !=
    *.eye5 80 >
  start
    40 *.vel sub .up store
stop

cond
    *.refeye *55 =
    *.eye5 50 >
  start
    2 .dn store
stop

'turn towards food
'*************************
'avoid other conspecifics
'****************************
cond
start
mult 0
stop

cond
'*.eye4 *.eye5 >
*.eye4 *.eye6 >
start
mult -15
stop

cond
'*.eye6 *.eye5 >
*.eye6 *.eye4 >
start
mult 15
stop

cond
*.eye3 *.eye5 >
*.eye3 *.eye4 >
*.eye3 *.eye6 >
start
mult -50
stop

cond
*.eye7 *.eye5 >
*.eye7 *.eye6 >
*.eye7 *.eye4 >
start
mult 50
stop

cond
*.eye1 *.eye5 >
*.eye1 *.eye4 >
*.eye1 *.eye6 >
*.eye1 *.eye3 >
*.eye1 *.eye7 >
start
mult -100
stop

cond
*.eye9 *.eye5 >
*.eye9 *.eye4 >
*.eye9 *.eye6 >
*.eye9 *.eye3 >
*.eye9 *.eye7 >
start
mult 100
stop

' Avoid conspecifics
' ***********************
cond
    *.refeye *55 =
  start
    mult 85
stop

'reproduce
'***********
cond
    *.nrg 4000 >
    *.eye5 0 =
  start
    25 .repro store
    mult 250
stop

'Tie to an enemy
'********************
cond
    *.eye5 30 >
    *.eye5 *.eye4 =
    *.eye5 *.eye6 =
    *.refeye *55 !=
  start
    *51 .tie store
    mult 0
stop

' Actually rotate
' *****************
cond
start
     .aimdx store
stop

' sever ties to conspecifics
' *****************************
cond
    *.trefeye *55 =
  start
    *51 .deltie store
stop

'Spin when attacked
'*************************
cond
    *.shdn 0 <
    *.pleas -10 <
  start
    620 .aimsx store
stop

cond
    *.hitdn 0 !=
  start
    620 .aimsx store
stop

'Feed
'******
cond
   *.numties 0 >
  start
    *51 .tienum store
    -1000 .tieval store
    -1 .tieloc store
    *51 .readtie store
stop

cond
    *.numties 0 >
    *.waste 100 >
    *.trefeye 0 =
  start
    1000 .tieval store
    -4 .tieloc store
stop

cond
*.slime 90 <
start
50 .mkslime store
stop

cond
*.refeye *55 !=
*.eye5 50 >
start
-1 .shoot store
stop

end

156

F1 bots / Devincio Dominator (F1)(PY)-03.03.04

« on: February 21, 2005, 11:08:35 AM »

Code: [Select]

'Devincio_Dominator3
'***********************
' F1 tie feeder with specialized features
' Built prior to V2.3
' PY

'initialize
'*********
cond
    *.robage 0 =
  start
    8 rnd 2 add 51 store
    45 55 store
    .tie inc
stop

' move forward
'****************
cond
    *.refeye *55 !=
  start
    30 *.vel sub .up store
 stop

cond
    *.refeye *55 !=
    *.refeye 0 !=
    *.eye5 80 >
  start
    40 *.vel sub .up store
stop

'turn towards food
'*************************
'avoid other conspecifics
'****************************
cond
start
mult 0
stop

cond
*.eye4 *.eye6 >
start
mult -15
stop

cond
*.eye6 *.eye4 >
start
mult 15
stop

cond
*.eye3 *.eye5 >
*.eye3 *.eye4 >
*.eye3 *.eye6 >
start
mult -50
stop

cond
*.eye7 *.eye5 >
*.eye7 *.eye6 >
*.eye7 *.eye4 >
start
mult 50
stop

cond
*.eye1 *.eye5 >
*.eye1 *.eye4 >
*.eye1 *.eye6 >
*.eye1 *.eye3 >
*.eye1 *.eye7 >
start
mult -100
stop

cond
*.eye9 *.eye5 >
*.eye9 *.eye4 >
*.eye9 *.eye6 >
*.eye9 *.eye3 >
*.eye9 *.eye7 >
start
mult 100
stop

' Avoid conspecifics
' ***********************
cond
    *.refeye *55 =
  start
    mult 85
stop

'reproduce
'***********
cond
*.robage 50 <
*.nrg 2800 >
*.eye5 50 <
start
50 .repro store
mult 250
stop

cond
    *.nrg 6000 >
    *.eye5 50 <
  start
    25 .repro store
    mult 250
stop

'Tie to an enemy
'********************
cond
    *.eye5 30 >
    *.eye5 *.eye4 =
    *.eye5 *.eye6 =
    *.refeye *55 !=
  start
    *51 .tie store
    mult 0
    65 inc
stop

' Actually rotate
' *****************
cond
start
     .aimdx store
stop

' sever ties to conspecifics
' *****************************
cond
    *.trefeye *55 =
  start
    *51 .deltie store
stop

'Feed
'******
cond
   '*.numties 0 >
   *65 0 >
  start
    *51 .tienum store
    -1000 .tieval store
    -1 .tieloc store
    *51 .readtie store
stop

cond
*.numties 0 =
*65 0 !=
start
65 dec
stop

cond
start
100 .mkslime store
stop

cond
*.refeye *55 !=
*.refeye 0 !=
*.eye5 0 >
start
.mkslime .shoot store
-100 .shootval store
stop

end

157

F1 bots / BodySnatcher (F1)(K0zm0)-09.01.05

« on: February 21, 2005, 11:05:59 AM »

Code: [Select]

'BodySnatcher
'Made by k0zm0
'9.jan.05
'Made for DB v2.34

def alert 50

cond
0 *.refeye =
*.eye5 0 >
*.vtimer 0 =
start
4 .mkvirus store
100 .vshoot store
stop

cond
*.myeye *.refeye !=
*.eye5 0 >
*.vtimer 0 =
start
3 .mkvirus store
100 .vshoot store
stop

cond
*.nrg 5000 <
start
100 .fdbody store
stop

cond
*.nrg 4999 >
start
100 .strbody store
stop

cond
*.kills 20 >
*.body 10000 >
start
50 .repro store
stop

cond
*.nrg 5000 >
*.eye5 30 >
*.myeye *.refeye !=
start
-6 .shoot store
stop

cond
*.nrg 4000 <
*.eye5 30 >
*.myeye *.refeye !=
start
-1 .shoot store
stop

cond
*.alert 0 !=
*.eye5 0 =
start
*.shang .setaim store
stop

cond
*.eye1 *.eye5 >
*.eye1 *.eye3 >
*.eye1 *.eye7 >
start
100 .aimsx store
stop

cond
*.eye9 *.eye5 >
*.eye9 *.eye7 >
*.eye9 *.eye3 >
start
100 .aimdx store
stop

cond
*.eye3 *.eye5 >
*.eye3 *.eye4 >
*.eye3 *.eye7 >
start
45 .aimsx store
stop

cond
*.eye7 *.eye5 >
*.eye7 *.eye6 >
*.eye7 *.eye3 >
start
45 .aimdx store
stop

cond
*.eye4 *.eye5 >
*.eye4 *.eye6 >
start
25 .aimsx store
stop

cond
*.eye6 *.eye5 >
*.eye6 *.eye4 >
start
25 .aimdx store
stop

cond
start
*.maxvel *.vel sub 4 div .up store
stop

cond
*.eye5 35 >
*.fixed 0 =
start
1 .fixpos store
stop

cond
*.eye5 40 <
*.fixed 1 =
start
0 .fixpos store
stop

cond
*.eye5 0 >
*.myeye *.refeye =
start
*.refaim .setaim store
stop

cond
*.robage 10 >
*.numties 0 >
*.tiepres 1 =
start
1 .deltie store
stop

cond
*.numties 0 >
start
*.tiepres .tienum store
.tieval .tieloc store
1000 .tieval store
stop

cond
*.eye5 0 >
*.refeye *.myeye =
*.in1 *.out1 !=
start
*.in1 .out1 store
*.in1 .alert store
stop

cond
*.eye5 0 >
*.myeye *.refeye !=
*.refeye 0 !=
*.refshoot 0 =
*.reftie 0 !=
start
2 .out1 store
2 .alert store
stop

cond
*.eye5 0 >
*.myeye *.refeye !=
*.refeye 0 !=
*.refshoot 0 !=
*.reftie 0 =
start
1 .out1 store
1 .alert store
stop

cond
*.eye5 0 >
*.myeye *.refeye !=
*.refeye 0 !=
*.refshoot 0 !=
*.reftie 0 !=
start
3 .out1 store
3 .alert store
stop

cond
*.body 5000 >
*.waste 100 >
*.eye5 0 >
start
*.waste .shootval store
-4 .shoot store
stop

cond
*.alert 1 =
*.body 2000 >
start
200 *.shell sub .mkshell store
stop

cond
*.alert 2 =
*.body 2000 >
start
200 *.slime sub .mkslime store
stop

cond
*.alert 3 =
*.body 2000 >
start
200 *.slime sub .mkslime store
200 *.shell sub .mkshell store
stop
end

158

F1 bots / Carnatus Orbis (F1)(PY)-20.09.04

« on: February 21, 2005, 11:03:57 AM »

Code: [Select]

' Carnatus Orbis (Fat Circle)
' Obese son of HDV4
' By PY.
' Basic F1 tie feeder with body controls

def feed 70
def feedrate 71
def tietag 72

'reproduce
'***********
cond
*.nrg *60 >
*.body *61 >
*.eye5 0 =
start
20 .repro store
2 50 store
150 .aimdx store
stop

'initialize
'*********
cond
*.robage 0 =
start
.shoot .ploc store
2000 60 store
200 61 store
.tie inc
*.myeye .refeye store
.tienum .vloc store
999 .venval store
stop

cond
*.robage 1 =
start
.deltie inc
628 .aimdx store
stop

cond
*60 30000 <
start
60 inc
61 inc
stop

' move forward
'****************
cond
*.eye5 60 <
*.robage 0 !=
*.vel 20 <
*.numties 0 =
start
5 .up store
stop

cond
*.eye5 0 >
*.eye5 50 <
*.refeye *.myeye !=
*.numties 0 =
start
*.maxvel *.vel sub .up store
stop

'turn towards food
'*************************
cond
*.eye5 0 =
*.eye1 *.eye9 !=
start
mult
*.eye9 *.eye1 sub 4 mult
stop

cond
*.eye5 30 <
*.eye2 *.eye8 !=
start
mult
*.eye8 *.eye2 sub 3 mult
stop

cond
*.eye5 40 <
*.eye3 *.eye7 !=
start
mult
*.eye7 *.eye3 sub 2 mult
stop

cond
*.eye5 70 <
*.eye4 *.eye6 !=
start
mult
*.eye6 *.eye4 sub
stop

'avoid conspecifics
'*********************
cond
*.refeye *.myeye =
*.eye5 20 >
*.robage 0 !=
start
mult
280
stop

cond
start
.aimdx store
stop

cond
*.tiepres 0 !=
'*.tietag 0 !=
start
.feed inc
.tietag inc
stop

cond
*.feed 1 =
start
-3 .tieloc store
25 .tieval store
*.tiepres .tienum store
stop

cond
*.feed 1 >
start
-1 .tieloc store
-3000 .tieval store
*.tiepres .tienum store
stop

cond
*.refeye *.myeye !=
*.eye4 *.eye6 =
*.eye5 40 >
*.numties 0 =
start
500 rnd .tie store
'.tietag inc
stop

cond
*.feed 0 >
*.numties 0 =
start
0 .feed store
'0 .tietag store
stop

cond
*.refeye *.myeye !=
*.eye5 50 >
*.refpoison 0 =
start
-1 .shoot store
stop

cond
*.refeye *.myeye !=
*.eye5 50 >
*.refpoison 0 >
start
-6 .shoot store
stop

cond
*.nrg 1000 >
*.poison 5000 <
start
10 .strpoison store
stop

cond
*.nrg 100 >
*.venom 100 <
start
10 .strvenom store
stop

cond
*.nrg 800 >
start
100 .strbody store
stop

cond
*.waste 100 >
start
*.waste .shootval store
-4 .shoot store
1 .backshot store
stop

end

159

F1 bots / Anon Terrifica (F1)(PY)-pre 30.07.04

« on: February 21, 2005, 10:27:56 AM »

Code: [Select]

' *PY's Anon Terifica
' ************************
cond
*.vel 10 <
*.refeye *55 !=
start
2 .up store
stop

' initialize
' *********
cond
*.robage 0 =
start
10 rnd 1 add 53 store
20 55 store
25 .tie store
stop

cond
*.robage 1 =
start
25 .deltie store
stop

' dump waste
' **********
cond
*.waste 50 >
start
-4 .shoot store
50 .shootval store
stop

'reproduce
'***********
cond
*.nrg 3000 >
start
50 .repro store
0 50 store
628 .aimdx store
stop

'turn towards food
'*************************
cond
*.eye1 *.eye5 >
*.eye1 *.eye9 >
start
-110 .aimdx store
3 .up store
stop

cond
*.eye9 *.eye5 >
*.eye9 *.eye1 >
start
110 .aimdx store
3 .up store
stop

cond
*.eye3 *.eye5 >
*.eye3 *.eye7 >
start
-70 .aimdx store
2 .up store
stop

cond
*.eye7 *.eye5 >
*.eye7 *.eye3 >
start
70 .aimdx store
2 .up store
stop

'Tie to an enemy
'********************
cond
*.eye5 30 >
*.eye4 *.eye6 %=
*.refeye *55 !=
'*50 2 >
*.robage 2 >
start
*53 .tie store
0 .aimdx store
stop

'avoid other conspecifics
'****************************
cond
*.refeye *55 =
start
280 .aimsx store
stop

' Avoid corpses
' ****************
cond
*.refnrg 1 <
*.eye5 50 >
start
150 .aimsx store
stop

cond
*.numties 0 >
start
*53 .tienum store
-1000 .tieval store
-1 .tieloc store
stop

end

160

Formula 2 / Formula 2 league

« on: February 20, 2005, 02:20:09 PM »

Link for: Running the leagues yourself
Link for: Error reporting (bugs with league or errors with links and bot DNA or problems running the league yourself.)

• League: F2
• Last update: 1st October 2008 by Commander Keen
• F2 League Rules
• This league was run on DB v2.43.1L[/b]

Top Bots in F2 league:
(Download of files needed to run this league yourself at bottom of page.)

#F2
1 - Spinner_v1.51(F2)(Moonfisher)26-09-08
2 - ThisnThat1.01(F2)(Peksa)12.05.08
3 - Multiply4(F1)(F2)(Peter)19-12-07
4 - Excalibur 1.12 (F2)(Light)-06.03.07
5 - Martian Tank 3 (F2)(Martian)-06.07.2007
6 - Excalibur (F2)(Light)-26.02.05
7 - Republican Bee (F2)(Commander Keen)
8 - Bubbles (F2)(Jez)-21.08.06
9 - Blue on blue (F2)(Jez)-05.08.06
10- Martian Tank 2 (F2)(Martian)-04.07.2007
11- Markus Volithistralis2 (F2)(Ark)-08.02.06
12- Hunter V2.3 (F2)(PY)-26.04.05
13- Ymir (F2)(Numsgil)-21.02.05
14- Ratticus Rex (F2)(Jez)-27.02.07
15- SWARM 2.0 (F2)(Elite)-10.03.07
16- Zebedee V2.1 (F2)(Jez)-26.07.06
17- Icarus (F2)(Light)-26.11.04
18- Spiral (IB)(F2)(abyaly)-16.06.07
19- Tortuca Mechanica (F2)(Eight)-18.09.04
20- Purple Swarmer (F2)(PY)-23.02.05
21- One Man Bucket (SS)(F2)(abyaly)-03.04.07
22- Seasnake_1.0(F2)(EricL)
23- Brevis (SS) (F2) (Moonfisher) 22-03-08
24- Fishy (IB)(MacadamiaNuts)-11.06.07
25- OculusInfinitusv1.1(F2)(CommanderKeen)
26- Vermis Bicerebrus(F2)(Bacillus)
27- Massed Hunter(F2)(rayz)
28- Daedelus (F2)(Light)-29.07.04
29- BOTbot(F2)(Bacillus)
30- Purple Flamma (F2)(PY(Mod))-04.01.05

If you need more information on how to run the league please look here: Running the leagues yourself

161

Formula 1 / Formula 1 league

« on: February 20, 2005, 01:31:39 PM »

Link for: Running the leagues yourself
Link for: Error reporting (bugs with league or errors with links and bot DNA or problems running the leagues yourself.)

• League F1
• Last update: 08.07.07
• F1 League Rules
• This league was run on DB 2.43[/b]

(Dates are as accurate as I can get them, pre means earliest file I have but no date of posting bot)
Most of the bots created before 04.12.04 have been modded by PY to make them run after that date. So if you get beaten by a really old bot remember to thank him for all his hard work! :D

Kudo's to Eric making 2.43 work as well as it does!  :clap:


DarwinBots Formula 1 all-comers league[/b][/color]

Top Bots in F1 league
(The easiest way to run this league yourself is to download the two zipped files at the bottom of post.)

#F1
1 - Guardian v0.9 (F1)(Trafalgar)-15.07.07
2 - Etch (F1Vir)(abyaly)-10.04.2007
3 - Reaper (F1)(Googlyeyesultra)-17.07.07
4 - Aura (1G)(abyaly)-29.03.2007
5 - Excalibur 1.12 (F2)(Light)-06.03.07
6 - Ratticus Rex (F2)(Jez)-27.02.07
7 - UNA 3.0 (1G)(Elite)-29.04.06
8 - The One (1G)(Shen)-23.04.05
9 - DIN (F1)(Endy(Mod))-21.02.05
10- Destinatus Preliator (F2)(PY)-16.09.04
11- Dominator Invincibalis(DOM INV) (F1)(PY)-pre 18.06.04
12- Carnatus Orbis (F1)(PY)-20.09.04
13- Kyushu (F1)(Henk)-08.05.06
14- Darth Shimazu (F1)(Henk)-pre 30.07.04
15- Spanish Conquistador (6GVir)(Numsgil)-12.05.05
16- Animal Supremus (F1Vir)(Elite(Mod))-22.01.06
17- Callidus (F1)(Shen)-05.04.05
18- Bubbles (F2)(Jez)-21.08.06
19- Blue on blue (F2)(Jez)-05.08.06
20- T. Mosquito v1.03 (1G)(MacadamiaNuts)-14.01.07
21- DIN2 (F1)(Endy(Mod))-02.04.05
22- Duplo Simpleboticus (F2)(Jez&PY)-01.03.04
23- HDV4 (F1)(PY)-pre 30.07.04
24- James 4 (F1)(Jez)-27.07.04
25- Animal Minimaxis 3 (F1Vir)(-venom-)-14.01.07
26- SWARM 2.0 (F2)(Elite)-10.03.07
27- Proeliator Gryphus (F1)(Strangers)-3.3.07
28- Speedy(6GVir)(Peter)-27.06.07
29- Martian Tank 3 (F2)(Martian)-06.07.2007
30- Martian Tank 2 (F2)(Martian)-04.07.2007

Zipped folder with all current F1 bots and F1league.txt - see Running the leagues yourself if you are not sure how to use these.

162

Announcements / Welcome!!!!

« on: February 20, 2005, 02:00:10 AM »

Here it is. The updated, new and improved DarwinBots Forum.

Sign up and Enjoy

 :D  PY  :D