Topics

16

Veggies / VegSwarm (Veg)(Elite)-10.03.07

« on: March 11, 2007, 08:32:00 AM »

' VegSWARM
'
' A vegetable that swarms

cond
start
.tie 1 *.robage sub 0 floor mult inc
.deltie inc
*.maxvel *.vel sub .up store
*.eye1 *.eye9 sub 2 mult .aimdx store
stop

cond
*.robage 0 =
start
1220 .eye5width store
stop

' Swarm

cond
*.eye5 0 >
*.refeye *.myeye =
*.robage 5 mod 0 =
start
*.refaim .setaim *.robage sgn mult store
stop

' Reproduce

cond
*.robage 50 mod 0 =
*.nrg 7000 1000 rnd sub >
start
50 .repro store
stop

end

17

Veggies / Veg known to be missing from download folder

« on: March 11, 2007, 08:30:41 AM »

VegSwarm (Veg)(Elite)-10.03.07

18

F2 bots / Ratticus Rex (F2)(Jez)-27.02.07

« on: February 27, 2007, 11:59:41 AM »

Code: [Select]

'The non spinning bot with a very big bite!

'unnofficially came first in F1 and F2
'losing a max of one round in any match

'simply written and not bug fixed, this bot shouldn't be much of a
'challenge for the rest of you to beat...

cond
*.robage 0 =
start
1 .tie store
stop

cond
*.eye5width 1221 !=
start
1221 .eye5width store
stop

'target and move
cond
*.memval *.genes !=
*.eye5 0 >
start
*.refxpos *.refypos angle .setaim store
*.refxpos *.refypos dist 500 div *.maxvel mult *.refvel add 0 floor
*.maxvel ceil .up store
*.veldx .sx store
-6 .shoot store
*.body 100 div .shootval store
stop

'repro
cond
*.paralyzed 0 =
*.poisoned 0 = or
*.pwaste 10000 > or
start
100 .repro store
stop

cond
*.nrg 30000 >=
start
50 .repro store
stop

'avoid friends
cond
*.memval *.genes =
start
5 .up store
*.refxpos *.refypos angle 628 add .setaim store
stop

cond
*.numties 0 >
start
*.tiepres .deltie store
stop

cond
*.waste 500 >
start
*.waste .shootval store
-4 .shoot store
stop

cond
*.nrg 2000 >
*.body 10000 <
start
100 .strbody store
stop

cond
*.nrg 200 <
start
100 .fdbody store
stop

'memloc check
cond
.genes .memloc !=
start
.genes .memloc store
*.thisgene 1 add .delgene store
stop

19

Off Topic / A couple of evo stories

« on: February 24, 2007, 11:59:44 PM »

Just a couple of reports I have seen recently on the internet;

Chimps hunting with spears

Robot swarms 'evolve' effective communication

20

Bugs and fixes / In game DNA display

« on: February 14, 2007, 03:48:32 AM »

Checking the code for Strangers bot in game it looked strange; where he had finished the gene with a mult (-store) the genes were joined and it seemed to add some partially random 0's to the code.
(gene 14 0 0 and 0 0 cond... ie)

Just wanted to know if this was affecting the bots performance or there was a reason for this.

21

F1 bots / Potismuss Terminator 2.0 (F1)(Mutchy)-26.09.04

« on: February 02, 2007, 05:49:43 PM »

Code: [Select]

'Topic: New Bots
'Mutchy
'Potissimus Terminator 2.0
'modified by PY

'gene far left eye
cond
*.eye1 *.eye5 >
*.eye5 *.eye5 =
start
mult -104
stop

'gene far right eye
cond
*.eye9 *.eye5 >
start
mult 104
stop

'gene middle left eye
cond
*.eye3 *.eye5 >
start
mult -52
stop

'gene middle right eye
cond
*.eye7 *.eye5 >
start
mult 52
stop

'gene fire!
cond
*.eye5 71 !=
*.eye5 40 >
*.refeye *.myeye !=
*.robage 0 >
start
-1 .shoot store
stop

'gene makin babies .new condition of eye5 = 0 from PY
cond
*.nrg 2500 >
*.eye5 0 =
start
50 .repro store
0 .shoot store
stop


'gene im not lazy?
cond
*.vel 30 <
*.refeye *.myeye !=
*.numties 0 =
start
30 *.vel sub .up store
stop


cond
*.robage 0 =
start
330 .tie store
stop


cond
*.numties 0 =
start
0 66 store
stop

'*************new****************
cond
*.eye5 40 >
*.refaimdx *.myaimdx !=
start
-6 .shoot store
stop

cond
*.fixed 0 !=
start
0 .fixpos store
stop

'new gene from PY to fix position for feeding
cond
*50 1 =
*.trefeye *.myeye !=
start
20 .tienum store
0 .fixang store
100 .fixlen store
0 50 store
stop

cond
*.multi 1 =
start
1 50 store
stop

'gene run away from friends
cond
*.refeye *.myeye =
start
mult -180
stop

'gene mult
cond
start
.aimdx store
stop

' modified by PY
cond
*.eye5 28 >
*.refeye *.myeye !=
*.numties 0 =
start
20 .tie store
20 .readtie store
stop

' delete ties to family
cond
*.trefeye *.myeye =
start
20 .deltie store
stop

cond
*.body 2000 <
*.nrg 2000 >
start
100 .strbody store
stop

cond
*.tiepres 0 !=
*.numties 0 >
*66 0 =
start
*.tiepres .tienum store
20 .tieval store
.tieval .vloc store
1000 .venval store
-3 .tieloc store
stop


end

22

F1 bots / Shimazu fixed (F1)(henk)(03-02-2007)

« on: February 02, 2007, 05:49:05 PM »

Code: [Select]

'Patched by PY for V2.3
'Shimazu

'reset out1
cond
*.eye5 0 =
*.in1 1 =
*.robage 100 >
start
0 .out1 store
stop

'Identify as Shimazu
cond
*.out1 1 !=
start
1
.out1
store
stop

'reproduce. Long survival required to do so, to avoid lucky suckers
cond
*.nrg 9000 >
*.robage 500 >
*.robage 600 <
start
50 .repro store
628 .aimsx store
50 50 store
stop

cond
*.nrg 9000 >
*.robage 600 =
*50 50 !=
start
50 .mrepro store
628 .aimsx store
stop

' repro to continue really good bots
cond
*.nrg 10000 >
*.robage 2000 >
start
50 .repro store
628 .aimdx store
50 50 store
stop

cond
*.repro 50 =
*.numties 1 =
*.trefeye 0 =
*.trefnrg 1000 <
start
31 .deltie store
stop

'kill
cond
*.eye5 0 >
*.in1 1 !=
*.robage 100 >
start
-1 .shoot store
stop

'Engage tie
cond
*.eye5 30 >
*.in1 1 !=
*.numties 0 =
*.robage 100 >
*.robage < 500
start
31 .tie store
-3 .shoot store 20 .shootval
0 .refnrg store
2 40 store
stop

'Engage tie 2
cond
*.eye5 30 >
*.in1 1 !=
*.numties 0 =
*.robage 100 >
*.robage > 600
start
31 .tie store
-3 .shoot store 20 .shootval
0 .refnrg store
2 40 store
stop

cond
*40 2 =
start
2 .tielen store
1 40 store
stop

'Feed
cond
*.numties 0 >
*.trefup 0 =
start
31 .tienum store
-1000 .tieval store
-1 .tieloc store
100 .sharenrg store
stop

'read the tie
cond
*.numties 0 >
*.robage 100 >
start
31 .readtie store
stop

cond
*.trefup 0 >
*.eye5 0 =
start
31 .deltie store
stop

'move when seeing something
cond
*.eye5 0 >
*.robage 100 >
*.tie 31 !=
*.numties 0 =
start
10 .up store
stop

'move when seeing nothing
cond
*.eye5 0 =
*.robage 100 >
*.tie 31 !=
*.numties 0 =
start
10 .up store
stop

cond
*.nrg 1000 >
*.venom 30000 <
start
10 .strvenom store
stop

cond
*.eye1 *.eye9 !=
*.numties 0 =
start
*.eye9 *.eye1 sub 4 mult .aimdx store
stop

cond
*.eye2 *.eye8 !=
*.numties 0 =
start
*.eye8 *.eye2 sub 3 mult .aimdx store
stop

cond
*.eye3 *.eye7 !=
*.numties 0 =
start
*.eye7 *.eye3 sub 2 mult .aimdx store
stop

cond
*.eye4 *.eye6 !=
*.numties 0 =
start
*.eye6 *.eye4 sub .aimdx store
stop

cond
*.refage 100 <
*.robage 100 <
*.eye5 0 >
start
314 .aimdx store
0 .refage store
stop

cond
*.robage 0 =
start
314 .aimdx store
stop

cond
*.shdx -1 =
start
314 .aimdx store
31 .tie store
stop

cond
*.shsx -1 =
start
-314 .aimdx store
31 .tie store
stop

cond
*.shdn -1 =
start
628 .aimdx store
31 .tie store
stop

cond
*.shup -1 =
start
31 .tie store
stop

cond
*.in1 1 =
start
314 .aimdx store
stop

cond
*.eye5 0 =
*.in1 1 =
start
0 .in1 store
stop

end

23

Short bots / Random Virus Shooter(a) (F1)(vir)(K0zm0)-07.11.04

« on: February 02, 2007, 05:48:24 PM »

Code: [Select]

'Topic: Virus
'K0zm0
'
*.fixed 0 =
start
10 .up store
-2 .shoot store
50 .mrepro store
stop

cond
*.eye5 30 >
*.refeye *.myeye !=
start
-1 .shoot store
stop

cond
*.vtimer 0 =
start
87 .aimdx store
*50 .mkvirus store
*.genes rnd 50 store
500 .vshoot store
1 .fixpos store
stop
end

24

F1 bots / Venator (F1)(Mutchy)-18.07.04

« on: February 02, 2007, 05:47:32 PM »

Code: [Select]

'Topic: New Bots
'Mutchy

Venator
F1 League
' Engage tie to non-Venator
cond
*.eye5 33 >
*.refeye *.myeye !=
start
31 .tie store
stop

' Feed through tie
cond
*.numties 0 >
start
31 .tienum store
-1000 .tieval store
-1 .tieloc store
'100 .sharenrg store
stop

cond
*.slime 90 <
start
100 .mkslime store
stop

'gene
cond
*.tienum 31 !=
*.numties 0 >
start
*.tienum .deltie store
stop

'gene2
cond
*.eye5 34 <
start
26 .aimdx store
stop


'gene run away from friends
cond
*.refeye *.myeye =
*.eye5 0 >
start
27 .aimdx store
1 .dn store
stop

'gene makin babies
cond
*.nrg 5000 >
start
50 .repro store
stop

cond
*.robage 0 =
start
1 .tie store
stop

'gene no tie
'cond
'*.numties 0 !=
'*.robage 1 =
'start
'1 .deltie store
'stop

'gene
cond
*.eye5 0 >
*.refeye *.myeye !=
*.eye5 34 <
start
5 *.vel sub .up store
stop
end

25

F1 bots / Venator(a) (F1)(Mutchy)-16.10.04

« on: February 02, 2007, 05:46:55 PM »

Code: [Select]

'Topic: Bot Tuning
'Mutchy
'
'Venator!
' Engage tie to enemy
cond
*.eye5 33 >
*.refeye *.myeye !=
start
31 .tie store
stop

' Feed through tie
cond
*.numties 0 >
start
31 .tienum store
-1000 .tieval store
-1 .tieloc store
stop

cond
*.slime 90 <
start
100 .mkslime store
stop

'gene fire!
cond
*.eye5 40 >
*.refeye *.myeye !=
start
-6 .shoot store
stop

'gene
cond
*.tienum 31 !=
*.numties 0 >
start
*.tienum .deltie store
stop

'gene2
cond
*.eye5 34 <
start
26 .aimdx store
stop


'gene run away from friends
cond
*.refeye *.myeye =
*.eye5 0 >
start
27 .aimdx store
1 .dn store
stop

'gene makin babies
cond
*.nrg 3000 >
start
50 .repro store
stop

cond
*.robage 0 =
start
1 .tie store
stop

'gene no tie
'cond
'*.numties 0 !=
'*.robage 1 =
'start
'1 .deltie store
'stop

'gene
cond
*.eye5 0 >
*.refeye *.myeye !=
*.eye5 34 <
start
5 *.vel sub .up store
stop

cond
*.shdn 0 <
*.pleas -10 <
start
620 .aimsx store
stop

cond
*.hitdn 0 !=
start
620 .aimsx store
stop

' Anti tie gene
' Evil anti-tie gene.
cond
*.tiepres 1 !=
*.tiepres 2 !=
*.numties 0 >
start
*.tiepres .tienum store
.tieval .tieloc store
1000 .tieval store
stop

cond
*.body 2000 <
*.nrg 1000 >
start
200 .strbody store
stop


end

26

F1 bots / Vex Obnoxious (F1)(PYmod)(03-02-2007)-pre V2.3

« on: February 02, 2007, 05:46:08 PM »

Code: [Select]

'Patched by PY for V2.3
' Vex Obnoxious

cond
*.robage 0 =
start
1 900 rnd 77 store
*77 .readtie store
stop

cond
*.vel 28 <
start
30 *.vel sub .up store
stop

cond
*.eye1 *.eye5 >
start
*.eye1 .aimsx store
stop

cond
*.eye9 *.eye5 >
start
*.eye9 -1 mult .aimsx store
stop

cond
*.eye3 *.eye5 >
start
-52 .aimdx store
stop

cond
*.eye7 *.eye5 >
start
52 .aimdx store
stop


cond
*.eye5 30 >
*.refeye 12 !=
*.refaimdx 5 !=
start
*77 .tie store
0 .aimdx store
0 .aimsx store
-1 .shoot store
stop

cond
*.numties 0 >
start
*77 .tienum store
-1000 .tieval store
-1 .tieloc store
stop

cond
*.trefeye 12 =
*.numties 0 >
*.trefaimdx 5 =
start
*77 .deltie store
stop

cond
*.eye5 0 !=
*.refeye 12 =
*.refaimdx 5 =
start
628 .aimdx store
stop

cond
*.nrg 6000 >
start
25 .repro store
628 .aimdx store
stop

cond
*.slime 95 <
start
100 *.slime sub .mkslime store
stop

cond
*.waste 10 >
start
*.waste .strpoison store
stop
end

27

F1 bots / Xar (F1)(K0zm0)-30.08.04

« on: February 02, 2007, 05:45:16 PM »

Code: [Select]

'Topic: New Bots
'K0zm0
'Xar
'Made by k0zm0
'30.aug.2004
'version 3
cond
*.robage 0 =
start
999 rnd 70 store
60 inc
stop

cond
*.slime 100 <
start
100 *.slime sub .mkslime store
stop

cond
*.numties 0 !=
start
*70 .readtie store
stop

cond
*.trefeye *.myeye =
start
*.tiepres .deltie store
stop

cond
*.body 200 <
*.nrg 2000 >
start
100 .strbody store
stop

cond
*.body 400 >
start
100 .fdbody store
stop

cond
*.eye5 25 >
*.numties 3 !=
*.refeye *.myeye !=
start
*70 .tienum store
*70 .tie store
stop

cond
*.nrg 6000 >
start
add 628
50 .repro store
stop

cond
*.numties 0 =
*.eye5 0 =
start
0 multi
stop

cond
*.numties 0 =
*.eye5 26 <
*.eye9 0 =
start
100 add
stop

cond
*.numties 0 =
*.eye5 26 <
*.eye9 0 >
start
*.eye9 *.eye1 sub add
stop

cond
*.numties 0 =
*.eye5 24 <
start
*.eye6 *.eye4 sub add
stop


cond
*.numties 0 =
*.eye5 0 =
*.vel 20 <
start
0 multi
20 .vel sub .up store
stop

cond
*.numties 0 =
start
.aimdx store
stop

cond
*.eye5 25 >
*.refeye 0 =
start
-1 .shoot store
stop

cond
*.ref
*.refnrg *.nrg <
*.eye5 25 >
*.refeye *.myeye !=
*.refeye 0 !=
start
-1 .shoot store
stop

cond
*.refnrg *.nrg >
*.eye5 25 >
*.refeye *.myeye !=
start
-6 .shoot store
stop

cond
*50 2 !=
start
50 inc
stop

cond
*50 2 =
start
0 50 store
stop

cond
*50 1 =
start
*70 .tienum store
-1 .tieloc store
-1000 .tieval store
stop

cond
*50 0 =
*.numties 0 >
start
*70 .tienum store
*.aim .tieval store
.setaim .tieloc store
stop
end

28

F1 bots / Xar 1 (F1)(PYmod)-20.09.04

« on: February 02, 2007, 05:44:39 PM »

Code: [Select]

'Topic: Leagues?
'K0zm0
'PY's fixed version of K0zm0's Xar.
'
'Xar
'Made by k0zm0
'30.aug.2004
'version 3
cond
*.robage 0 =
start
999 rnd 70 store
60 inc
stop

cond
*.slime 100 <
start
100 *.slime sub .mkslime store
stop

cond
*.numties 0 !=
start
*70 .readtie store
stop

cond
*.trefeye *.myeye =
start
*.tiepres .deltie store
stop

cond
*.body 200 <
*.nrg 2000 >
start
100 .strbody store
stop

cond
*.body 400 >
start
100 .fdbody store
stop

cond
*.eye5 25 >
*.numties 3 !=
*.refeye *.myeye !=
start
*70 .tienum store
*70 .tie store
stop

cond
*.nrg 6000 >
start
mult
628
50 .repro store
stop

cond
*.numties 0 =
*.eye5 0 =
start
mult
0
stop

cond
*.numties 0 =
*.eye5 26 <
*.eye9 0 =
start
mult
100
stop

cond
*.numties 0 =
*.eye5 26 <
*.eye9 0 >
start
mult
*.eye9 *.eye1 sub
stop

cond
*.numties 0 =
*.eye5 24 <
start
mult
*.eye6 *.eye4 sub
stop


cond
*.numties 0 =
*.eye5 0 =
*.vel 20 <
start
mult
0
20 *.vel sub .up store
stop

cond
*.numties 0 =
start
.aimdx store
stop

cond
*.eye5 25 >
*.refeye 0 =
start
-1 .shoot store
stop

cond
*.ref
*.refnrg *.nrg <
*.eye5 25 >
*.refeye *.myeye !=
*.refeye 0 !=
start
-1 .shoot store
stop

cond
*.refnrg *.nrg >
*.eye5 25 >
*.refeye *.myeye !=
start
-6 .shoot store
stop

cond
*50 2 !=
start
50 inc
stop

cond
*50 2 =
start
0 50 store
stop

cond
*50 1 =
start
*70 .tienum store
-1 .tieloc store
-1000 .tieval store
stop

cond
*50 0 =
*.numties 0 >
start
*70 .tienum store
*.aim .tieval store
.setaim .tieloc store
stop
end

29

F1 bots / Paranoia1 (F1)(Eight)-02.09.04

« on: February 02, 2007, 05:43:46 PM »

Code: [Select]

'Topic: New Bots
'Eight

' Paranoia 1  by Eight (eightland.com)
' identifies enemy types and tries to act accordingly.

' pee in pool
cond
*.waste 100 >
start
100 .shootval store
1 .backshot store
-4 .shoot store
stop

' bored
cond
*.eye5 0 =
start
40 .aimsx store
stop

' see friend
cond
*.eye5 0 >
*.refaimdx *.myaimdx =
start
80 .aimsx store
stop

' sproing
cond
*.sun 1 =
*.vel 0 =
start
30 .up store
stop

' unfix bot if frozen.
cond
*.fixed 1 =
start
0 .fixpos store
stop

' if target is tie with lower energy, shoot -1
cond
*.eye5 0 >
*.refaimdx *.myaimdx !=
*.reftie 0 >
*.refnrg *.nrg <
start
45 inc
-1 .shoot store
stop

' if target is tie with higher energy, shoot -6
cond
*.eye5 0 >
*.refaimdx *.myaimdx !=
*.reftie 0 >
*.refnrg *.nrg >
start
45 inc
-6 .shoot store
stop

' if has seen tiefeeder, make slime and scent
cond
*45 0 >
*.slime 100 <
*.nrg *.slime >
start
50 .mkslime store
stop

' if has seen tiefeeder, make poison and scent
cond
*45 0 >
*.poison 100 <
*.nrg *.poison >
start
50 .mkpoison store
stop

' send scent
cond
*45 0 >
start
.out1 inc
stop

' pick up scent
cond
*.in1 0 >
start
45 inc
stop

' if target is poisonous, shoot it.
cond
*.eye5 30 >
*.refaimdx *.myaimdx !=
*.refpoison 0 >
start
-6 .shoot store
stop

' if target is venomous, keep distance and try to disable it.
cond
*.eye5 30 >
*.refaimdx *.myaimdx !=
*.refvenom 0 >
*.reffixed 0 =
start
5 .dn store
1 .shootval store
216 .shoot store
stop

' approach frozen bot.
cond
*.eye5 30 <
*.refaimdx *.myaimdx !=
*.reffixed 1 =
start
5 .up store
stop

' pick at frozen bot and back away.
cond
*.eye5 30 >
*.refaimdx *.myaimdx !=
*.reffixed 1 =
start
5 .dn store
-1 .shoot store
stop

' if hit with a body shot, heal self
cond
*.shup -6 =
*.body *.nrg !%=
start
50 .mkshell store
50 .strbody store
stop

' if hit with a body shot, heal self
cond
*.shsx -6 =
*.body *.nrg !%=
start
50 .mkshell store
50 .strbody store
5 .sx store
stop

' if hit with a body shot, heal self
cond
*.shdx -6 =
*.body *.nrg !%=
start
50 .mkshell store
50 .strbody store
5 .dx store
stop

' if hit with a body shot, heal self
cond
*.shdn -6 =
*.body *.nrg !%=
start
50 .mkshell store
50 .strbody store
-1 .backshot store
5 .up store
stop

' if hit with energy shot, restore energy
cond
*.shup -1 =
*.body *.nrg !%=
start
50 .fdbody store
stop

' if hit with energy shot, restore energy
cond
*.shsx -1 =
*.body *.nrg !%=
start
50 .fdbody store
60 .aimsx store
stop

' if hit with energy shot, restore energy
cond
*.shdx -1 =
*.body *.nrg !%=
start
50 .fdbody store
60 .aimdx store
stop

' if hit with energy shot, restore energy
cond
*.shdn -1 =
*.body *.nrg !%=
start
100 .fdbody store
-6 .backshot store
628 .aimdx store
stop

' bumped
cond
*.eye5 80 >
*.refaimdx *.myaimdx !=
*.refnrg *.nrg <
*.hitup 0 !=
start
-1 .shoot store
stop

' bumped
cond
*.eye5 80 >
*.refaimdx *.myaimdx !=
*.refnrg *.nrg >
*.hitup 0 !=
start
-6 .shoot store
stop

' bumped
cond
*.hitsx 0 !=
start
300 .aimsx store
stop

' bumped
cond
*.hitdx 0 !=
start
300 .aimdx store
stop

' bumped
cond
*.hitdn 0 !=
start
628 .aimdx store
stop

' eyes
cond
*.eye1 *.eye9 !=
*.refaimdx *.myaimdx !=
start
*.eye1 *.eye9 sub 2 mult .aimsx store
*.eye1 *.eye9 sub 2 div .sx store
stop

' eyes
cond
*.eye3 *.eye7 !=
*.refaimdx *.myaimdx !=
start
*.eye3 *.eye7 sub 2 div .aimsx store
stop

' eyes
cond
*.eye4 *.eye6 !=
*.refaimdx *.myaimdx !=
start
*.eye4 *.eye6 sub 4 div .aimsx store
stop

' eyes
cond
*.eye4 0 >
*.refaimdx *.myaimdx !=
start
5 .up store
stop

' launch
cond
*.robage 0 =
start
30 .dn store
stop

' pounce
cond
*.eye5 0 >
*.refaimdx *.myaimdx !=
*.maxvel *.vel >
start
*.maxvel 5 div .up store
stop

' see, attach tie and feed
cond
*.eye5 30 >
*.numties 0 =
*.refaimdx *.myaimdx !=
*.refup 0 =
start
600 rnd 2 add .tie store
stop

' tie present
cond
*.tiepres 0 >
start
*.tiepres .readtie store
1 .fixpos store
stop

' disconnect friend
cond
*.numties 0 >
*.tiepres 0 >
*.trefaimdx *.myaimdx =
start
*.readtie .deltie store
stop

' eat
cond
*.numties 0 >
*.tiepres 0 >
*.trefaimdx *.myaimdx !=
start
*.readtie .tienum store
-1000 .tieval store
-1 .tieloc store
stop

' repro
cond
*.numties 0 =
*.eye5 50 <
*.nrg 5000 >
start
50 .repro store
stop

end

30

F1 bots / Kyushu(a) (F1)(Mutchymod)-29.10.04

« on: February 02, 2007, 05:43:13 PM »

Code: [Select]

'Topic: Bot Tuning
'Mutchy
'
'Patched by PY for V2.3
' Kyushu Bot modified to run in V2.3
' Tie bot
' Combat Bot
' By Henk

' ********** General Genes **********

' Get waste out of the way.
cond
*.waste 100 >
start
-4 .shoot store
*.waste .shootval store
stop

' ********** nonsense genes to identify **********

cond
*.nrg 0 =
start
-1 .shoot store
-1 .shoot store
-1 .shoot store
-1 .shoot store
stop

' ********** TIE Genes **********

' Engage tie
cond
*.eye5 30 >
*.refshoot *.myshoot !=
start
*55 .tie store
-6 .shoot store
stop

cond
*.robage 1 =
*.numties 0 >
start
99 .readtie store
stop

' Feed through tie when it's a non-veg
cond
*.numties 0 >
*.trefshoot *.myshoot !=
*.trefeye 0 >
start
100 .sharenrg store
.fixang .tieloc store
628 .tieval store
stop

' feed when it's a veg
' Fixed a problem here. He was looking for
' trefeye <> 0. Veggies have ONE eye not zero
' PY

cond
*.robage 0 =
start
99 .readtie store
stop

cond
*.trefshoot *.myshoot !=
*.trefeye 1 =
start
*55 .tienum store
-1 .tieloc store
-1000 .tieval store
stop


' ********** Move genes **********
cond
*.numties 0 =
start
40 *.vel sub .up store
stop

' ********** Follow Genes **********
cond
*.eye1 *.eye9 >
*.eye1 *.eye5 >
*.numties 0 =
start
-102 .aimdx store
stop

cond
*.eye9 *.eye1 >
*.eye9 *.eye5 >
*.numties 0 =
start
102 .aimdx store
stop

cond
*.eye4 *.eye6 >
*.eye4 *.eye5 >
start
-26 .aimdx store
stop

cond
*.eye6 *.eye4 >
*.eye6 *.eye5 >
*.numties 0 =
start
26 .aimdx store
stop

' ********** Species genes **********

' turn away from other Kyushu.
cond
*.refshoot *.myshoot =
*.eye5 20 >
start
314 .aimdx store
stop

' delete tie to fellow Kyushu
cond
*.trefshoot *.myshoot =
*.numties 0 >
start
*55 .deltie store
stop

' ********** Initiating genes **********

' Tie to father. Or is it a mother?
cond
*.robage 0 =
start
.tie inc
900 rnd 1 add 55 store
stop

‘ delete tie again and store tie phase in .readtie
cond
*.robage 1 =
start
.deltie inc
*55 .readtie store
stop

' make shell
cond
*.shell 50 <
start
50 *.shell sub .mkshell store
stop

' ********** Repro Genes **********

' Turn back to food. I hope.
cond
*41 0 >
start
628 .aimdx store
41 dec
stop

' Reproduce
cond
*.nrg 4500 >
*.robage 50 >
start
50 .repro store
628 .aimdx store
41 inc
stop

' Evil anti-tie gene.
cond
*.tiepres *55 !=
*.numties 0 >
start
*.tiepres .tienum store
.tieval .tieloc store
1000 .tieval store
stop

cond
*.eye5 40 >
*.refshoot *.myshoot !=
start
-6 .shoot store
stop

cond
*.body 2000 <
*.nrg 2000 >
start
200 .strbody store
stop

cond
*.robage 0 =
start
1 .readtie store
stop

cond
*.numties 0 >
*.trefshoot *.myshoot !=
start
0 .fixang store
stop

end