Darwinbots Forum

Bots and Simulations => Bestiary => F2 bots => Topic started by: PurpleYouko on February 21, 2005, 01:07:11 PM

Title: Circumversor Algificus (F2)(Jez)-30.10.03
Post by: PurpleYouko on February 21, 2005, 01:07:11 PM
Code: [Select]
'***circumversor algificus*** the chilling spinner ***
'***because it calms down when resources become scarce ***
'* default conditions unblocked *
'* Purple Youko +/- conditions applied * critical mass 250 - 300*

' Shot bot developed by Jez.
' The first robot to deliberately spin while not actively hunting


'***start condition***

cond
*63 0 =
*.eye5 0 =
start
1 63 store
20 .up store
-20 .dn store
stop

'***reproduce***

cond
*.eye5 0 =
*.nrg 6000 >
start
25 .repro store
50 .aimdx store
stop

'***target***

cond
*.eye5 *.eye4 <
start
26 .aimsx store
stop

cond
*.eye5 *.eye6 <
start
26 .aimdx store
stop

cond
*.eye5 *.eye1 <
start
104 .aimsx store
stop

cond
*.eye5 *.eye9 <
start
104 .aimdx store
stop

'***shoot***

cond
*.eye5 0 >
*.refeye 14 !=
start
10 .up store
-10 .dn store
-1 .shoot store
stop

cond
*.eye5 0 >
*.refeye 0 =
start
20 .up store
-20 .dn store
-1 .shoot store
stop

'***nothing in front***

cond
*.eye5 0 =
start
52 .aimdx store
stop

'***friend in front***

cond
*.eye5 0 >
*.refeye 14 =
start
208 .aimdx store
0 .shoot store
stop
end