'31.10.03
'Topic: The next generation of ultimate killers
'PY
'H_Devincio_Venator
' *** Tie Hunter ***
'This thing is absolutely ravenous.
'It sometimes devours with a single bite
'Reaches 200 individuals in about 30 seconds with only 10 vegs.
'Should come with a health warning!!
'***********************
'reproduce
'***********
cond
*.nrg 8000 >
start
30 .repro store
0 50 store
stop
' move forward
'****************
cond
'*60 21<
start
*50 *.eye5 sub 10 div .up store
*50 *.eye5 sub -10 div .dn store
stop
cond
*50 100 <
start
50 inc
stop
'turn towards food
'*************************
cond
*.eye1 *.eye5 >
*.eye1 *.eye9 >
start
-110 .aimdx store
'10 .sx store
stop
cond
*.eye3 *.eye5 >
*.eye3 *.eye7 >
start
-70 .aimdx store
'10 .sx store
stop
cond
*.eye7 *.eye5 >
*.eye7 *.eye3 >
start
70 .aimdx store
'10 .dx store
stop
cond
*.eye9 *.eye5 >
*.eye9 *.eye1 >
start
110 .aimdx store
'10 .dx store
stop
'avoid other conspecifics
'****************************
cond
*.refeye 21 =
*.eye5 20 >
start
180 .aimsx store
stop
'Spin when attacked
'*************************
cond
*.shup 0 <
*.pleas -10 <
start
620 .aimsx store
stop
cond
*.hitup 0 !=
start
620 .aimsx store
stop
'random direction change
'****************************
cond
10 rnd 1 =
start
100 rnd 50 sub .aimsx store
stop
'Tie to an enemy
'********************
cond
*.eye5 30 >
*.refeye 21 !=
*50 10 >
start
1 .tie store
stop
cond
start
1 .tienum store
-6000 .tieval store
-1 .tieloc store
stop
'shoot at enemy
'******************
cond
*.eye5 35 >
*.refeye 21 !=
start
-1 .shoot store
stop
end
