Darwinbots Forum

General => Leagues => Multi-Bots => Topic started by: Testlund on September 11, 2013, 12:39:42 PM

Title: Tie Struggler
Post by: Testlund on September 11, 2013, 12:39:42 PM
This will be a multibot until generation 3. Then it stops working.  :angry:

Code: [Select]
'*************************************
'*          Tie Struggler            *
'*                                   *
'*    Generation 3 can't tie! >:-(   *
'*************************************

cond
*.robage 0 =
start
67 .memloc store
101 67 store
.tie inc
32 .stifftie store
stop

cond
*.numties 1 < and
*.refxpos 0 > and
*.memval *67 =
start
*.refxpos *.refypos angle .setaim store
.tie inc
32 .stifftie store
stop

cond
*.refxpos 0 > and
*.memval *67 !=
start
*.refxpos *.refypos angle .setaim store
-1 .shoot store
stop

cond
*.nrg 16000 > and
*.numties 3 <
start
50 .repro store
314 rnd .aimdx store
stop

cond
*.nrg 16000 > and
*.numties 2 >
start
*.tiepres .tienum store
32 .tieval store
-1 .tieloc store
stop

cond
*.nrg 8000 < and
*.numties 0 >
start
*.tiepres .tienum store
-32 .tieval store
-1 .tieloc store
stop

cond
*.body 256 <
start
32 .strbody store
stop
Title: Re: Tie Struggler
Post by: Panda on September 12, 2013, 05:17:22 AM
What stops working about it?
Title: Re: Tie Struggler
Post by: Testlund on September 12, 2013, 10:59:09 AM
It starts out nicely with children tieing to there parents up to the 3rd generation of bots. Than they don't tie anymore and I end up with
single bots over the screen.

Have I done the stifftie command right?
Title: Re: Tie Struggler
Post by: Botsareus on September 14, 2013, 01:09:06 PM
Ah, thx.

I will totally take a look.
Title: Re: Tie Struggler
Post by: Testlund on September 14, 2013, 02:53:18 PM
I've found out what the problem is. It happens when vision is disabled and the bots use touch senses, but it doesn't make any sense why it only happens from the 3rd generation of bots.

The bot below uses vision instead. You can compare this one with the above if you want.

Code: [Select]
'*************************************
'*          Tie Struggler            *
'*             (eyes)                *
'*       Made by Testlund in         *
'*       September 14, 2013.         *
'*************************************

cond
*.robage 5 <
start
.tie inc
314 rnd .aimdx store
stop

cond
*.eye2 *.eye5 >
start
-64 .aimright store
stop

cond
*.eye8 *.eye5 >
start
64 .aimright store
stop

cond
*.eye5 40 > and
*.refeye *.myeye =
start
1 .tie store
314 rnd .aimdx store
32 .stifftie store
stop

cond
*.eye5 40 > and
*.refeye *.myeye != and
*.refnrg 0 >
start
-1 .shoot store
stop

cond
*.nrg 16000 > and
*.body 2000 > and
*.numties 3 <
start
50 .repro store
314 rnd .aimdx store
stop

cond
*.nrg 16000 > and
*.numties 2 >
start
*.tiepres .tienum store
32 .tieval store
-1 .tieloc store
stop

cond
*.nrg 8000 < and
*.numties 0 >
start
*.tiepres .tienum store
-32 .tieval store
-1 .tieloc store
stop

cond
*.body 1000 <
*.nrg 8000 > and
start
32 .strbody store
stop
Title: Re: Tie Struggler
Post by: Botsareus on September 14, 2013, 03:21:02 PM
Thank you for narrowing it down, I had no idea what was going on, I may know now.
Title: Re: Tie Struggler
Post by: Botsareus on September 14, 2013, 03:24:36 PM
Actually, robots currently can not tie by touch, that is still a work in progress.
They can however tie to there parent on the first cycle of there lives, replacing the temporary ties with a permanent one. I don't know if this helps much as I have not carefully studied the DNA of your robot.
Title: Re: Tie Struggler
Post by: Botsareus on November 06, 2013, 10:19:11 AM
Once again, using a mod version of TieStruggler (added a chloroplast gene) I was able to get it to form ties across 12 generations.
See attachments