Topics

1

Evolution and Internet Sharing Sims / duel sim eco

« on: February 28, 2017, 11:38:06 PM »

so i had an idea about evolving complex ecosystems. have 2 separately evolving sims starting from the same or close to the same settings and bots(this would be similar to my duel evo sims both plant and animal evolving). when they both evolve a good bit to be considered different species, put in a temporary teleport in both to allow interactions between them. after a short time then delete the teleports and allow them to evolve separately for a while once more and repeat. what do you guys think about it and if anyone has done anything like this what was their results.. maybe this will get the forum a bit more active for a little bit...

2

Evolution and Internet Sharing Sims / dule evo sim

« on: June 09, 2016, 11:00:33 PM »

so i made an alga that could survive animal minimal in a thin fluid environment with a decent sim size of 9 so i could run it with a good relative speed (5 cycles/sec) instead of the .1 - 1 a few days ago... day one the alga had around 10 mutations and animal had about half that. looking at the graphs i had going (pop and avg mut) the alga was shooting up in mutations where animal had flat lined  alga had finaly stalled in mutations at around 15 and animal was still stuck at .. 5 mutations. the pop was at about 500-600 for alga and animal still struggles to stay at around 100. if there was ever a time good mutations to happen it would be now but lack of pop is making that very difficult for the animal. here are the before and after bots.

alga before:

Code: [Select]

cond
*971 0 =
*.nrg 100 >
*.daytime 1 =
start
10 .mkchlr store
stop

cond
*.nrg 20000 >
start
50 .repro store
stop

cond
*.pain 10 >
*971 0 =
start
50 971 store
10 .repro store
314 rnd .aimsx store
stop

cond
*971 0 >
start
*.body 5 sub .fdbody store
10 .dn store
971 dec
stop

cond
*.robage 100 <
start
*.chlr .rmchlr store
stop


alga current:

Code: [Select]

cond
 *971 0 =
 *.nrg 100 >
 *.tieang2 *.mkvirus =
 start
 10 .mkchlr store
 stop
''''''''''''''''''''''''  Gene:  1 Ends at position  15  '''''''''''''''''''''''

''''''''''''''''''''''''  Gene:  2 Begins at position  16  '''''''''''''''''''''''
 cond
 *.nrg 20000 >
 *.refaim 50 .repro dec
 stop
''''''''''''''''''''''''  Gene:  2 Ends at position  24  '''''''''''''''''''''''

''''''''''''''''''''''''  Gene:  3 Begins at position  25  '''''''''''''''''''''''
 cond
 *.robage 100 <
 store
 stop
''''''''''''''''''''''''  Gene:  3 Ends at position  30  '''''''''''''''''''''''

''''''''''''''''''''''''  Gene:  4 Begins at position  31  '''''''''''''''''''''''
 cond
 *.pain 10 >
 *.trefsx *.tin1 *.in1 start
 50 971 store
 10 .repro store
 314 rnd .aimleft store
 stop
''''''''''''''''''''''''  Gene:  4 Ends at position  49  '''''''''''''''''''''''

''''''''''''''''''''''''  Gene:  5 Begins at position  50  '''''''''''''''''''''''
 cond
 *971 0 >
 start
 *.body store
 *.eye5dir *.eye5 .fdbody store
 *.eye6 .dn store
 971 dec
 *.chlr .rmchlr store
 stop
''''''''''''''''''''''''  Gene:  5 Ends at position  69  '''''''''''''''''''''''


animal before:

Code: [Select]

'Animal_Minimalis
'By: Nums
'Good for mutation sims and for
'newbies to see how a basic bot works.
'Contains everything necessary for it
'to survive and reproduce.

' Gene 1 Food Finder
cond
 *.eye5 0 >
 *.refeye *.myeye !=
start
 *.refveldx .dx store
 *.refvelup 30 add .up store
stop

' Gene 2 Eat Food
cond
 *.eye5 50 >
 *.refeye *.myeye !=
start
-1 .shoot store
 *.refvelup .up store
stop

' Gene 3 Avoiding Family
cond
 *.eye5 0 =
 *.refeye *.myeye = or
start
 314 rnd .aimdx store
stop

' Gene 4 Reproduce
cond
 *.nrg 20000 >
start
 10 .repro store
stop

end

animal after:

Code: [Select]

cond
 *.eye5 0 *.rmchlr *.refnrg *.myeye !=
 start
 *.refveldx .dx store
 *.refvelup 30 add .up store
 stop
''''''''''''''''''''''''  Gene:  1 Ends at position  17  '''''''''''''''''''''''

''''''''''''''''''''''''  Gene:  2 Begins at position  18  '''''''''''''''''''''''
 cond
 *.eye5 50 >
 *.bodgain *.myeye !=
 start
 -1 .shoot store
 *748 .up store
 stop
''''''''''''''''''''''''  Gene:  2 Ends at position  32  '''''''''''''''''''''''

''''''''''''''''''''''''  Gene:  3 Begins at position  33  '''''''''''''''''''''''
 cond
 *.eye5 0 =
 store
 *.myeye =
 or
 start
 *.timer rnd .aimright store
 stop
''''''''''''''''''''''''  Gene:  3 Ends at position  46  '''''''''''''''''''''''

''''''''''''''''''''''''  Gene:  4 Begins at position  47  '''''''''''''''''''''''
 cond
 *.nrg 20000 >
 start
 10 .repro store
 stop
''''''''''''''''''''''''  Gene:  4 Ends at position  55  '''''''''''''''''''''''

all in all not what i expected but hay that's evolution for ya

3

Bugs and fixes / posible vegi repop bug

« on: November 04, 2015, 09:21:13 PM »

dbnovegi is where i killed all vegies to trigger the spawning event and modified the settings to repop every cycle threshold isn't met.
db1vegi is where only one vegi spawned at the spawning event

sets for this example:

100 max chloroplasts
5 threshold
5 bots per spawning
1 cycle per spawning event (to spawn every cycle)

now if i'm right it should have spawned 5 bots (green) rather than just one

4

Bugs and fixes / desablechlr

« on: October 31, 2015, 09:35:59 AM »

disable chlr doesn't seem to work. animal min has chlr

5

Bugs and fixes / poison and venom not working

« on: April 19, 2015, 01:50:08 AM »

i know it's a bit late for bugs but i just found a pretty big one.

i was messing around with poison but nothing i put into it works like it should or rather at all. and i just checked venom and it doesn't work either.

cond
*.shflav 0 !=
*.shflav -2 !=
start
50 .vloc store
50 .venval store
1 .strvenom store
*.shang .aimshoot store
-3 .shoot store
stop

cond
*.nrg 30000 >
start
314 rnd .aimdx store
50 .repro store
stop


'Gene 3 I was born!
cond
*.robage 0 =
start
180 .aimdx store
stop


'Gene 4 Moving out

'Gene 5 Almost moved out
cond
*.robage 10 <
start
10 .up store
stop

this is the bot i've been playing with just switching out the poison and venom but doesn't even change basic memory.

6

RANT / code

« on: March 24, 2015, 12:39:00 AM »

ok i am moving this section from db3 section to here to avoided filling up the topic there of arguing

from spike43884:

And most of the things I try a lot on, especially before asking, it makes sense now the Abs, but elsewhere its been explained in ways, among other things in DB code, which make it seem messy. Plus, even messy code you can eventually understand, some of the biggest programming languages have inefficiencies and parts which are messy, take JAVA for example, when you run a program, it'll tell you that you have an error, but unlike python and such won't tell you where the error is. With java, good lord, everythings forced to be so long and thousands and thousands of lines of code are needed for simple programs, 1 error, not a clue where it is, not a clue what the error is. A mere inefficiency. The more efficient, and easy DB code is, the better for new people coming on. Plus, if the programming is easy then it could help people that don't know much about DNA and such understand it more, as even though its not perfect to real life, its probably one of the best, if not the best open source, free simulators out there. Then to top it off, the more simplistic the code for darwinbots the better, as DNA is made up of 4 bases, its that simple, of course we couldn't right in that easily (unless your steven hawkins maybe?) so it needs to be abbreviated into common, or relatively quick to work out, and well explained abbreviations, and commands. These commands then need multiple assets able to be given to them, thus when combined with other commands or operators, and intergers it can perform an almost endless array of tasks.

i understand you were a little annoyed by my little rant and i admit that i went a little overboard on it but consider my side for a minute. in all the code i have given you have you tried to understand it or did you just put it in and hope for the best. seeing that you still didn't even know abs that tells me that you just put it in. if you did try but couldn't understand it why didn't you ask for help to do so.

the way i see it code it's self is not messy unless the coder(human, evo, ect.) is messy (which is usually the case)

i hope this helps you understand where i'm coming from.

how good are at math specially in algebra?
i ask this because this is basically all db dna is.

also java does have crash catching systems that you put in the code. though it would be frequently it would catch any crashes. i saw a few tutorials and clearly remember that much as i was trying to learn it but lost my attention because of how bored i got from the tutorials. (i'm more of a show me all the commands and what they mean in a list (preferably organized) and show me how to structure it and i'm good to go.)

7

Bot Tavern / zero evo behavior

« on: March 06, 2015, 12:17:57 AM »

observing my 0 bot evo sim i found a bot that actually reacted to what it sees, but when i looked at the dna i found absolutely no direct reason for it.


 start
 *493 *.pwaste *.refage 526 *.up 522 *.eye7 *.tieang .vtimer store
 floorstore
 <
 -11 *.pleas -40 *.trefvelmysx *.shootval *.tielen store
''''''''''''''''''''''''  Gene:  1 Ends at position  20  '''''''''''''''''''''''

the only thing i could come up with was the floorstore was affecting the *.eye7 in the previous line. i tested and found that only when something was in eye7 that it moved. this puts a whole new spin on how the dna really works and how bots can be built. too bad this bot doesn't repro. come to think of it all the other bots i have no idea how they repro either. they do all kinds of things like shooting viruses and deleting their dna. i'm confused


 start
 *493 *.pwaste *.refage 526 *.up 522 *.eye7 0 .refxpos store
 *.refvelscalar store
 -11 *.pleas -40 store
 *.shootval *.tielen *.shang''''''''''''''''''''''''  Gene:  1 Ends at position  20  '''''''''''''''''''''''

this was just the best chosen by the program which was a virus infection as the last mutation. 50 bots optimal for start with feeder vegies if you want to watch/evo yourself.

8

Simulation Emporium / free large evo sim

« on: January 10, 2015, 06:20:45 PM »

i started with a difficult environment with modified bots and they evolved very differently than i expected them to. i thought the animals would stay moving forward but they move to the side now instead. the alga ties to everything to move away from them but at the same time spins frantically. i see why they do what they do and it still surprises me.

9

Interesting behaviour bots / animal_minimal_gender(Shadowgod2)(interesting)(10-8-2014)

« on: December 07, 2014, 12:30:47 AM »

Code: [Select]

'animal_minamal_gender
'by Shadowgod2
'12/6/2014
'gender based bot
'you will need female version
'males fight eachother because they will take over otherwise

def male 50
def female 51

cond
*.refeye *.myeye =
*.refbody *.male mult 1000 < and
*.eye5 0 = or
start
100 rnd *.female 2 mult 1 sub mult .aimdx store
stop

cond
*.refeye *.myeye =
*.refbody *.male mult 1000 > and
*.refeye *.myeye != or
*.eye5 0 >
start
*.refveldx .dx store
*.refvelup 30 add .up store
stop

cond
*.eye5 50 >
*.refeye *.myeye !=
*.refeye *.myeye =
*.in1 1 sub *.male mult -1 = and or
start
-1 .shoot store
*.refveldx .dx store
*.refvelup 30 add .up store
stop

cond
start
1 .male store
-8 .shoot *.in1 mult *.refbody 1000 sub sgn 0 floor mult store
stop

start
1 rnd 2 mult 1 sub *.thisgene add .delgene *.robage sgn -1 mult 1 add mult store
*.thisgene .delgene *.robage sgn mult store
stop

cond
start
1 .female store
1 .out1 store
50 .sexrepro *.fertilized sgn mult *.body 1000 sub sgn 0 floor mult store
stop

end


10

Interesting behaviour bots / NeuralNetv1(Shadowgod2)(11-12-2014)(interesting behavior)

« on: November 13, 2014, 12:51:13 AM »

Code: [Select]

'Neural Net Bot by Shadowgod2
'a new type of neuron that enables chanales
'11-22-2014 11:43pm

'neuron setup
'*ni1 * *nw1 mult *np1 * *npm1 sub sgn 0 floor mult
'*ni2 * *nw2 mult *np2 * *npm2 sub sgn 0 floor mult add
'*ni3 * *nw3 mult *np3 * *npm3 sub sgn 0 floor mult add n store
'*px1 * *npm1 sub sgn 0 floor
'*px2 * *npm2 sub sgn 0 floor add
'*px3 * *npm3 sub sgn 0 floor add np store

def reproing 181
def muttype 182
def nimut 183
def mut 184
def mutage 185

start
10 .mut store
100 .mutage store
*.thisgene .delgene store
stop

'mutations

'type
cond
*.robage *.mutage >
*.reproing 0 =
start
6 rnd *.mut rnd -1 mult 1 add 0 floor mult .muttype store
stop

'muataion chance

cond
*.muttype 1 =
start
10 5 sub *.mut add 32000 ceil 10 floor .mut store
0 .muttype store
stop

'nnet mut

cond
*.muttype 2 =
start
29 rnd 20 add add .nimut store
13 rnd 140 add *.nimut store
*.nimut * 14 add *.nimut 30 add store
0 .muttype store
stop

cond
*.muttype 3 =
start
29 rnd 80 add .nimut store
10 rnd 5 sub *.nimut * add 32000 ceil -32000 floor *.nimut store
0 .muttype store
stop

cond
*.muttype 4 =
start
29 rnd 110 add .nimut store
2 rnd *.nimut store
0 .muttype store
stop

'output mut

cond
*.muttype 5 =
start
4 rnd 168 add .nimut store
13 rnd 154 add *.nimut store
*.nimut * 14 add *.nimut 8 add store
0 .muttype store
stop

cond
*.muttype 6 =
start
3 rnd 172 add .nimut store
2 rnd *.nimut store
0 .muttype store
stop

'input
cond
*.reproing 0 =
start
*.eye5 140 store
3 154 store
*.refeye 141 store
3 155 store
*.nrg 142 store
3 156 store
*.refvelup 143 store
3 157 store
'nnet
*20 * *80 mult *50 * *110 sub sgn 0 floor mult
*21 * *81 mult *51 * *111 sub sgn 0 floor mult add
*22 * *82 mult *52 * *112 sub sgn 0 floor mult add 144 store
*50 * *110 sub sgn 0 floor
*51 * *111 sub sgn 0 floor add
*52 * *112 sub sgn 0 floor add 158 store
                                   
*23 * *83 mult *53 * *113 sub sgn 0 floor mult
*24 * *84 mult *54 * *114 sub sgn 0 floor mult add
*25 * *85 mult *55 * *115 sub sgn 0 floor mult add 145 store
*53 * *113 sub sgn 0 floor
*54 * *114 sub sgn 0 floor add
*55 * *115 sub sgn 0 floor add 159 store
                                     
*26 * *86 mult *56 * *116 sub sgn 0 floor mult
*27 * *87 mult *57 * *117 sub sgn 0 floor mult add
*28 * *88 mult *58 * *118 sub sgn 0 floor mult add 146 store
*56 * *116 sub sgn 0 floor
*57 * *117 sub sgn 0 floor add
*58 * *118 sub sgn 0 floor add 160 store
                                         
*29 * *89 mult *59 * *119 sub sgn 0 floor mult
*30 * *90 mult *60 * *120 sub sgn 0 floor mult add
*31 * *91 mult *61 * *121 sub sgn 0 floor mult add 147 store
*59 * *119 sub sgn 0 floor
*60 * *120 sub sgn 0 floor add
*61 * *121 sub sgn 0 floor add 161 store
                                       
*32 * *92 mult *62 * *122 sub sgn 0 floor mult
*33 * *93 mult *63 * *123 sub sgn 0 floor mult add
*34 * *94 mult *64 * *124 sub sgn 0 floor mult add 148 store
*62 * *122 sub sgn 0 floor
*63 * *123 sub sgn 0 floor add
*64 * *124 sub sgn 0 floor add 162 store
                                     
*35 * *95 mult *65 * *125 sub sgn 0 floor mult
*36 * *96 mult *66 * *126 sub sgn 0 floor mult add
*37 * *97 mult *67 * *127 sub sgn 0 floor mult add 149 store
*65 * *125 sub sgn 0 floor
*66 * *126 sub sgn 0 floor add
*67 * *127 sub sgn 0 floor add 163 store
                                     
*38 * *98 mult *68 * *128 sub sgn 0 floor mult
*39 * *99 mult *69 * *129 sub sgn 0 floor mult add
*40 * *100 mult *70 * *130 sub sgn 0 floor mult add 150 store
*68 * *128 sub sgn 0 floor
*69 * *129 sub sgn 0 floor add
*70 * *130 sub sgn 0 floor add 164 store
                                     
*41 * *101 mult *71 * *131 sub sgn 0 floor mult
*42 * *102 mult *72 * *132 sub sgn 0 floor mult add
*43 * *103 mult *73 * *133 sub sgn 0 floor mult add 151 store
*71 * *131 sub sgn 0 floor
*72 * *132 sub sgn 0 floor add
*73 * *133 sub sgn 0 floor add 165 store
                               
*44 * *104 mult *74 * *134 sub sgn 0 floor mult
*45 * *105 mult *75 * *135 sub sgn 0 floor mult add
*46 * *106 mult *76 * *136 sub sgn 0 floor mult add 152 store
*74 * *134 sub sgn 0 floor
*75 * *135 sub sgn 0 floor add
*76 * *136 sub sgn 0 floor add 166 store
                                 
*47 * *107 mult *77 * *137 sub sgn 0 floor mult
*48 * *108 mult *78 * *138 sub sgn 0 floor mult add
*49 * *109 mult *79 * *139 sub sgn 0 floor mult add 153 store
*77 * *137 sub sgn 0 floor
*78 * *138 sub sgn 0 floor add
*79 * *139 sub sgn 0 floor add 167 store
stop
'output
cond
*168 *172 >
*.reproing 0 =
start
*176 * .up store
stop

cond
*169 *173 >
*.reproing 0 =
start
*177 * .aimsx store
stop

cond
*170 *174 >
*.reproing 0 =
start
-1 .shoot store
stop

cond
*171 *175 >
*.reproing 0 =
start
*179 * .repro store
stop
'repro

cond
*.reproing 2 =
start
*180 .tieloc store
*180 * .tieval store
180 inc
*180 28 add 180 *180 140 sub abs -1 mult 1 add mult store
100 .stifftie store
20 .fixlen store
stop

cond
*180 179 >
start
0 .reproing store
1 .deltie store
stop

cond
*.numties 0
*.trefage 3 >
*.reproing 1 = and or
start
0 .reproing store
stop

cond
*.numties 0 !=
*.trefage 3 <= or
*.reproing 1 =
start
2 .reproing store
20 180 store
stop

cond
*.reproing 1 =
start
1 .tie store
1 .tienum store
stop

cond
*.repro 0 >
start
1 .reproing store
stop
end
still a bit buggy but works very well seeing i only managed to start testing today.

11

F1 bots / TurbulentSwarm2_f1_Shadowgod2_11-2-2014

« on: November 02, 2014, 09:43:24 PM »

geared up

Code: [Select]

'an unstable_swarming bot which does scatter easly with very diffirent eyes
'now geared up
'by Shadowgod2
'11/2/2014
'f1

def robage1 50
def attack 52
def trig 55
def eyet1 56
def eyet2 57
def eyetimer1 58
def eyetimer2 59
def eyecheck 60

'eyepos

cond
*.robage 5 <
start
-575 .eye2dir store
575 .eye8dir store
-130 .eye1dir store
130 .eye9dir store
-291 .eye3dir store
291 .eye7dir store
-100 .eye4dir store
100 .eye6dir store
280 .eye2width store
280 .eye8width store
-34 .eye1width store
-34 .eye9width store
149 .eye3width store
149 .eye7width store
93 .eye4width store
93 .eye6width store
-34 .eye5width store
2 rnd 518 mult 511 sub 1 floor .ploc store
 314 *.ploc .eye5dir sub sgn 1 add mult
 -50 *.ploc .up sub sgn -1 mult 1 add mult add
 -2 *.ploc .shoot sub sgn abs -1 mult 1 add mult add
 .pval store
stop


'reconization

cond
*.refeye *.myeye !=
*.eyef 0 != and
*.refbody 500 > and
start
1 .attack store
*.refxpos *.refypos angle .setaim store
0 .eye5dir store
0 .focuseye store
1 .out1 store
stop

'comunization

cond
*.refeye *.myeye =
*.eyef 0 = or
start
0 .attack store
0 .out1 store
stop

cond
*.in1 1 =
*.attack 0 =
start
*.refxpos *.refypos angle 50 *.focuseye sgn -1 mult mult add .setaim store
*.refvelup *.refxpos *.refypos dist debugint 900 sub 10 ceil -10 floor add 10 floor .up store
stop


'swarm

cond
*.attack 0 =
*.refeye *.myeye = and
*.focuseye -3 > and
*.focuseye 3 < and
*.in1 0 = and
start
*.refxpos *.refypos angle 70 *.focuseye sgn -1 mult mult add .setaim store
*.refvelup *.refxpos *.refypos dist debugint 900 sub 10 ceil -10 floor add 10 floor .up store
stop

'lonehunt

cond
*.attack 0 =
*.eyef 0 =
start
10 .up store
stop

'feed

cond
*.shflav -2 !=
*.attack 0 =
start
*.shang .setaim store
stop

cond
*.refeye *.myeye !=
*.eye5 0 > and
*.attack 1 = and
start
*.refvelup *.refxpos *.refypos dist debugint 500 sub 30 ceil -30 floor add .up store
1 rnd 5 mult 6 sub .shoot *.eye5 20 sub sgn 0 floor mult store
*.nrg 40 div 500 sub 10 floor *.shoot 2 add 0 floor mult .shootval store
stop

'eyescanning

start
.robage1 inc
stop

cond
*.robage1 32000 =
start
0 .robage1 store
stop

cond
*.attack 0 =
*.eyet1 0 >= and
*.eyet2 0 >= and
start
*.robage1
*.eye2 sgn
*.eye3 sgn add
*.eye4 sgn add
*.eye5 sgn add
*.eye6 sgn add
*.eye7 sgn add
*.eye8 sgn add
mod 1 add .eyecheck store
stop

start
0 .fixpos store
stop

'eyeslecting

cond
*.attack 0 =
start
*.eye2 sgn 61 store
*.eye2 sgn *.eye3 sgn add 62 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add 63 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add 64 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add *.eye6 sgn add 65 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add *.eye6 sgn add *.eye7 sgn add 66 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add *.eye6 sgn add *.eye7 sgn add *.eye8 sgn add 67 store
stop

cond
*.attack 0 =
*.eyecheck *61 =
start
-3 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *62 = and
*62 *61 != and
start
-2 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *63 = and
*63 *62 != and
start
-1 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *64 = and
*64 *63 != and
start
0 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *65 = and
*65 *64 != and
start
1 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *66 = and
*66 *65 != and
start
2 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *67 = and
*67 *66 != and
start
3 .focuseye store
stop

cond
*.attack 0 =
*.eye9dir 130 >=
start
1 .trig store
stop

cond
*.attack 0 =
*.eye9dir -480 <=
start
0 .trig store
stop

'wisker scanning

cond
*.attack 0 =
*.trig 1 =
start
*.eye1dir 10 add .eye1dir store
*.eye9dir 10 sub .eye9dir store
stop

cond
*.attack 0 =
*.trig 0 =
start
*.eye9dir 10 add .eye9dir store
*.eye1dir 10 sub .eye1dir store
stop

'eye1

cond
*.focuseye -4 =
*.refeye *.myeye =
start
5 .eyetimer1 store
stop

cond
*.eye1 0 >
*.eyet1 0 = and
*.eyetimer1 0 = and
*.attack 0 = and
start
-4 .focuseye store
-1 .eyet1 store
stop

cond
*.eyetimer1 0 >
start
.eyetimer1 dec
stop

cond
*.eye1 0 >
*.eyet1 -1 = and
*.refeye *.myeye = and
start
3 .eyet1 store
stop

cond
*.eye1 0 =
*.eyet1 -1 =
start
0 .eyet1 store
stop

cond
*.eyet1 0 >
start
.eyet1 dec
stop

'eye9

cond
*.focuseye 4 =
*.refeye *.myeye =
start
5 .eyetimer2 store
stop

cond
*.eye9 0 >
*.eyet2 0 = and
*.eyetimer2 0 = and
*.attack 0 = and
start
4 .focuseye store
-1 .eyet2 store
stop

cond
*.eyetimer2 0 >
start
.eyetimer2 dec
stop

cond
*.eye9 0 >
*.eyet2 -1 = and
*.refeye *.myeye = and
start
3 .eyet2 store
stop

cond
*.eye9 0 =
*.eyet2 -1 =
start
0 .eyet2 store
stop

cond
*.eyet2 0 >
start
.eyet2 dec
stop

'shell/poison

cond
*.nrg 1000 >
*.poison 100 <
start
100 .strpoison store
stop

cond
*.nrg 1000 >
*.shell 500 <
start
100 .mkshell store
stop

cond
*.slime 1000 <
*.nrg 1000 >
start
100 .mkslime store
stop

'repro

cond
*.nrg 20000 >
start
50 .repro store
314 rnd .aimsx store
stop

12

F3 bots / TurbulentSwarm(f3,f2,f1)(Shadowgod2)(11-2-2014)

« on: November 02, 2014, 03:21:45 PM »

a surprisingly good bot at least against animal_minamals.

Code: [Select]

'an unstable_swarming bot which does scatter easly with very diffirent eyes
'by Shadowgod2
'11/2/2014
'f1,f2,f3


def robage1 50
def attack 52
def mytienum 53
def trig 55
def eyet1 56
def eyet2 57
def eyetimer1 58
def eyetimer2 59
def eyecheck 60

'eyepos

cond
*.robage 5 <
start
-575 .eye2dir store
575 .eye8dir store
-130 .eye1dir store
130 .eye9dir store
-291 .eye3dir store
291 .eye7dir store
-100 .eye4dir store
100 .eye6dir store
280 .eye2width store
280 .eye8width store
-34 .eye1width store
-34 .eye9width store
149 .eye3width store
149 .eye7width store
93 .eye4width store
93 .eye6width store
-34 .eye5width store
31999 rnd .mytienum store
stop


'reconization

cond
*.refeye *.myeye !=
*.eyef 0 !=
start
1 .attack store
*.refxpos *.refypos angle .setaim store
0 .focuseye store
1 .out1 store
stop

'comunization

cond
*.refeye *.myeye =
*.eyef 0 = or
start
0 .attack store
0 .out1 store
stop

cond
*.in1 1 =
*.attack 0 =
start
*.refxpos *.refypos angle 50 *.focuseye sgn -1 mult mult add .setaim store
*.refvelup *.refxpos *.refypos dist debugint 900 sub 10 ceil -10 floor add 10 floor .up store
stop


'swarm

cond
*.attack 0 =
*.refeye *.myeye = and
*.focuseye -3 > and
*.focuseye 3 < and
*.in1 0 = and
start
*.refxpos *.refypos angle 70 *.focuseye sgn -1 mult mult add .setaim store
*.refvelup *.refxpos *.refypos dist debugint 900 sub 10 ceil -10 floor add 10 floor .up store
stop

'lonehunt

cond
*.attack 0 =
*.eyef 0 =
start
10 .up store
stop

'feed

cond
*.refeye *.myeye !=
*.eye5 0 > and
*.attack 1 = and
start
*.refvelup *.refxpos *.refypos dist debugint 500 sub 10 ceil -10 floor add .up store
-1 .shoot *.eye5 20 sub sgn 0 floor mult store
stop

'eyescanning

start
.robage1 inc
stop

cond
*.robage1 32000 =
start
0 .robage1 store
stop

cond
*.attack 0 =
*.eyet1 0 >= and
*.eyet2 0 >= and
start
*.robage1
*.eye2 sgn
*.eye3 sgn add
*.eye4 sgn add
*.eye5 sgn add
*.eye6 sgn add
*.eye7 sgn add
*.eye8 sgn add
mod 1 add .eyecheck store
stop

'eyeslecting

cond
*.attack 0 =
start
*.eye2 sgn 61 store
*.eye2 sgn *.eye3 sgn add 62 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add 63 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add 64 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add *.eye6 sgn add 65 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add *.eye6 sgn add *.eye7 sgn add 66 store
*.eye2 sgn *.eye3 sgn add *.eye4 sgn add *.eye5 sgn add *.eye6 sgn add *.eye7 sgn add *.eye8 sgn add 67 store
stop

cond
*.attack 0 =
*.eyecheck *61 =
start
-3 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *62 = and
*62 *61 != and
start
-2 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *63 = and
*63 *62 != and
start
-1 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *64 = and
*64 *63 != and
start
0 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *65 = and
*65 *64 != and
start
1 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *66 = and
*66 *65 != and
start
2 .focuseye store
stop
cond
*.attack 0 =
*.eyecheck *67 = and
*67 *66 != and
start
3 .focuseye store
stop

cond
*.attack 0 =
*.eye9dir 130 >=
start
1 .trig store
stop

cond
*.attack 0 =
*.eye9dir -480 <=
start
0 .trig store
stop

'wisker scanning

cond
*.attack 0 =
*.trig 1 =
start
*.eye1dir 10 add .eye1dir store
*.eye9dir 10 sub .eye9dir store
stop

cond
*.attack 0 =
*.trig 0 =
start
*.eye9dir 10 add .eye9dir store
*.eye1dir 10 sub .eye1dir store
stop

'eye1

cond
*.focuseye -4 =
*.refeye *.myeye =
start
5 .eyetimer1 store
stop

cond
*.eye1 0 >
*.eyet1 0 = and
*.eyetimer1 0 = and
*.attack 0 = and
start
-4 .focuseye store
-1 .eyet1 store
stop

cond
*.eyetimer1 0 >
start
.eyetimer1 dec
stop

cond
*.eye1 0 >
*.eyet1 -1 = and
*.refeye *.myeye = and
start
3 .eyet1 store
stop

cond
*.eye1 0 =
*.eyet1 -1 =
start
0 .eyet1 store
stop

cond
*.eyet1 0 >
start
.eyet1 dec
stop

'eye9

cond
*.focuseye 4 =
*.refeye *.myeye =
start
5 .eyetimer2 store
stop

cond
*.eye9 0 >
*.eyet2 0 = and
*.eyetimer2 0 = and
*.attack 0 = and
start
4 .focuseye store
-1 .eyet2 store
stop

cond
*.eyetimer2 0 >
start
.eyetimer2 dec
stop

cond
*.eye9 0 >
*.eyet2 -1 = and
*.refeye *.myeye = and
start
3 .eyet2 store
stop

cond
*.eye9 0 =
*.eyet2 -1 =
start
0 .eyet2 store
stop

cond
*.eyet2 0 >
start
.eyet2 dec
stop

'nrg/body

cond
*.body 3000 <
*.nrg 10000 >
start
100 .strbody store
stop

cond
*.nrg 1000 <
start
100 .fdbody store
stop

'repro

cond
*.nrg 20000 >
start
50 .repro store
314 rnd .aimsx store
stop
and attachment for easier download.

13

Bugs and fixes / eye bug

« on: October 25, 2014, 09:18:33 PM »

eye's aren't triggering until nearly half way. snap shot shows just outside triggering but well within the eye sight

14

Off Topic / personalities now illiness

« on: October 25, 2014, 02:09:32 AM »

i thought you guys should read this. just another thing wrong with people today.

http://earthweareone.com/nonconformity-and-freethinking-now-considered-mental-illnesses/

15

Simulation Emporium / large free eco sim

« on: September 18, 2014, 01:07:16 AM »

the sim is over 374 hours and 14 mil cycles. the sets have been slowly moded to current to prevent extinction. animal_minimal ans alga_mininal_chlr used. alga doesn't make chlr all the time anymore. number of bots are very stable. sim runs at an avg of 10 cycles/sec. enjoy