New to darwinbots please help!

[Plasmoid]

Hello c: I'm new to darwinbots and I've tried my best to put a bot together but for some reason, when I run a simulation it just... POOF. It dies :/ Because I'm new to this I have no idea what on earth happens to them. It's a modified Animal-Minimalis which I tried to make using the tutorial wiki. Could someone be kind enough to help me fix this problem?
If someone could stop my little babies from exploding I'd be very grateful :'c

' Gene 1 Food Finder
cond
 *.eye5 0 >
 *.refeye *.myeye !=
start
 *.refveldx .dx store
 *.refvelup 30 add .up store
stop

' Gene 2 Eat Food
cond
 *.eye5 50 >
 *.refeye *.myeye !=
start
8 .shoot store
 *.refvelup .up store
stop

' Gene 3 Avoiding Family
cond
 *.eye5 0 =
 *.refeye *.myeye = or
start
 314 rnd .aimdx store
stop

' Gene 4 Poison
cond
 *.poison 500 <
start
 50 .strpoison store
stop

' Gene 5 Shell
cond
 *.shell 250 <
start
 100 .mkshell store
stop

' Gene 6 Reproduce
cond
 *.nrg 15000 >
start
 10 .repro store
stop

' Gene 7 Waste
cond
*.waste 40 >
start
.backshot inc
-4 .shoot store
*.waste .shootval store
stop

' Gene 8 Backshoot
cond
*.shflav 0 !=
*.shflav -2 !=
start
1256 *.shang sub .aimshoot store
8 .shootval store
-6 .shoot store
0 .shflav store
stop

' Gene 9 Slime
cond
 *.slime 300 <
start
 100 .mkslime store
stop

'Gene 10 Antivirus
cond
 *.mkvirus 0 !=
start
 *.mkvirus .delgene store
stop
end

[Testlund]

Hi and welcome to the forum! :-)

My guess is they run out of energy trying to keep the slime level up. I've asked Botsareus to slow down the decay speed for slime, which may be fixed in the next beta.
So you may want to add a gene so they don't store slime if their energy is too low, like this for example:

Code: [Select]

' Gene 9 Slime
cond
 *.slime 300 <
 *.nrg 500 > and
start
 100 .mkslime store
stop
If you use costs you need to have genes designed to handle that.

Here are a couple of bots you can try and compare with.

Code: [Select]

cond
 *.eye5 0 >
 *.refeye *.myeye !=
start
 *.refveldx .dx store
 *.refvelup 30 add .up store
stop
cond
 *.eye5 50 >
 *.refeye *.myeye !=
start
-1 .shoot store
 *.refvelup .up store
stop
cond
 *.eye5 0 =
 *.refeye *.myeye = or
start
 314 rnd .aimdx store
stop
cond
 *.nrg 16000 >
start
 10 .strbody store
stop
cond
 *.body 16000 >
start
 50 .repro store
stop

Code: [Select]

' Blind Boticus is a modified version of A. Boticus
'
'Modified by Testlund to use touch senses instead of vision (check Disable Vision).
'
start
.fixpos *.fixed mult dec
51 *51 sgn mult dec
51 *51 sgn -1 mult mult inc
stop

cond
*.nrg 1000 >
start
10 *.vel sub 2 div .up store
stop

cond
*.refup *.myup = or
*.refxpos 0 = and
*51 20 !=
start
314 rnd .aimdx store
51 inc
51 inc
stop

cond
*.refxpos 0 != and
*.refup *.myup !=
start
*.refxpos *.refypos angle .setaim store
8 .fixpos store
-6 .shoot store
stop

cond
*.nrg 5000 >
start
32 .strbody store
stop

cond
*.body 5000 >
start
50 .repro store
stop

[Shadowgod2]

so does your poison need an nrg condition in it

your eat food gene needs to have -1 or -6 to gain nrg from shooting, yours isn't doing anything as far as i can tell.