Messages

16

Bot Tavern / Discerpo Inscribo

« on: December 05, 2006, 06:05:23 PM »

(As posted in league settings by Nums), check that your costs are proportional and at 100%. unfortunately using the league settings in the latest DB version tends to set this at zero, meaning your bot won't get any reward for firing shots. Tick and untick the F1 settings option first so that it is as close to default as possible.

It's not a code fault, it's a settings fault and Eric is working on the problem as we speak.

yay!

17

Bot Tavern / Discerpo Inscribo

« on: December 05, 2006, 03:28:08 PM »

Rofl, where's the option box?..

EDIT

Your bot works now Kage, along with all the other F2 bots!

I suggest you add a veg search routine so it doesn't just sit still if it can't see veg and another repro gene for when it's not fighting tie bots. A good test is if your bots can cope in a sim against just veg.

I already got the repro thing coded in for the next discerpo...but I don't know how to code it in so that it can beat those lethal veggies in an all out pitched melee combat?

18

Bot Tavern / Missing bots

« on: December 04, 2006, 06:35:05 PM »

3 more bots to add to your list

Asterus Igni
               found in the Hello and a Shortbot [or it was called something like that (in the newbies forum, near the end of the first page of the topic it has the bot)]

Code: [Select]

'Asterus Igni
'By Esrever
'~~~~~~~~~~~~
'Bot Designed for SB League
'Two minor bugs fixed by Henk

' Gene 1 Catch and
' Fight Prep
cond
*.eye5 0 >
*.refeye *.myeye !=
*.numties 0 =
start
*.refveldx .dx store
*.refvelup 20 add .up store
200 *.poison sub .strpoison store
75 *.slime sub .mkslime store
10 *.body sub 10 mult .strbody store
stop

' Gene 2 Tie Up
cond
' *,numties 0 = and (this as the original condition with a bug)
*.numties 0 = and ' fixed
*.eye5 40 > and
*.refeye *.myeye != and
*.eye5 77 != and
*.robage 0 = or
start
1 .tie store
1 .readtie store
stop

' Gene 3 Eat Enemies
cond
*.trefeye *.myeye !=
start
1 .tienum store
-1000 .tieval store
-1 .tieloc store
stop

' Gene 4 Anti-Cannibalism
' and Birth Setup
cond
*.trefeye *.myeye =
*.robage 1 = or
start
1 .deltie store
200 *.poison sub .strpoison store
75 *.slime sub .mkslime store
10 *.body sub 10 mult .strbody store
stop

' Gene 5 Avoid/Search
cond
*.eye5 0 =
*.refeye *.myeye = or
start
471 rnd .aimdx store
stop

' Gene 6 Reproduce
cond
*.nrg 4000 >
start
60 .repro store
stop

' added an end command
end

Batavus Minimalis (Shortbot forum)

Code: [Select]

' Batavus duo
' a SBMB (ShortBot Multibot)

def id 803

' GENE ONE: make a tie at birth
' *************************
cond
*.robage 0 =
*.eye5 70 >
start
1 .tie store
314 .id store
.shoot .ploc store
stop

' GENE TWO: reproduce if not an mb
' *****************************
cond
*.numties 0 =
*.robage 0 >
start
50 .repro store
0 .aimdx store
314 .id store
stop

' GENE THREE: share through tie, fix tie angle
' ************************************
cond
*.numties 0 >
*.robage *40 >
*.robage 10 >
start
628 .fixang store
400 .fixlen store
*.robage 25 add 40 store
50 .sharenrg store
1 .readtie store
0 .fixpos store
20 *.poison sub *.nrg 2 div ceil .strpoison store
stop

'GENE FOUR: Turn and move (head only)
' ********************************
cond
*.numties 0 >
*.trefage *.robage >
*.eye5 35 <=
start
*.eye9 *.eye1 sub 4 mult 50 store
*.eye6 *.eye4 sub 51 store
*50 *51 add 130 ceil .aimdx store
*.maxvel *.vel sub .up store
0 .fixpos store
stop

' GENE FIVE: Reproduce (tail only)
' ***************************
cond
*.trefage *.robage <
*.nrg 7000 >
start
1 .deltie store
314 .aimdx store
stop

' GENE 6: Kill (head only)
' *******************
cond
*.numties 0 >
*.trefage *.robage >
*.eye5 35 >
start
803 .memloc store
*.memval .aimdx store
-1 .shoot store
.fixpos inc
stop

end

Vector 1.0 (also found in short bots)

Code: [Select]

'Vector 1.0 by abyaly
'Public SG version
'Communicates the location of food to conspecs
'I will release a legible and commented version once it is finished
'Which will be some time after finals are over ^^

cond
start
*.refveldx 4 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.maxvel *.vel sub 1 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.maxvel *.vel sub 1 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refveldx 4 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refvelup 1 *.eye5 sub sqr dup div 40 mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refveldx 4 *.eye5 sub sqr dup div 40 mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refaim 19 *.eye5 sub sqr dup div 40 mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
314 5 *.eye5 0 sub sqr dup div *.refeye *.myeye sub dup div 1 sub abs mult *.in1 0 sub dup div 1 sub abs *.in2 0 sub dup div 1 sub abs mult *.memval 0 sub dup div 1 sub abs mult 9 rnd 0 sub dup div 1 sub abs add sgn mult mult store
*.maxvel *.vel add *.eye5 mult 50 div 15 ceil 4 *.eye5 0 sub sqr dup div *.refeye *.myeye sub dup div 1 sub abs mult *.in1 0 sub dup div 1 sub abs *.in2 0 sub dup div 1 sub abs mult *.memval 0 sub dup div 1 sub abs mult 9 rnd 0 sub dup div 1 sub abs add sgn mult mult store
330 *.robage 0 sub dup div 1 sub abs mult inc
467 *.robage 1 sub dup div 1 sub abs mult inc
51 *.memloc sgn -1 mult 1 add 474 mult store
0 51 *51 sgn mult *.eye5 sgn 1 sub abs *.refeye *.myeye sub dup div 1 sub abs add sgn mult store
1 51 *.eye5 sgn mult *.refeye *.myeye sub dup div mult *.refeye sgn mult store
800 *.out1 dup div mult dec
800 *.eye5 sgn mult *.memval sgn *.refeye *.myeye sub dup div add sgn mult inc
801 *.out2 dup div mult dec
801 *.eye5 sgn mult *.in1 *.memval add dup div *.refeye *.myeye sub dup div add sgn mult inc
*.eye1 -4 mult *.eye2 -3 mult *.eye3 -2 mult *.eye4 -1 mult *.eye6 1 mult *.eye7 2 mult *.eye8 3 mult *.eye9 4 mult add add add add add add add add *.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9 add add add add add add add add div 34 mult *.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9 add add add add add add add add dup div *.eye5 sgn 1 sub dup div mult *.shdn *.shdx *.shsx add add dup div 1 sub dup mult mult 5 mult store
330 *.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9 add add add add add add add add dup div 1 sub dup mult *.shdn *.shdx *.shsx add add dup div 1 sub dup mult mult 5 mult store
*.refxpos *.refypos angle 19 *.robage sgn mult *.refeye *.myeye sub dup div mult *.refxpos *.refypos angle *.aim sub dup div mult *.shdn *.shdx *.shsx add add dup div 1 sub dup mult mult *.eye5 sgn mult store
*.shang 314 add 5 *.shdn *.shdx *.shsx add add dup div mult *.refeye *.myeye sub dup div 1 sub dup div *.refeye sgn 1 sub sgn abs add mult store
100 313 *.nrg 500 sub sqr sgn mult 500 *.body sub sqr sgn mult store
*.body 0 floor 312 *.body sgn mult 100 *.nrg sub sqr sgn mult store
*.body 50 sub 0 floor 100 ceil 312 *.body 50 sub sqr sgn mult 800 *.nrg sub sqr dup div mult store
60 300 30 *.eye4 *.eye5 *.eye6 add add 3 div sub sqr sgn mult *.nrg 600 sub sgn mult store
100 *.shell sub 0 floor 100 ceil 100 *.shell sub sgn abs 822 mult store
*.waste 8 *.waste 10 sub sgn mult store
-4 7 *.waste 10 sub sgn mult store
-6 7 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
4 8 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
*.refvelup 1 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
*.refveldx 4 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
-6 7 *.refshell 20 sub sqr sgn mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
4 8 20 *.refshell 20 sub sqr sgn mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
-1 7 *0 20 sub sqr sgn 1 sub abs mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
32 8 *0 20 sub sqr sgn 1 sub abs mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.refvelup 1 *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.refveldx 4 *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
340 inc
340 inc
end

19

Bot Tavern / Discerpo Inscribo

« on: December 04, 2006, 06:24:15 PM »

I just found a medieval picture on google and used it.

I could of just been a reader of the thread, then again, they were all too lazy to even look at it  , sorry for my failure to recruit new people

20

Bot Tavern / Missing bots

« on: December 04, 2006, 04:34:09 PM »

I found it under "My evo bot" (it was made by Shen and is on the second page of the short bots sub forum of the bestiary)

21

Bot Tavern / Discerpo Inscribo

« on: December 04, 2006, 04:31:13 PM »

I looked at your weblink and blog btw, are we talking Medieval 2? Those pictures look very familiar.

Wait, how did you know which blog was mine?  

Erm, I dunno, I just found the image on the internet

22

Bot Tavern / Missing bots

« on: December 03, 2006, 05:30:46 PM »

I found 2 of them around the forum...



Heres Symbioticus 2.5

Code: [Select]

' Symbioticus
'
' A tank with a battery ...
'
' Ties to a veg, pulls
' it close behind it and
' uses it as an energy
' source
'
' Version 2.0
' - Code completely redone
' - Uses a modified version of Animal Minimalis' search pattern
' Version 2.1
' - Uses some better coding to save energy
' Version 2.2
' - Improves on turning and movement genes
' Version 2.3
' - Adds a roaming routine to cover more ground
' Version 2.4
' - Some minor changes, improved some routines, better .fdbody routine
' Version 2.5
' - Some minor changes, corrected an error in the coding which caused Symbioticus to become immobile when it lost it's veg, annotated some more of the code to make it more understandable

'*************************************************************

def roam 51 ' Used for movement
def done 52 ' Used for setting tie

' Delete birth tie and set .memloc

cond
start
.tie *.robage -1 mult 1 add mult inc
.tiepres .memloc *.robage -1 mult 1 add mult store
.deltie inc
stop

'*************************************************************

' Find and tie to a veggie

cond
*.robage 0 >
*.done 0 =
*.multi 0 =
*.eye5 0 >
*.eye5 45 <
*.refshoot 0 =
*.refaimdx 1 =
*.refeye 0 =
*.memval 86 !=
*.numties 0 =
start
40 .up store
stop

cond
*.robage 0 >
*.eye5 45 >
*.refshoot 0 =
*.refaimdx 1 =
*.refeye 0 =
*.memval 86 !=
*.numties 0 =
start
86 .tie store
stop

cond
*.robage 0 >
*.numties 0 =
*.eye5 0 =
*.memval 86 = or
*.refshoot 0 != or
*.refaimdx 1 != or
*.refeye 0 != or
start
314 rnd .aimdx store
stop

'*************************************************************

' Set tie and unfix veg

cond
*.numties 1 =
*.treffixed 1 =
start
86 .tienum store
.fixpos .tieloc store
0 .tieval store
stop

cond
*.numties 1 =
*.multi 0 =
*.done 0 =
start
.done inc
628 .fixang store
15 .fixlen store
86 .tienum store
.fixang .tieloc store
628 .tieval store
86 .readtie store
stop

'*************************************************************

' When tied to a vegetable

cond
*.myeye *.trefeye =
start
*.tiepres .deltie store
stop

cond
*.numties 0 =
start
0 *.shell sub .mkshell *.shell sgn mult store
.done *.done sgn mult dec
stop

'*************************************************************

' Sharing and producing

cond
*.multi 1 =
start
75 .sharenrg store
50 .shareslime store
50 .shareshell store
.sharewaste inc
*.pleas 3 div .strbody *.pleas sgn mult store
*.pleas 3 div .mkslime *.pleas sgn mult store
600 *.shell sub .mkshell store
stop

' Shooting and tracking genes for when I become an MB

' Shoot

cond
*.multi 1 =
*.eye5 0 >
*.refeye *.myeye !=
*.memval 86 !=
start
-32 .shootval store
-6 .shoot store
stop

cond
*.multi 1 =
*.eye5 45 >
*.refeye *.myeye !=
*.memval 86 !=
start
32 .shootval store
-6 .shoot store
stop

' Move

cond
*.multi 1 =
*.eye5 0 =
*.memval 86 = or
*.refeye *.myeye = or
*.roam 100 <
start
100 .aimdx store
.roam inc
stop

cond
*.roam 99 >
*.multi 1 =
*.eye5 0 =
*.memval 86 = or
*.refeye *.myeye = or
start
100 .up store
.roam inc
stop

cond
*.roam 200 >
start
0 .roam store
stop

' Aim and chase

cond
*.multi 1 =
*.eye5 0 >
*.refeye *.myeye !=
*.memval 86 !=
start
*.refxpos *.refypos angle .setaim store
*.refveldx .aimdx store
stop

cond
*.multi 1 =
*.eye5 0 >
*.eye5 30 <
*.refeye *.myeye !=
*.memval 86 !=
start
*.refvelup *.refvelup add 60 add .up store
stop

'*************************************************************

' Reproduction

cond
start
10 .repro *.body 5000 sub sgn mult *.multi sgn mult store
stop

cond
*.nrg 100 <
start
*.body 100 ceil .fdbody *.body sgn mult store
stop

'*************************************************************

' Shoot back at annoying enemies

cond
*.shflav 0 !=
*.shflav -2 !=
*.multi 1 =
*.shoot 0 =
*.refeye 0 = or
start
1256 *.shang sub .aimshoot store
64 .shootval store
-6 .shoot store
0 .shflav store
stop

' Antiviral (for replicating viruses)

cond
*.mkvirus 0 !=
start
*.mkvirus .delgene store
stop

' Junk DNA (for conspecific recognition)

cond
start
*.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5
stop

end
I think this is Shen's Evobot

Code: [Select]

def newmom 50

' - Birth -
cond
*.robage 0 =
start
.newmom inc
stop

cond
*.newmom 0 >
start
.newmom inc
stop

cond
*.newmom 200 =
start
0 .newmom store
stop

cond
*.nrg 10000 >
start
30 rnd 20 add .repro store
1 .newmom store
stop


' - Avoid Babies -
cond
*.eye5 0 >
*.newmom 0 >
start
400 .aimsx store
stop


' - Move -
cond
*.vel 10 <
*.eye5 50 <
start
5 .up store
40 80 rnd sub .aimsx store
stop

' - Eye -
cond
*.eye2 *.eye8 >
*.eye5 0 =
start
100 .aimsx store
10 .sx store
stop

' - Eye -
cond
*.eye8 *.eye2 >
*.eye5 0 =
start
-100 .aimsx store
-10 .sx store
stop

' - Eat -
cond
*.newmom 0 =
*.eye5 40 >=
start
-1 .shoot store
stop


end

23

Bot Tavern / Discerpo Inscribo

« on: December 03, 2006, 05:24:36 PM »

Don't be sorry, you were just trying to help

24

Newbie / Winners and losers update on league progress

« on: December 03, 2006, 12:31:27 PM »

Wait...why is this in the newbie forum?

25

Bot Tavern / Discerpo Inscribo

« on: December 03, 2006, 12:28:18 PM »

You can do anything you like in F1, the bots can be as nasty and devious as you wish.  

EDIT

Btw, if you don't want to keep quoting the last post just click on add reply at bottom rather than reply on post.

yes, not to sound rude or anything but I know, for me it just works better, because than you can be sure of whom I am replying to, not to mention its easier to reach

26

DNA - General / Energy Shooting Virus

« on: December 03, 2006, 12:25:54 PM »

Something such as

cond
  *.eye5 20 >
  *.vtimer 1 =
start
  40 .vshoot store
stop

would fire your virus when it sees something, the number stored in .vshoot determines how far the virus travels, the higher the number the greater distance but the more energy used you would also want to add some cospec recognition so you dont shoot at your own bots.

Thanks, I will add it to my bot

27

Newbie / Winners and losers update on league progress

« on: December 03, 2006, 09:25:34 AM »

Jez doesn't have that kind of power, the force is weak in him  

but I  remember him moving topics around...

28

Bot Tavern / Discerpo Inscribo

« on: December 03, 2006, 09:23:32 AM »

Oops! May well be my fault that your bot died Kage.  Yours was probably the first one I tested which is why I made this post. You may have noticed that more bots that I tested died v veg than survived, including every one of my bots that I tested!!  

If you have downloaded the latest version of DB then you will be able to see how well it is doing for yourself, it has been suggested that it is the waste setting causing this problem so I'll be trying all the bots that couldn't cope again; after changing the waste setting.

AFAIK (I'm familiar with the old versions of DB not the latest ones but it should still be the same ) slime is a defence against ties. It doesn't cause your bot any harm to have slime when you don't need it, all it is doing then is costing nrg to make! It used to be that you could only have slime or shell but I'm not sure that is true still. I'll check the wiki in a while and make sure.

I am running all the leagues as one at the moment. Depending on the result I may then title that the F1 league and reinstate all the old leagues, that's why I am adding the (F1) or (F2) etc bits to the bots names, they'll be easier to sort back into individual leagues and we'll be able to see at a glance which are the dominant types of bots.

What I normally do if I change a bot, power it up lots or add ties etc, but keep the original design of an old bot is simply add a V2 or V1.1 to it. That way you keep the old bot and have a recognisable new bot while keeping track of how the new bot developed.
F2 simply means you can't use ties for feeding, it's fine to use ties in other ways though.

Can we leech in F1 if someone else ties to us?

29

DNA - General / Energy Shooting Virus

« on: December 03, 2006, 09:21:00 AM »

Sorry, but what would the gene be, I guess I never put it in to any of my bots and that would explain why they aren't firing their virus

30

Newbie / Winners and losers update on league progress

« on: December 03, 2006, 09:18:30 AM »

Apparently not, I haven't got round to checking yet though.  

EDIT

Mine was set to -1  

Eric! Could you lock the other settings as well if you hit the F1 league conditions tick? Things like max vel, collision elasticity, fluid resistance. Anything that can be changed really that isn't locked when F1 league conditions are meant to apply. Unless they already are but just not showing it...

You mean I might not of been slaughtered?  

Jez, couldn't you just keep moving the topic back and forth, like you could move it back to a forum you could post on and then move it back instead of creating multiple topics?