Author Topic: All Hunter 2.1 [F1 - Spike43884]  (Read 8623 times)

Offline spike43884

  • Bot Overlord
  • ****
  • Posts: 656
    • View Profile
All Hunter 2.1 [F1 - Spike43884]
« on: March 26, 2017, 09:12:17 AM »
Quick n' dirty upgrade to my classic 'All Hunter'. Took a repro gene from another bot and dragged in just a couple of gimmick's genes. It's not able to last out quite so long so dies against some of the weaker F1 bots, but it does win against a notable proportion of the other F1 bots, with the exception of moonfisher's top 3 bots. Would love to see how it'd fair in the next F1 League.

Code: [Select]
'All Hunter
'By Spike43884
'
'Grabbed some gimmicks from, Gimmick! (And a repro gene from someone)
'Interestingly it loses against some lower-ranking bots, even though it wins against a good chunk of the higher ranking ones (with exception to top 3, those superbots from moonfisher).
'I suspect what has occurred, is that while it's capacity to fight in a crowded arena quickly is improved, it can't last out too long, so the non-aggressive bots outlive it instead.


def attack 50
def hunt 51

'Low Priority (WASTE REMOVAL)
cond
*.waste 100 >=
start
-4 .shoot store
*.waste .shootval store
stop


'Initialisation (EYES)
cond
*.robage 2 <
start
 135 .eye1width store
 135 .eye2width store
 135 .eye3width store
 135 .eye4width store
 15 .eye5width store
 135 .eye6width store
 135 .eye7width store
 135 .eye8width store
 135 .eye9width store
 410 .eye1dir store
 300 .eye2dir store
 190 .eye3dir store
 80 .eye4dir store
 0 .eye5dir store
 -80 .eye6dir store
 -190 .eye7dir store
 -300 .eye8dir store
 -410 .eye9dir store
stop


'Gene 1 No food = Hunt
cond
*.eye1 0 =
*.eye2 0 =
*.eye3 0 =
*.eye4 0 =
*.eye5 0 =
*.eye6 0 =
*.eye7 0 =
*.eye8 0 =
*.eye9 0 =
*.hunt 0 =
start
157 rnd .aimdx store
1 .hunt store
stop


'Gene 2 No food & Turned = Move
cond
*.eye1 0 =
*.eye2 0 = and
*.eye3 0 = and
*.eye4 0 = and
*.eye5 0 = and
*.eye6 0 = and
*.eye7 0 = and
*.eye8 0 = and
*.eye9 0 = and
*.hunt 1 = and
start
15 .up store
2 .hunt store
stop

cond
*.eye1 0 =
*.eye2 0 =
*.eye3 0 =
*.eye4 0 =
*.eye5 0 =
*.eye6 0 =
*.eye7 0 =
*.eye8 0 =
*.eye9 0 =
*.hunt 2 =
start
10 .up store
3 .hunt store
stop

cond
*.eye1 0 =
*.eye2 0 =
*.eye3 0 =
*.eye4 0 =
*.eye5 0 =
*.eye6 0 =
*.eye7 0 =
*.eye8 0 =
*.eye9 0 =
*.hunt 3 =
start
10 .up store
0 .hunt store
stop


' Gene 1 Food Finder (waiting)
cond
*.eye1 sgn
 *.eye2 sgn add
 *.eye3 sgn add
 *.eye4 sgn add
 *.eye5 sgn add
 *.eye6 sgn add
 *.eye7 sgn add
 *.eye8 sgn add
 *.eye9 sgn add 0 =
*.refeye *.myeye = or
start
10 rnd .aimdx store
stop


'Gene 2 Food Sighted
'*********************
cond
*.refeye *.myeye !=
*.eyef 0 !=
start
1 .attack store
stop

cond
*.refeye *.myeye =
*.eyef 0 = or
start
0 .attack store
stop

cond
*.eye1 0 >
*.attack 0 =
start
550 .aimdx store
stop

cond
*.eye2 0 >
*.attack 0 =
start
405 .aimdx store
stop

cond
*.eye3 0 >
*.attack 0 =
start
260 .aimdx store
stop

cond
*.eye4 0 >
*.attack 0 =
start
115 .aimdx store
stop

cond
*.eye6 0 >
*.attack 0 =
start
115 .aimsx store
stop

cond
*.eye7 0 >
*.attack 0 =
start
260 .aimsx store
stop

cond
*.eye8 0 >
*.attack 0 =
start
405 .aimsx store
stop

cond
*.eye9 0 >
*.attack 0 =
start
550 .aimsx store
stop
'*********************


' Gene 3 Chase Food
cond
*.eye5 0 >
*.refeye *.myeye !=
start
 *.refveldx .dx store
 *.refvelup 30 add .up store
stop

'Shot Regulation
cond
*.nrg 200 >
start
16 .shootval store
stop

cond
*.nrg 100 <=
start
0 .shootval store
stop


'Shell Regulation
cond
*.shell 500 <
start
'make shell
50 .mkshell store
stop


' Gene 4 Eat Food
cond
*.eye5 50 >
*.refeye *.myeye !=
start
-1 .shoot store
 *.refvelup .up store
stop


' Gene 5 Avoiding Family
cond
 *.eye5 0 =
 *.refeye *.myeye = or
start
 314 rnd .aimdx store
stop


' Gene 6 Recombine
cond
*.robage 0 =
*.numties 0 =
start
1 .tie store
stop


'Runaway Gene
cond
*.pain 250 >
start
250 .sx store
stop


'Chameleon Genes
cond
*.in1 0 !=
*.in1 *.out1 !=
start
*.in1 .out1 store
stop
cond
*.in2 0 !=
*.in2 *.out2 !=
start
*.in2 .out2 store
stop
cond
*.in5 0 !=
*.in5 *.out5 !=
start
*.in5 .out5 store
stop


' Gene 7 Reproduce
cond
*.nrg *.body 10 mult add 2300 >
start
40 .repro store
stop


' Gene 8 Singulise
cond
 *.numties 0 !=
start
.deltie inc
.deltie inc
stop
end
Autism can allow so much joy, and at the same time sadness to be seen. Our world is weird, and full of contradiction everywhere, yet somehow at moments seems to come together, and make near perfect sense.

Offline Botsareus

  • Society makes it all backwards - there is a good reason for that
  • Moderator
  • Bot God
  • *****
  • Posts: 4483
    • View Profile
Re: All Hunter 2.1 [F1 - Spike43884]
« Reply #1 on: March 30, 2017, 08:16:21 PM »
Alright dude, it will be a while, I want to add a couple of my evolutions in here a well, then I will run a proper F1 league and a MB league with all these new bots.

Thanks for posting bots again btw. It was kind of dead in here, at least in this specific section of the forum.
Oh, and sorry for not including your crossover of FF and QuickDraw, it was kind of a pointless hack and ran too slow for me to care.

Offline spike43884

  • Bot Overlord
  • ****
  • Posts: 656
    • View Profile
Re: All Hunter 2.1 [F1 - Spike43884]
« Reply #2 on: April 03, 2017, 01:24:56 PM »
Alright dude, it will be a while, I want to add a couple of my evolutions in here a well, then I will run a proper F1 league and a MB league with all these new bots.

Thanks for posting bots again btw. It was kind of dead in here, at least in this specific section of the forum.
Oh, and sorry for not including your crossover of FF and QuickDraw, it was kind of a pointless hack and ran too slow for me to care.
Ah don't worry, can't wait to see the new leagues.
It'd be nice if we could try get a few folks interested in DB again, I tried to pull some from a sciency forum a good few months back but nobody seemed to notice.

I'm hoping at some point to try and get a bot in the medal tables (1st, 2nd or 3rd) in at least on of the leagues, although I can never understand the code in moonfishers bots.
Autism can allow so much joy, and at the same time sadness to be seen. Our world is weird, and full of contradiction everywhere, yet somehow at moments seems to come together, and make near perfect sense.