Bots and Simulations > F2 bots

Jejen 1.11 (F2)(Ramiro)-10.03.07

(1/1)

Ramiro:

--- Code: ---' Jejen 1.11
' Just a mix of SWARM (Elite) and Hunter 2.13 (PY)
' and many other good ideas from other authors
' Nothing of my own creation actually
' Works on 2.43



' Anti birth-tie

cond
start
.tie *.robage 1 add mult inc
.deltie inc
stop

' Swarm

cond
*.eye5 0 >
*.refeye *.myeye =
start
*.refaim .setaim store
*.refvelup .up store
stop

' Move

cond
*.eye5 0 =
start
1 .up store
*.eye9 *.eye1 sub 2 mult .aimdx store
stop

' Aim

cond
*.eye5 0 >
*.refeye *.myeye !=
*.eye1 *.eye5 >
*.eye1 *.eye9 >
start
100 .aimsx store
'5 .sx store
stop

cond
*.eye5 0 >
*.refeye *.myeye !=
*.eye9 *.eye5 >
*.eye9 *.eye1 >
start
-100 .aimsx store
'5 .dx store
stop

cond
*.eye5 0 >
*.refeye *.myeye !=
*.eye3 *.eye5 >
*.eye3 *.eye7 >
start
50 .aimsx store
'5 .sx store
stop

cond
*.eye5 0 >
*.refeye *.myeye !=
*.eye7 *.eye5 >
*.eye7 *.eye3 >
start
-50 .aimsx store
'5 .dx store
stop

cond
*.eye5 35 >
*.refeye *.myeye !=
start
*.refvelup .up store
*.refvelsx .sx store
*.refveldx .dx store
*.refxpos *.refypos angle .setaim store

stop

' Attack

cond
*.eye5 35 >
*.refeye *.myeye !=
start
-6 .shoot store
16 .shootval store
stop

' Retaliate

cond
*.shflav 0 !=
*.shflav -2 !=
start
1256 *.shang sub .aimshoot store
1256 *.shang sub .setaim store
8 .shootval store
-6 .shoot store
0 .shflav store
stop


' Reproduce

cond
*.body 1000 >
start
30 .repro store
stop

' Feed on and store body

cond
*.nrg 10000 >
start
100 .strbody store
stop

cond
*.nrg 1000 <
start
*.body 0 floor .fdbody *.body sgn mult store
stop

end

--- End code ---


Just a swarming bot that works in 2.43. I use it as a veggie (challenging prey) for evolution sims with other bots.

Jez:
What a curious bot, it became more succesful when faced with aggresive opponents!
I didn’t expect it to do very well, it doesn’t have a gene to deal with eye5 36 < meaning it would see a veg and stop unless it was knocked closer. Plus its swarm function seemed to result in bots freezing. On its own it can’t survive!

Nethertheless it reached position ~23 in the F2 league! If you would like to leave it as it is I will happily do a proper run and give it its official league standing, on the other hand if you would like this bot moved to the bestiary and a new improved version entered in the league just say.
It would be easy enough to move this topic to the bot tavern if you’d like a few tips for improving it.

Ramiro:
Actually I was thinking of using SWARM 2.0 and some other genes to make Jejen 2.0

All genes are TM of Elite, PY and some from the wiki manual. I just blend them togheter.

Navigation

[0] Message Index