Messages

46

Newbie / Re: Best thing ever

« on: July 01, 2012, 12:13:29 AM »

For whate ikke said:

Code: [Select]

' Show I'm fertilized
cond
*.fertilized 0 >
start
' Display my fertilize status
*.fertilized .out1 store
stop

' Sex with unfertilized only
cond
*.eye5 50 >
*.refeye *.myeye =
' Are they fertilized?
*.in1 0 =
start
-8 .shoot store
stop
The in/out pairs are a nice way to communicate for many different things.

For attacking parents and children, you can put in *.robage conditions in the shoot and follow genes. Like shoot and follow only *.refage 10 >
And only shoot and follow when I'm *.robage 10 >

I like ikke's suggestion of making them only sexrepro with sperm they have more kills with.

You probably saw it by now, but the Sysvar page is the best page on the wiki in my opinion. http://wiki.darwinbots.com/w/Sysvar

47

Newbie / Re: Best thing ever

« on: June 29, 2012, 03:43:44 PM »

I think it is broken now, but it sounds like it made an awesome looking graph. And it was supposed to split species in 2.
 http://forum.darwinbots.com/index.php/topic,2910.msg1377954.html#msg1377954

The genetic distance and generation distance graphs are also broken.

48

Newbie / Re: Best thing ever

« on: June 29, 2012, 12:02:57 AM »

cond
 *.eye5 -10 >

That makes it so the bot always does that gene even when it doesn't see something. (because eye5 is always at least 0 which is > -10)

As a result, the bot stops moving to the side and starts accelerating 30 when it doesn't see a bot, because the refvel resets to 0.

If you have this as a plant, then it probably helped it run away from predators because it always moves now.

49

Newbie / Re: Best thing ever

« on: June 28, 2012, 10:25:01 PM »

Toroidal means that the world loops around both east west and north south. The bots go up and come out the bottom, go right and come out the left. It's default for F1 conditions.

Veggies will mutate if "disable mutations" is unchecked (1).  You can also change the species and different rate of mutations in "mutations rates" (2).
I circled the stuff in the attached screen shot.

50

Newbie / Re: Best thing ever

« on: June 28, 2012, 07:20:58 PM »

It would seem that the problem arises when .aimdx becomes .aimright

Aimdx means aimright. For some reason in the program it lists it as that.

The problem really is that the veggies got "cancerous" by sticking an "else" in the repro gene. The bot reproduces unless it has more than 30000 nrg now.

Cancerous veggies are a very very very common mutation with veggies. Cancer bots aren't because they just die...

Edit: I still don't know of a good way to make veggies not cancerous... Try setting the veggy energy option to "kilobody point" That makes it so small veggies don't get as much nrg as big plants. (and cancer plants start out small) Also try lowering the nrg they get.

51

Newbie / Re: Best thing ever

« on: June 28, 2012, 06:07:28 PM »

' Gene 4 Reproduce
cond
 *.nrg 1000 >
start
 10 .repro store
stop
end

 FYI You have two reproduce genes, the first needs 6000 nrg but the second only needs 1000, so the first will not turn on.
The first turns the bot to make sure it has room.

I agree with Nums, there probably are bots in the way.

You could have it turn it the gene you want to use. Most likely the second repro gene.

Edit: Your moss is very interesting to watch, it forms little clumps that run away/follow at a distance predators.

52

Newbie / Re: Best thing ever

« on: June 28, 2012, 05:29:34 PM »

3. Is there any methodology that allows bots to mix their code to form an offspring?

Like Nums said.
You could have it shoot sperm randomly when it sees something, and then .sexrepro when it is fertilized.

Code: [Select]

'Put this after your -1 .shoot store gene
cond
*.eye5 40 >
20 rnd 1 =
start
-8 .shoot store
stop

cond
*.nrg 10000 >
*.fertilized 0 >
start
30 .sexrepro store
stop
This would work for a cannibot also. 

2. Just try and get meaningful evolution as quickly as possible.

An advanced way of evolving fast is to have only important values in the bot change as it reproduces.  You can do this by using Racial Memory that lets the bots pass down the values they used with a chance to change them. http://wiki.darwinbots.com/w/Racial_memory

Code: [Select]

'Define names for the variables
def repronrg 971
def distance 972

'How far away to start shooting
cond
*.eye5 *.distance >
start
-1 .shoot store
stop

'How much nrg for repro
cond
*.nrg *.repronrg >
start
30 .repro store
stop

'Randomly change the values when young
cond
*.robage 100 <
10000 rnd 1 =
start
'Randomly add subtract up to 5 from value
*.distance -5 10 rnd add add .distance store
*.repronrg -5 10 rnd add add .repronrg store
stop

'Set the first values
cond
*.distance 0 =
*.repronrg 0 =
start
50 .distance store
10000 .repronrg store
stop
For that ^ you should have mutations disabled (in options).  Then when they get better, you look at the best bot's memory at 971 and 972. 

Is there a way to run two simulations at once?

Page 5 here has a nice tutorial on how to set up connect sims. (I havent had a chance to try it though) http://forum.darwinbots.com/index.php/topic,486.60.html

p.s. Hope I wrote the code right nums.

53

Bug reports / Re: Regular Ties don't form with vision disabled 2.45.01

« on: June 09, 2012, 01:41:13 AM »

I thought it was a bug because a bot does not necessary need to know there is a bot in front of it to tie to it. I found this while testing my blind bot against the bots posted here: http://forum.darwinbots.com/index.php/topic,3549.0.html (The blind bot challenge).

The 2 blind bots here work by firing ties randomly and sharing energy. They don't make any reference to eyes so they should be able to work with vision disabled.
In fact, most of the ref values can be used with touch now and still work with vision disabled.

This limitation or bug makes it more difficult for blind bots to evolve with vision disabled because they can't be multy bots or use tie feeding.

Therefore I think it is a bug and should not be by design.

P.S. The ties I am referring to are the ties initiated by bots, not the birth tie. The birth tie does indeed form with vision disabled.

54

Bug reports / Re: Quadratic Plant Energy 2.45.01 [False Alarm]

« on: June 07, 2012, 07:38:25 PM »

That sounds good. It's a lot more direct (need body to get energy).

But there's no need to change if you don't want to change. 

55

Bug reports / Re: Quadratic Plant Energy 2.45.01

« on: June 06, 2012, 11:04:32 PM »

Yep sorry, false alarm. It follows your equation.

It doesn't work like I expected it. I thought that little plants would barely get any energy, but like you said they get what's in the box, just big plants get way more.

Is there a way we can get rid of that constant (241/256)?  That way little plants get no energy and DIE :Muahaha:

...ya probably not a very good idea... I'll just set the energy to 50 times less than what I want... 

56

Bug reports / Quadratic Plant Energy 2.45.01 [False Alarm]

« on: June 06, 2012, 05:17:46 AM »

I don't think this setting is working in 2.45.01 

I'll have to stick with kilobody...

57

Bug reports / Regular Ties don't form with vision disabled 2.45.01

« on: June 06, 2012, 12:10:32 AM »

For some reason, I can't get regular ties to form when the bot's vision is disabled. In version 2.45.01

Attached is a save featuring different tie forming bots, none of them will form permanent ties.

58

Bot Challenges / Re: Blind bot

« on: June 04, 2012, 01:50:32 PM »

I used the version that Num (Thanks) fixed here: http://forum.darwinbots.com/index.php/topic,1249.0.html, File: http://forum.darwinbots.com/index.php?action=dlattach;topic=1249.0;attach=949
This is 2.45.01 with a .shflav and .shang fix.

The original post for this contest was to not use ref values, but now ref values work with vision disabled, for collisions, so Maybe we can use them now?

I have another bot I'm making that beats this bot, but it uses ref values.

59

Bot Challenges / Re: Blind bot

« on: May 30, 2012, 04:52:14 PM »

It's a year late, but I want to post my bot also. It beats every bot here. It uses echolocation using shots. Don't worry, I made it without knowing about the contest. (a couple days ago)
Animal Resono 1.0

Code: [Select]

' Animal_Resono_1.0 (F2)(Tilthan) 30.05.12
' Also Blind Bot, Interesting Behavior

' This bot does not use any eyes and can run with vision disabled
' It uses info shots as conspec recognition, I'm in the process of changing this so it can be in F3
' It is the only bot I know of that uses echolation using shots
' I'm very proud that it can beat some bots with eyes (A_Minimalis...)
' A side effect of it's conspec is that it makes a mine field and plays pinball
' Version 1.1 is in the bestiary.

def guess 50
def search 51

def me 52
def age 10
def power 32


' 1 Get Mom Tie
cond
*.robage 0 =
start
.tie inc
stop

' 2 Get Rid of Mom Tie
cond
*.robage 1 =
start
.deltie inc
stop

' 3 Get Away from Mom
cond
*.robage .age <
*.vel 180 <
start
10 .dn store
stop

' 4 Find Food, Start Sonar
cond
300 *.nrg div 5 add rnd 0 =
and
*.guess 0 =
and
*.robage .age >
start
100 rnd 100 add .aimdx store
-1 .shoot store
.search inc
stop

' 5 Find Food, Get Sonar
cond
*.shang 0 >
and
*.robage .age >
and
*.me 0 =
start
*.shang .aimdx store
3 .guess store
*.velup -1 mult .up store
*.veldx -1 mult .dx store
0 .search store
stop

' 6 Tell Comrades to Move
cond
*.guess 1 =
start
.me .shoot store
.shootval inc
.guess dec
stop

' 7 Shoot at Food
cond
*.guess 1 >
start
-6 .shoot store
.power .shootval store
.guess dec
stop

' 8 Migrate for more Food
cond
*.search 600 >
*.nrg 500 >
start
-100 .up store
0 .search store
stop

' 9 Unstick if stuck
cond
*.fixed 0 >
start
0 .fixpos store
stop

'''''''''''Better movement hopefully
' 10 Shot Front, move forward
cond
*.shdn 0 !=
start
*.up -10 add .up store
stop

' 11 Shot Back, move back
cond
*.shup 0 !=
start
*.up 10 add .up store
stop

' 12 Shot Right, Move Right
cond
*.shdx 0 !=
start
*.dx 10 add .dx store
stop

' 13 Shot Left, Move Left
cond
*.shsx 0 !=
start
*.dx -10 add .dx store
stop

' 14 Body Maintenence
cond
*.nrg 1120 >
*.body 500 <
start
100 .strbody store
stop

' 15
cond
*.nrg 1000 <
*.body 50 >
start
100 .fdbody store
stop

' 16 If Fam warns me or If I hit Fam, Move
cond
*.me 0 !=
and
*.robage 0 !=
start
0 .guess store
284 rnd 120 add .aimdx store
-80 .up store
0 .me store
stop

' 17 Reproduce
cond
*.nrg 10000 >
and
*.pleas 0 %=
'and
'*.robage .age >
start
30 .repro store
stop

end
P.S. Version 1.1 of this bot is better, but uses ref values, but now ref values work on blind bots, so it is still blind.
Also I used Nums current .shang fix (2) http://forum.darwinbots.com/index.php/topic,1249.0.html

60

Untagged bots / Animal_Resono_1.3 (F3)

« on: May 30, 2012, 04:44:01 PM »

One day I had the greatest idea, I should make a bot that was blind. I thought I should use echolocation as his main sense, and it is. Upon looking at the forums, I discovered he was unique, and he makes it to 15th in the F3 League.
I introduce the strongest F3 Blind Bot I have found, Animal Resono
It also beats Mister Magoo, and PhiNotPi's blind bots.
Version 1.0 also does. (which doesn't use ref)

Warning, I used Nums .shang fix (2) to make this.  http://forum.darwinbots.com/index.php/topic,1249.0.html

Code: [Select]

' Animal_Resono_1.2 (F3)(Tilthan) 05.06.12
' Also Blind Bot, Interesting Behavior

' This bot does not use any eyes (in practice) and can run with vision disabled
' It uses it's echolocation properties as conspec recognition, if hit by only one shot, friendly
' It is the only bot I know of that uses echolocation using shots
' A side effect of it's conspec is that it makes a mine field and plays pinball
' Changes 1.2 - Uses shot pings as long-distance conspec
'         1.1 - Uses ref values for further conspec and touch targeting, (Having eyes as priority for ref is annoying)

' Variables
def guess 50
def search 51
def detect 52

' Constants
def age 10
def power 32

' 1 Get Mom Tie, and try to make my eyef useless.
cond
 *.robage 0 =
start
 .tie inc
 1222 .eye5width store
 628 .eye5dir store
stop

' 2 Get Rid of Mom Tie
cond
 *.robage 1 =
start
 .deltie inc
stop

' 3 Get Away from Mom
cond
 *.robage .age <
 *.vel 180 <
start
 10 .dn store
stop

' 4 Find Food, Start Sonar
cond
 400 *.nrg div 5 add rnd 0 =
and
 *.guess 0 =
and
 *.robage .age >
start
 214 rnd 100 add .aimdx store
 -1 .shoot store
 .search inc
stop

' 5 Find Food, Get Sonar
cond
 *.shang 0 >
and
 *.robage .age >
start
 *.shang .aimdx store
 2 .guess store
 *.velup -1 mult .up store
 *.veldx -1 mult .dx store
 0 .search store
stop

' 7 Shoot at Food
cond
 *.guess 0 !=
start
 -6 .shoot store
 .power .shootval store
 .guess dec
stop

' 8 Migrate for more Food
cond
 *.search 600 >
 *.nrg 500 >
start
 -100 .up store
 0 .search store
stop

' 9 Unstick if stuck
cond
 *.fixed 0 >
start
 0 .fixpos store
stop

'''''''''''Better movement hopefully
' 10 Shot Front, move forward
cond
 *.shdn 0 !=
start
 *.up -10 add .up store
stop

' 11 Shot Back, move back
cond
 *.shup 0 !=
start
 *.up 10 add .up store
stop

' 12 Shot Right, Move Right
cond
 *.shdx 0 !=
start
 *.dx 10 add .dx store
stop

' 13 Shot Left, Move Left
cond
 *.shsx 0 !=
start
 *.dx -10 add .dx store
stop

' 14 Body Maintenence
cond
 *.nrg 1105 >
 *.body 1000 <
start
 100 .strbody store
stop

' 15
cond
 *.nrg 1000 <
 *.body 1010 > or
start
 100 .fdbody store
stop

' Fam Detector
cond
 *.shflav -1 =
 *.shflav -6 = or
start
 0 .timer store
 .detect inc
stop

' 16 If Fam Fired at Me, Move
cond
 *.shang 0 =
 *.timer 1 >
 *.detect 0 >
and
 *.robage 0 !=
start
 0 .guess store
 0 .detect store
 284 rnd 120 add .aimdx store
 -35 .up store
stop

' 17 Hit Fam Get Away
cond
 *.refup *.myup =
start
 0 .guess store
 0 .detect store
 284 rnd 120 add .aimdx store
 -35 .up store
stop

' 18 Hit Food, Eat Food--From EricL
cond
 *.refxpos 0 >
 *.refup *.myup !=
start
 *.refxpos *.refypos angle .setaim store
 -6 .shoot store
 .power .shootval store
stop

' 19 Reproduce
cond
 *.nrg 9000 >
and
 *.guess 0 =
and
 *.pleas abs 100 <
start
 -314 .aimdx store
 30 .repro store
stop

end

Edit: Replaced with version 1.2 which now is F3, but still is slightly better than 1.1
Included are all three versions:
1.2 Refs
1.1 Info Shots, Refs
1.0 Info Shots, Meets Qualifications of Blind Bot Challenge