Topics

16

Suggestions / Ties should be referred to by the same number on both ends

« on: June 01, 2008, 02:57:53 PM »

Current behavior:
If a bot A stores 123 in .tie and creates a tie to bot B, the following happens
1) bot A can access the tie as tie number 123
2) bot B can access the tie as tie number 1 (if it had no ties previously; otherwise it uses the least available +ve integer)

Suggested behavior:
If bot A stores 123 in .tie and creates a tie to bot B, both bots should refer to that tie as 123

17

Bugs and fixes / *.tiepres not working correctly OPEN

« on: June 01, 2008, 02:40:32 PM »

If a bot acquires multiple ties with the same tie number and deletes one, the following occurs:
1) only the older tie is deleted
2) *.tiepres will ignore the remaining tie with the same number as the deleted one

If the tie is deleted from the other end, this only happens if the older tie was deleted.

Tested using the console.

18

Bugs and fixes / .in9 and .in10 don't work

« on: April 02, 2008, 11:28:56 AM »

As topic states.
Coincidentally, 820 is the memory location used by .mkslime and by .in10.
I don't know if .in9 has a similar collision.

19

Suggestions / .tin / .tout sysvars

« on: March 26, 2008, 11:03:27 AM »

I propose that an equivalent of the in/out sysvars be implemented for ties.
*.tin would read the value of the .tout sysvar for the bot on the other end of the tie.
Use the same method as the .tref vars to determine which tie is read from.

20

Suggestions / .shootval not working as advertised

« on: March 20, 2008, 11:08:43 AM »

The following was found using a bot with 1000 body.

Code: [Select]

.shootval   log2 |shootval|    shot cost      lifetime(cycles)     multiplier
     0            -                2             12                    1
    -1            0                2             12                    1
    -2            1                2             12                    1
    -4            2                2             12                    1
    -8            3                16            22                    2
    -16           4                32            33                    3
    -32           5                64            44                    4Two problems:
The additional cost of the shot should be equal to the value stored in .shootval
The distance multiplier should be equal to log2 |shootval| (when >= 1)

For sufficiently great values, the cost is treating shootval as if it was twice as large and the multiplier is treating shootval as if it was half as large.

21

Single Store League / Introducing the SS league

« on: March 19, 2008, 11:40:24 AM »

#SS
1 - Brevis (SS)(F2)(Moonfisher)-22.03.08
2 - One Man Bucket (SS)(F2)(abyaly)-03.04.07
3 - Bardus (SS)(Moonfisher)-19.03.2008
4 - Animal_Archaea (SS)(Ecosims)MacadamiaNuts-10.08.2007
5 - Singularis (SS)(Commander_Keen)-19.03.2008
6 - Nano (SS)(MacadamiaNuts)-02.02.07
7 - EMPTY
8 - EMPTY
9 - EMPTY
10- EMPTY
11- EMPTY
12- EMPTY
13- EMPTY
14- EMPTY
15- EMPTY
16- EMPTY
17- EMPTY
18- EMPTY
19- EMPTY
20- EMPTY
21- EMPTY
22- EMPTY
23- EMPTY
24- EMPTY
25- EMPTY
26- EMPTY
27- EMPTY
28- EMPTY
29- EMPTY
30- EMPTY

22

Bugs and fixes / .shell doesn't update properly (in bot memory) when hit by venom or by -6 shots

« on: March 18, 2008, 10:25:59 PM »

[attachment=815:New_Bitm...mage__3_.PNG]
The bot on the left has just shot the bot on the right.
The bot on the right has lost some shell.
Although it is programmed to grow shell whenever shell is less than 1000, it isn't doing it.
? .shell in console also gives a wrong shell value.

23

Bugs and fixes / Console doesn't sanitize inputs RESOLVED 2.43.1e

« on: March 18, 2008, 09:33:08 PM »

DB explodes when large values are assigned to a var through the console

24

Bugs and fixes / .sx acceleration vector not displayed properly

« on: March 16, 2008, 08:35:25 PM »

[attachment=812:sx.PNG]

25

Bugs and fixes / Eyes not picking up bots RESOLVED (BY DESIGN)

« on: March 16, 2008, 04:20:32 PM »

The veggie is looking at the tiny bots.
Some of them are inside the eye range but aren't noticed.
(In an unrelated note, the tiny bots should be dead due to energy loss, but aren't)
[attachment=810:eyes.PNG]

26

F1 bots / Etch Mk II(F1)(abyaly)-15.03.2008

« on: March 15, 2008, 09:57:30 PM »

Code: [Select]

'Etch Mk II
'Dirty F1 tie fighter by abyaly
'For version 2.43.1d
'March 15, 2008

def id 6395
def status 53
def tstatus 54
def ally 1
def veggie 2
def enemy 3
def rrr 942

def speed 10

'****************************Birth init**************************
cond
*.robage 0 =
start
  .dnalen .memloc store
  .dnalen .tmemloc store
  100 rnd .rrr store
stop
'****************************************************************

'*******************Const****************************************
cond
start
'Unfix myself
  0 .fixpos *.fixed sgn mult store
'Identify myself
  .id dup *.out5 sub sgn abs .out5 mult store
'arrange my eyes
  -140 dup *.eye1dir sub sgn abs .eye1dir mult store
  -105 dup *.eye2dir sub sgn abs .eye2dir mult store
  -70  dup *.eye3dir sub sgn abs .eye3dir mult store
  -35  dup *.eye4dir sub sgn abs .eye4dir mult store
  35   dup *.eye6dir sub sgn abs .eye6dir mult store
  70   dup *.eye7dir sub sgn abs .eye7dir mult store
  105  dup *.eye8dir sub sgn abs .eye8dir mult store
  140  dup *.eye9dir sub sgn abs .eye9dir mult store
  -30  dup *.eye1width sub sgn abs .eye1width mult store
  -25  dup *.eye2width sub sgn abs .eye2width mult store
  -15  dup *.eye3width sub sgn abs .eye3width mult store
  5    dup *.eye4width sub sgn abs .eye4width mult store
  45   dup *.eye5width sub sgn abs .eye5width mult store
  125  dup *.eye6width sub sgn abs .eye6width mult store
  285  dup *.eye7width sub sgn abs .eye7width mult store
  605  dup *.eye8width sub sgn abs .eye8width mult store
  1221 dup *.eye9width sub sgn abs .eye9width mult store
  .deltie *.tienum sgn mult inc
stop
'****************************************************************

'************************Eye focus manager***********************
cond
  *.eye1 0 >
  *.eye2 0 > or
  *.eye3 0 > or
  *.eye4 0 > or
  *.eye5 0 > or
  *.eye6 0 > or
  *.eye7 0 > or
  *.eye8 0 > or
  *.eye9 0 > or
start
'Focus using the narrowest eye that sees something
  *.eye1 *.eye2 *.eye3 *.eye4
  *.eye5 *.eye6 *.eye7 *.eye8 *.eye9
  floor floor floor floor
  floor floor floor floor
  50 store
  -4 *50 *.eye1 sub sgn abs -- - .focuseye mult store
  -3 *50 *.eye2 sub sgn abs -- - .focuseye mult store
  -2 *50 *.eye3 sub sgn abs -- - .focuseye mult store
  -1 *50 *.eye4 sub sgn abs -- - .focuseye mult store
  0  *50 *.eye5 sub sgn abs -- - .focuseye mult store
  1  *50 *.eye6 sub sgn abs -- - .focuseye mult store
  2  *50 *.eye7 sub sgn abs -- - .focuseye mult store
  3  *50 *.eye8 sub sgn abs -- - .focuseye mult store
  4  *50 *.eye9 sub sgn abs -- - .focuseye mult store
stop
'****************************************************************

'****************************Tie manager*************************
cond
  *.numties 0 >
start
'We will need this later :D
  *.tiepres .tienum store
  *.tiepres .readtie store
stop
'****************************************************************

'****************************Target ID***************************
cond
'I see something..   what is it?
  *.eyef 0 >
start
'Oh, you. Hi again, I guess.
  .ally
    *.in5 .id sub sgn abs -- -
    *.refage sgn -- - add sgn mult
    *.memval *.dnalen sub sgn abs -- - mult
  .status store

'Its a veggie! Let's eat it!
  .veggie .status
    *.status .ally sub sgn abs mult
    *.refshoot sgn -- - mult
    *.refaimsx sgn -- - mult
    *.refkills sgn -- - mult
    *.refeye sgn -- - mult
    *.refup sgn -- - mult
    *.memval 13 sub sgn abs -- - mult
  store

'You're not my race and you're not food.. you must be trying to kill me!
  .enemy .status
    *.status .ally sub sgn abs mult
    *.status .veggie sub sgn abs mult
  store
stop
cond
'I'm attached to something..   what is it?
  *.tienum 0 >
start
'Oh, you. Hi again, I guess.
  .ally
    *.tmemval *.dnalen sub sgn abs -- -
    *.trefage sgn -- - add sgn mult
  .tstatus store

'Its a veggie! Let's eat it!
  .veggie .tstatus
    *.tstatus .ally sub sgn abs mult
    *.trefshoot sgn -- - mult
    *.trefaimsx sgn -- - mult
    *.trefkills sgn -- - mult
    *.trefeye sgn -- - mult
    *.trefup sgn -- - mult
    *.tmemval 13 sub sgn abs -- - mult
  store

'You're not my race and you're not food.. you must be trying to kill me!
  .enemy .tstatus
    *.tstatus .ally sub sgn abs mult
    *.tstatus .veggie sub sgn abs mult
  store
stop
'****************************************************************

'**************************Untie allies**************************
cond
  *.numties 0 >
  *.tstatus .ally =
start
  *.tiepres .deltie store
stop
'****************************************************************

'****************************Seeking*****************************
cond
  *.eye1 0 =
  *.eye2 0 =
  *.eye3 0 =
  *.eye4 0 =
  *.eye5 0 =
  *.eye6 0 =
  *.eye7 0 =
  *.eye8 0 =
  *.eye9 0 =
start
'We clearly aren't looking hard enough
  .speed .up store
stop
'****************************************************************

'*******************Aim in direction of movement*****************
cond
  *.velup 0 !=
  *.veldx 0 !=
  *.eyef 0 =
  *.numties 0 =
  *.status .ally = or
start
'theta = arctan (veldx / velup). (math ftw)
  *.veldx 628 mult *.velup div *.veldx *.velup div dup mult 8824 mult 31416 add 10000 div
  div - *.velup sgn sqr -- - 628 mult add *.aim add .setaim store
stop
cond
  *.velup 0 =
  *.veldx 0 !=
  *.eyef 0 =
  *.numties 0 =
  *.status .ally = or
start
'divide by zero (eek!)
  *.velsx sgn 314 mult *.aim add .setaim store
stop
'****************************************************************

'***********************Target non-allies************************
cond
  *.eyef 0 >
  *.status .ally !=
start
'"children, scooch closer"
  *.refvelup 250 *.eye3 sub add *.velup abs - floor .up store
  *.refveldx .dx store  *.refveldx .dx store
  *.refxpos *.refypos angle .setaim store
stop

'****************************************************************

'************************Avoid allies****************************
cond
  *.eyef 0 >
  *.status .ally =
start
'root 2 = 14142 10000 div
'Yo. How's it going? Good? Me too. See ya.
  *.tiepres .deltie store
  *.refveldx sgn abs -- - *.refveldx add sgn .speed mult - 14142 mult 20000 div  .dx store
  .speed 14142 mult 20000 div .up store
stop

'****************************************************************

'***********************EAT YOUR VEGGIES!!***********************
cond
  *.eyef 0 >
  *.status .veggie =
  *.numties 0 =
start
  *.memval .tie store
stop
cond
  *.eyef 0 >
  *.status .veggie =
start
  .tieloc *.robage *.rrr add 2 mod 0 sub sgn abs -- - mult
  .tienum *.robage *.rrr add 2 mod 1 sub sgn abs -- - mult add
  .shoot store

   -1 *.robage *.rrr add 2 mod 0 sub sgn abs -- - mult
   1  *.robage *.rrr add 2 mod 1 sub sgn abs -- - mult add
  .shootval store
stop
cond
  *.numties 0 >
  *.tstatus .veggie =
start
  .tieval .tieloc store
   30000 .tieval store

stop
'****************************************************************

'*********This section is dedicated to killin'*******************
'This section is also a pain to comment,
'but I'm sure you can figure it out if you're interested
cond
  *.eyef 0 >
  *.numties 0 =
  *.status .enemy =
start
  1000 rnd .tie store
  .shootval  *.robage *.rrr add 4 mod 0 sub sgn abs -- - mult
  .strpoison *.robage *.rrr add 4 mod 1 sub sgn abs -- - mult add
  .strvenom  *.robage *.rrr add 4 mod 2 sub sgn abs -- - mult add
  .fixpos    *.robage *.rrr add 4 mod 3 sub sgn abs -- - mult add
  .shoot store
  32000 .shootval store
stop
cond
  *.eyef 0 >
  *.numties 0 >
  *.status .enemy =
  *.trefbody 50 >
start
  .tieloc *.robage *.rrr add 2 mod 0 sub sgn abs -- - mult
  .tienum *.robage *.rrr add 2 mod 1 sub sgn abs -- - mult add
  .shoot store
  -1 *.robage *.rrr add 2 mod 0 sub sgn abs -- - mult
  1  *.robage *.rrr add 2 mod 1 sub sgn abs -- - mult add
  .shootval store
stop
cond
  *.eyef 0 >
  *.numties 0 >
  *.status .enemy =
  *.trefbody 50 <=
start
  .shootval  *.robage *.rrr add 4 mod 0 sub sgn abs -- - mult
  .strbody   *.robage *.rrr add 4 mod 1 sub sgn abs -- - mult add
  .strpoison *.robage *.rrr add 4 mod 2 sub sgn abs -- - mult add
  .strvenom  *.robage *.rrr add 4 mod 3 sub sgn abs -- - mult add
  .shoot store
  32000 .shootval store
stop
cond
  *.numties 0 >
  *.tstatus .enemy =
  *.trefbody 50 >
start
  .strbody *.robage *.rrr add 2 mod 0 sub sgn abs -- - mult
  .tieval  *.robage *.rrr add 2 mod 1 sub sgn abs -- - mult add
  .tieloc store
  32000 .tieval store
stop
cond
  *.numties 0 >
  *.status .enemy =
  *.trefbody 50 <=
start
  .shootval  *.robage *.rrr add 4 mod 2 sub sgn abs -- - mult
  .fdbody    *.robage *.rrr add 4 mod 3 sub sgn abs -- - mult add
  .strpoison *.robage *.rrr add 4 mod 0 sub sgn abs -- - mult add
  .strvenom  *.robage *.rrr add 4 mod 1 sub sgn abs -- - mult add
  .tieloc store
  32000 .tieval store
stop
'****************************************************************

'**************************Waste & body**************************
cond
  *.waste 400 >
start
  -4 .shoot store
  *.waste .shootval store
stop
cond
  *.body 2 >=
start
  *.body .fdbody store
stop
'****************************************************************

'*****************************Repro******************************
cond
  *.nrg *.body 10 mult add 600 >
start
'Face the direction opposite to velocity
  *.veldx 628 mult *.velup div *.veldx *.velup div dup mult 8824 mult 31416 add 10000 div
  div - *.velup sgn sqr -- 628 mult add *.aim add .setaim store
'Accelerate with current velocity
  80 *.velscalar sub 0 floor .dn store
  50 .repro store
stop
'****************************************************************Etch is back and working in current vers!
A few tactics have changed due to version trauma and new opportunities.
Reams the current F1 table in addition to pacifist and multiply4.
No close fights, contenders are welcome to take notes

27

Bot Tavern / Quick question

« on: March 14, 2008, 02:11:21 AM »

A few things seem to have changed since the last version I saw. It seems bots can now kill themselves by body feeding. It seems tie feeding works. It seems that bots with very low body have completely useless -1 shots now (in addition to completely useless body shots). Is this all accurate?

28

DNA - General / Rounding

« on: July 16, 2007, 06:02:16 PM »

is the rounding performed when you store a value, or are all numbers on the stack integers?

29

Interesting behaviour bots / Spiral (IB)(F2)(abyaly)-16.06.07

« on: June 16, 2007, 10:27:03 AM »

Code: [Select]

'Spiral
'Interesting Behavior bot by abyaly
'They work together to find food
'For version 2.43
'June 16, 2007




def spiral -15
'This number controls how much sideways push the bot
'exerts when part of a group.

def size 50
'This number controls how much body each bot will maintain

def swarmnumber 20
'This number is the maximum number of
'degrees of seperation between the bot and food
'for which it will follow the ally it sees.
'They branch off more if the number is lower.
'With a negative number they will never try to split up

def swarmdensity 90
'This numbers controls how close each bot wants to be
'to allies it follows. With higher numbers they tend to
'get closer and act more excited.


def id 8654
def status 62
def ally 1
def food 2
def enemy 3

cond
*.robage 0 =
start
  .tie inc
  140 .eye5width store
  .id .out5 store
stop

cond
start
  *.body .size sub *.body ceil .fdbody store
  .size *.body sub *.nrg 1000 sub ceil .strbody store
  *.tiepres dup sgn abs .deltie mult store
  0 .fixpos *.fixed mult store
stop

cond
  *.eye5 0 >
start
  .ally
*.in5 .id sub sgn abs -- - mult
  .status store
  .food .status
*.status .ally sub sgn abs mult
*.refshoot sgn -- - mult
*.refaimsx sgn -- - mult
*.refshell sgn -- - mult
*.refslime sgn -- - mult
*.refvenom sgn -- - mult
*.refkills sgn -- - mult
*.refeye sgn -- - mult
*.refup sgn -- - mult
  store
  .enemy .status
*.status .ally sub sgn abs mult
*.status .food sub sgn abs mult
  store
stop

cond
  *.eye5 0 =
  *.in3 0 = or
  *.robage 2 >
start
  *.aim 317 sub .setaim store
  *.robage dup 2 mod add 4 mod 2 mult
  .up *.robage 2 mult 4 mod sgn 3 mult add store
stop

cond
  *.eye5 0 >
  *.status .ally =
  *.in3 0 !=
  *.robage 1 >
start
  *.in1 .out1 store
  *.in2 .out2 store
  *.in3 -- .out3 store
  *.in1 *.in2 angle .setaim store
  *.refvelup .swarmdensity *.eye5 sub add *.velup abs - floor .up store
  *.refveldx .spiral add .dx store
stop

cond
  *.eye5 0 >
  *.status .ally !=
  *.robage 1 >
start
  *.refxpos *.refypos angle .setaim store
  *.refvelup 80 *.eye5 sub add *.velup abs - floor .up store
  *.refveldx .dx store
stop

cond
  *.eye5 0 >
  *.status .food =
  *.robage 1 >
start
  *.refxpos .out1 store
  *.refypos .out2 store
  .swarmnumber .out3 store
stop

cond
  *.eye5 70 >
  *.status .food =
start
  -1 .shoot store
stop

cond
  *.eye5 70 >
  *.status .food =
  *.robage 10 mod 0 =
  *.reffixed 0 =
start
  .fixpos .shoot store
  1 .shootval store
stop

cond
  *.eye5 70 >
  *.status .enemy =
start
  -1 .shoot store
  *.nrg 5 div 200 ceil .shootval store
stop

cond
  *.nrg 2000 >
start
  *.aim 317 add .setaim store
  50 .repro store
stop


30

Bug reports / tie feeding seems to be broken

« on: May 05, 2007, 08:58:57 AM »

I was trying to make a tie feeder and was wondering why it wouldnt work, then I noticed tie feeders from old versions dont work either. Leaching still works, though, so it seems there is a restriction on only positive values for tieval. Is this intentional?