Animal Minimaxis 2 (F1)(-Venom-)-05.01.07

[Jez]

Code: [Select]

'Animal_Minimaxis 2
'By: -venom-
'orij by nums
'now eats to gain energy and randomly fires
'virus wich deletes the infected bots genes and
'replaces them with a new gene that continualy
'spreads the virus.
'
'note: virus spreads better in v 2.42.9s
'gene 12 changed as mistake spotted in original post


' Gene 1 Food Finder
cond
*.eye5 0 >
*.refeye *.myeye !=
start
*.refveldx .dx store
*.refvelup 30 add .up store
stop

' Gene 2 Eat Food
cond
*.eye5 50 >
*.refeye *.myeye !=
start
-1 .shoot store
*.refvelup .up store
stop

' Gene 3 shoot back
cond
*.shflav 0 !=
*.shflav -2 !=
start
1256 *.shang sub .aimshoot store
8 .shootval store
400 .vshoot store
0 .shflav store
stop

' Gene 4,5,6,7 Avoiding others
cond
*.eye5 0 =
*.refeye *.myeye = or
start
314 rnd .aimdx store
stop

cond
start
*.refbody 2 div dup
stop

cond
*.eye5 0 >
*.body >
*.refeye 1 >
start
-15 .up store
stop

cond
*.eye5 50 >
*.body >
*.refeye 1 >
start
.setaim .shoot store
*.aim .shootval store
stop

' Gene 8 make shell
cond
*.shell 250 <
start
100 .mkshell store
stop

' Gene 9 make slime
cond
*.slime 100 <
start
1000 .mkslime store
stop

' Gene 10 Reproduce
cond
*.nrg 15000 >
start
30 .repro store
stop

' Gene 11,12,13 virus genes
cond
*.robage 0 =
start
7 989 store
stop

cond
*.vtimer 0 =
start
13 .mkvirus store
stop

cond
7 *989 !=
start
400 .vshoot store
*.thisgene .mkvirus *.vtimer -1 mult 1 add mult store
676 .myeye store
676 *.memloc store
*.mkvirus 1 add .delgene *.mkvirus *.thisgene sub dup mult sgn mult
*.thisgene 1 rnd 2 mult -1 add add .delgene store
stop
end

[-venom-]

cond
*.vtimer 0 =
start
3 .mkvirus store
stop

woh I just realized that there is an error in my code the 12 gene should say

13 .mkvirus store

not 3

my fault redface.gif

so could someone change that in the bestiary and were ever else

(omg can you run him through the league again this is a major change in his attack)

[Jez]

LOL!

I have edited the bestiary post and will run it through the league again. The league post and zipped files will be updated later.

EDIT;

Update completed, Minimaxis gained one more position in the league before being over run by Devincio Eversor. It was rerun from the bottom of the league again. I imagine if you can figure out a way to beat Eversor then Minimaxis should climb a few more steps!