'All Swarm 1.1
'By Spike43884
'Offshoot to All Eyes, Highly Aggressive, An attempt at a multibot.
'Forms medium sized groups, generally with a big bertha at heart...
'Often one or 2 of the groups smallest may fire off starting new colonies
'hopefully. It also has amazing conservation of energy whilest no food
'is sighted...Great for a spacious or dense simulation...Also thankfully
'doesn't have a startup time like some other bots...preventing birth
'weaknesses.
' Some assistance from Shadowgod2 to improve energy conservation.
def attack 50
'Initialisation (EYES)
cond
*.robage 2 <
start
135 .eye1width store
135 .eye2width store
135 .eye3width store
135 .eye4width store
15 .eye5width store
135 .eye6width store
135 .eye7width store
135 .eye8width store
135 .eye9width store
410 .eye1dir store
300 .eye2dir store
190 .eye3dir store
80 .eye4dir store
0 .eye5dir store
-80 .eye6dir store
-190 .eye7dir store
-300 .eye8dir store
-410 .eye9dir store
stop
' Gene 1 Food Finder (waiting)
cond
*.eye1 sgn
*.eye2 sgn add
*.eye3 sgn add
*.eye4 sgn add
*.eye5 sgn add
*.eye6 sgn add
*.eye7 sgn add
*.eye8 sgn add
*.eye9 sgn add 0 =
*.refeye *.myeye = or
start
10 rnd .aimdx store
stop
'Gene 2 Food Sighted
'*********************
cond
*.refeye *.myeye !=
*.eyef 0 !=
start
1 .attack store
stop
cond
*.refeye *.myeye =
*.eyef 0 = or
start
0 .attack store
stop
cond
*.eye1 0 >
*.attack 0 =
start
550 .aimdx store
stop
cond
*.eye2 0 >
*.attack 0 =
start
405 .aimdx store
stop
cond
*.eye3 0 >
*.attack 0 =
start
260 .aimdx store
stop
cond
*.eye4 0 >
*.attack 0 =
start
115 .aimdx store
stop
cond
*.eye6 0 >
*.attack 0 =
start
115 .aimsx store
stop
cond
*.eye7 0 >
*.attack 0 =
start
260 .aimsx store
stop
cond
*.eye8 0 >
*.attack 0 =
start
405 .aimsx store
stop
cond
*.eye9 0 >
*.attack 0 =
start
550 .aimsx store
stop
'*********************
' Gene 3 Chase Food
cond
*.eye5 0 >
*.refeye *.myeye !=
start
*.refveldx .dx store
*.refvelup 30 add .up store
stop
' Gene 4 Long Range Food Handling
'kills bot too fast
' Gene 5 Eat Food
cond
*.eye5 50 >
*.refeye *.myeye !=
start
-1 .shoot store
*.refvelup .up store
stop
' Gene 6 Avoiding Family
cond
*.eye5 0 =
*.refeye *.myeye = or
start
314 rnd .aimdx store
stop
' Gene 7 Reproduce
cond
*.nrg 20000 >
*.robage 3 > and
start
10 .repro store
stop
'*-*-*-*-*-*-*-*-*-*-*-*
' Gene 8 tie to parent
cond
*.robage 0 =
start
.tie inc
stop
' Gene 9 sever tie to parent
cond
*.robage 1 =
start
.deltie inc
stop
end
Its a pretty nasty attacker, will quite quickly spread with reasonable sized offspring (half size of all eyes offspring)...It was developed from all eyes 1.5/1.4
ENTER INTO F1 LEAGUE
