Author Topic: Missing bots  (Read 5727 times)

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« on: December 01, 2006, 05:21:03 PM »
Out of the 29 bots I found missing from the Bestiary, I have found all but 13, if you can provide the code for any of the following bots it would be appreciated...

Asterus Igni (SB)(Esrever) - FOUND
Batavus Duo (MB)(Henk) - FOUND
Black Flower (SB)(Henk)
Daedelus (F2)(Light) - FOUND
Potissimus Terminator (F1)(Mutchy) - FOUND
Robotdog (SB)(Viplex)
Schoonmaker Alternate (SB)(Henk)
Shen's Evobot (F2)(Shen) - FOUND
Simplebot20 (F2)(Unknown)
Symboticus 2.5 (MB)(Elite) - FOUND
Symboticus (MB)(Elite)
Terminator MkVII (F1)(Mutchy) - FOUND
Vector 1.0 (SB)(Abylayly) -FOUND
« Last Edit: December 05, 2006, 05:31:54 AM by Jez »
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams

Offline Henk

  • Bot Destroyer
  • ***
  • Posts: 110
    • View Profile
Missing bots
« Reply #1 on: December 01, 2006, 05:43:08 PM »
Quote from: Jez
Out of the 29 bots I found missing from the Bestiary, I have found all but 13, if you can provide the code for any of the following bots it would be appreciated...

Asterus Igni (SB)(Esrever)
Batavus Minimalis (MB)(Henk)
Black Flower (SB)(Henk)

Daedelus (F2)(Light)
Potissimus Terminator (Unknown)
Robotdog (SB)(Viplex)
Shoonmaker Alternate (SB)(Henk)

Shen's Evobot (F2)(Shen)
Simplebot20 (F2)(Unknown)
Symboticus 2.5 (MB)(Elite)
Symboticus (MB)(Elite)
Terminator MkVII (Unknown)
Vector 1.0 (SB)(Abylayly)

I'll get you the bots on the list when I get my old computer up and running here at my new place, should be within a few days...
cond
*.DBbugs 0 =
start
.rejoice inc
stop

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« Reply #2 on: December 02, 2006, 02:10:13 AM »
That's great, thanks Henk!
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams

Offline kage

  • Bot Neophyte
  • *
  • Posts: 49
    • View Profile
Missing bots
« Reply #3 on: December 03, 2006, 05:30:46 PM »
I found 2 of them around the forum...



Heres Symbioticus 2.5

Code: [Select]
' Symbioticus
'
' A tank with a battery ...
'
' Ties to a veg, pulls
' it close behind it and
' uses it as an energy
' source
'
' Version 2.0
' - Code completely redone
' - Uses a modified version of Animal Minimalis' search pattern
' Version 2.1
' - Uses some better coding to save energy
' Version 2.2
' - Improves on turning and movement genes
' Version 2.3
' - Adds a roaming routine to cover more ground
' Version 2.4
' - Some minor changes, improved some routines, better .fdbody routine
' Version 2.5
' - Some minor changes, corrected an error in the coding which caused Symbioticus to become immobile when it lost it's veg, annotated some more of the code to make it more understandable

'*************************************************************

def roam 51 ' Used for movement
def done 52 ' Used for setting tie

' Delete birth tie and set .memloc

cond
start
.tie *.robage -1 mult 1 add mult inc
.tiepres .memloc *.robage -1 mult 1 add mult store
.deltie inc
stop

'*************************************************************

' Find and tie to a veggie

cond
*.robage 0 >
*.done 0 =
*.multi 0 =
*.eye5 0 >
*.eye5 45 <
*.refshoot 0 =
*.refaimdx 1 =
*.refeye 0 =
*.memval 86 !=
*.numties 0 =
start
40 .up store
stop

cond
*.robage 0 >
*.eye5 45 >
*.refshoot 0 =
*.refaimdx 1 =
*.refeye 0 =
*.memval 86 !=
*.numties 0 =
start
86 .tie store
stop

cond
*.robage 0 >
*.numties 0 =
*.eye5 0 =
*.memval 86 = or
*.refshoot 0 != or
*.refaimdx 1 != or
*.refeye 0 != or
start
314 rnd .aimdx store
stop

'*************************************************************

' Set tie and unfix veg

cond
*.numties 1 =
*.treffixed 1 =
start
86 .tienum store
.fixpos .tieloc store
0 .tieval store
stop

cond
*.numties 1 =
*.multi 0 =
*.done 0 =
start
.done inc
628 .fixang store
15 .fixlen store
86 .tienum store
.fixang .tieloc store
628 .tieval store
86 .readtie store
stop

'*************************************************************

' When tied to a vegetable

cond
*.myeye *.trefeye =
start
*.tiepres .deltie store
stop

cond
*.numties 0 =
start
0 *.shell sub .mkshell *.shell sgn mult store
.done *.done sgn mult dec
stop

'*************************************************************

' Sharing and producing

cond
*.multi 1 =
start
75 .sharenrg store
50 .shareslime store
50 .shareshell store
.sharewaste inc
*.pleas 3 div .strbody *.pleas sgn mult store
*.pleas 3 div .mkslime *.pleas sgn mult store
600 *.shell sub .mkshell store
stop

' Shooting and tracking genes for when I become an MB

' Shoot

cond
*.multi 1 =
*.eye5 0 >
*.refeye *.myeye !=
*.memval 86 !=
start
-32 .shootval store
-6 .shoot store
stop

cond
*.multi 1 =
*.eye5 45 >
*.refeye *.myeye !=
*.memval 86 !=
start
32 .shootval store
-6 .shoot store
stop

' Move

cond
*.multi 1 =
*.eye5 0 =
*.memval 86 = or
*.refeye *.myeye = or
*.roam 100 <
start
100 .aimdx store
.roam inc
stop

cond
*.roam 99 >
*.multi 1 =
*.eye5 0 =
*.memval 86 = or
*.refeye *.myeye = or
start
100 .up store
.roam inc
stop

cond
*.roam 200 >
start
0 .roam store
stop

' Aim and chase

cond
*.multi 1 =
*.eye5 0 >
*.refeye *.myeye !=
*.memval 86 !=
start
*.refxpos *.refypos angle .setaim store
*.refveldx .aimdx store
stop

cond
*.multi 1 =
*.eye5 0 >
*.eye5 30 <
*.refeye *.myeye !=
*.memval 86 !=
start
*.refvelup *.refvelup add 60 add .up store
stop

'*************************************************************

' Reproduction

cond
start
10 .repro *.body 5000 sub sgn mult *.multi sgn mult store
stop

cond
*.nrg 100 <
start
*.body 100 ceil .fdbody *.body sgn mult store
stop

'*************************************************************

' Shoot back at annoying enemies

cond
*.shflav 0 !=
*.shflav -2 !=
*.multi 1 =
*.shoot 0 =
*.refeye 0 = or
start
1256 *.shang sub .aimshoot store
64 .shootval store
-6 .shoot store
0 .shflav store
stop

' Antiviral (for replicating viruses)

cond
*.mkvirus 0 !=
start
*.mkvirus .delgene store
stop

' Junk DNA (for conspecific recognition)

cond
start
*.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5 *.eye5
stop

end

I think this is Shen's Evobot
Code: [Select]
def newmom 50

' - Birth -
cond
*.robage 0 =
start
.newmom inc
stop

cond
*.newmom 0 >
start
.newmom inc
stop

cond
*.newmom 200 =
start
0 .newmom store
stop

cond
*.nrg 10000 >
start
30 rnd 20 add .repro store
1 .newmom store
stop


' - Avoid Babies -
cond
*.eye5 0 >
*.newmom 0 >
start
400 .aimsx store
stop


' - Move -
cond
*.vel 10 <
*.eye5 50 <
start
5 .up store
40 80 rnd sub .aimsx store
stop

' - Eye -
cond
*.eye2 *.eye8 >
*.eye5 0 =
start
100 .aimsx store
10 .sx store
stop

' - Eye -
cond
*.eye8 *.eye2 >
*.eye5 0 =
start
-100 .aimsx store
-10 .sx store
stop

' - Eat -
cond
*.newmom 0 =
*.eye5 40 >=
start
-1 .shoot store
stop


end
« Last Edit: December 03, 2006, 05:39:24 PM by kage »

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« Reply #4 on: December 03, 2006, 06:18:14 PM »
Sweet! Well spotted.

I'll add them to the bestiary tomorrow. I assumed if they had been posted on the forum they would have been put in the bestiary, might try using the search function to check for the others now...
« Last Edit: December 03, 2006, 06:20:26 PM by Jez »
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« Reply #5 on: December 04, 2006, 08:17:18 AM »
I still can't find shen's evobot on the forum  , I was looking for the date it was posted if you have that info as well.
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams

Offline kage

  • Bot Neophyte
  • *
  • Posts: 49
    • View Profile
Missing bots
« Reply #6 on: December 04, 2006, 04:34:09 PM »
I found it under "My evo bot" (it was made by Shen and is on the second page of the short bots sub forum of the bestiary)

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« Reply #7 on: December 04, 2006, 05:02:28 PM »
ROFL

I don't know how I missed that, I even searched the forums with just the word evobot! Must be 'cause it was titled 'My evo[space]bot'  

I'll update that soon then, thanks.
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams

Offline kage

  • Bot Neophyte
  • *
  • Posts: 49
    • View Profile
Missing bots
« Reply #8 on: December 04, 2006, 06:35:05 PM »
3 more bots to add to your list

Asterus Igni
               found in the Hello and a Shortbot [or it was called something like that (in the newbies forum, near the end of the first page of the topic it has the bot)]

Code: [Select]
'Asterus Igni
'By Esrever
'~~~~~~~~~~~~
'Bot Designed for SB League
'Two minor bugs fixed by Henk

' Gene 1 Catch and
' Fight Prep
cond
*.eye5 0 >
*.refeye *.myeye !=
*.numties 0 =
start
*.refveldx .dx store
*.refvelup 20 add .up store
200 *.poison sub .strpoison store
75 *.slime sub .mkslime store
10 *.body sub 10 mult .strbody store
stop

' Gene 2 Tie Up
cond
' *,numties 0 = and (this as the original condition with a bug)
*.numties 0 = and ' fixed
*.eye5 40 > and
*.refeye *.myeye != and
*.eye5 77 != and
*.robage 0 = or
start
1 .tie store
1 .readtie store
stop

' Gene 3 Eat Enemies
cond
*.trefeye *.myeye !=
start
1 .tienum store
-1000 .tieval store
-1 .tieloc store
stop

' Gene 4 Anti-Cannibalism
' and Birth Setup
cond
*.trefeye *.myeye =
*.robage 1 = or
start
1 .deltie store
200 *.poison sub .strpoison store
75 *.slime sub .mkslime store
10 *.body sub 10 mult .strbody store
stop

' Gene 5 Avoid/Search
cond
*.eye5 0 =
*.refeye *.myeye = or
start
471 rnd .aimdx store
stop

' Gene 6 Reproduce
cond
*.nrg 4000 >
start
60 .repro store
stop

' added an end command
end


Batavus Minimalis (Shortbot forum)


Code: [Select]
' Batavus duo
' a SBMB (ShortBot Multibot)

def id 803

' GENE ONE: make a tie at birth
' *************************
cond
*.robage 0 =
*.eye5 70 >
start
1 .tie store
314 .id store
.shoot .ploc store
stop

' GENE TWO: reproduce if not an mb
' *****************************
cond
*.numties 0 =
*.robage 0 >
start
50 .repro store
0 .aimdx store
314 .id store
stop

' GENE THREE: share through tie, fix tie angle
' ************************************
cond
*.numties 0 >
*.robage *40 >
*.robage 10 >
start
628 .fixang store
400 .fixlen store
*.robage 25 add 40 store
50 .sharenrg store
1 .readtie store
0 .fixpos store
20 *.poison sub *.nrg 2 div ceil .strpoison store
stop

'GENE FOUR: Turn and move (head only)
' ********************************
cond
*.numties 0 >
*.trefage *.robage >
*.eye5 35 <=
start
*.eye9 *.eye1 sub 4 mult 50 store
*.eye6 *.eye4 sub 51 store
*50 *51 add 130 ceil .aimdx store
*.maxvel *.vel sub .up store
0 .fixpos store
stop

' GENE FIVE: Reproduce (tail only)
' ***************************
cond
*.trefage *.robage <
*.nrg 7000 >
start
1 .deltie store
314 .aimdx store
stop

' GENE 6: Kill (head only)
' *******************
cond
*.numties 0 >
*.trefage *.robage >
*.eye5 35 >
start
803 .memloc store
*.memval .aimdx store
-1 .shoot store
.fixpos inc
stop

end


Vector 1.0 (also found in short bots)

Code: [Select]
'Vector 1.0 by abyaly
'Public SG version
'Communicates the location of food to conspecs
'I will release a legible and commented version once it is finished
'Which will be some time after finals are over ^^

cond
start
*.refveldx 4 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.maxvel *.vel sub 1 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.maxvel *.vel sub 1 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refveldx 4 *.eye5 0 sub sqr dup div *.eye5 41 sub -1 mult sqr dup div mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refvelup 1 *.eye5 sub sqr dup div 40 mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refveldx 4 *.eye5 sub sqr dup div 40 mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
*.refaim 19 *.eye5 sub sqr dup div 40 mult *.refeye *.myeye sub dup div 1 sub abs mult *.memval 0 sub sqr dup div *.in1 0 sub sqr dup div add sgn *.in2 0 sub sqr dup div add sgn mult mult store
314 5 *.eye5 0 sub sqr dup div *.refeye *.myeye sub dup div 1 sub abs mult *.in1 0 sub dup div 1 sub abs *.in2 0 sub dup div 1 sub abs mult *.memval 0 sub dup div 1 sub abs mult 9 rnd 0 sub dup div 1 sub abs add sgn mult mult store
*.maxvel *.vel add *.eye5 mult 50 div 15 ceil 4 *.eye5 0 sub sqr dup div *.refeye *.myeye sub dup div 1 sub abs mult *.in1 0 sub dup div 1 sub abs *.in2 0 sub dup div 1 sub abs mult *.memval 0 sub dup div 1 sub abs mult 9 rnd 0 sub dup div 1 sub abs add sgn mult mult store
330 *.robage 0 sub dup div 1 sub abs mult inc
467 *.robage 1 sub dup div 1 sub abs mult inc
51 *.memloc sgn -1 mult 1 add 474 mult store
0 51 *51 sgn mult *.eye5 sgn 1 sub abs *.refeye *.myeye sub dup div 1 sub abs add sgn mult store
1 51 *.eye5 sgn mult *.refeye *.myeye sub dup div mult *.refeye sgn mult store
800 *.out1 dup div mult dec
800 *.eye5 sgn mult *.memval sgn *.refeye *.myeye sub dup div add sgn mult inc
801 *.out2 dup div mult dec
801 *.eye5 sgn mult *.in1 *.memval add dup div *.refeye *.myeye sub dup div add sgn mult inc
*.eye1 -4 mult *.eye2 -3 mult *.eye3 -2 mult *.eye4 -1 mult *.eye6 1 mult *.eye7 2 mult *.eye8 3 mult *.eye9 4 mult add add add add add add add add *.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9 add add add add add add add add div 34 mult *.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9 add add add add add add add add dup div *.eye5 sgn 1 sub dup div mult *.shdn *.shdx *.shsx add add dup div 1 sub dup mult mult 5 mult store
330 *.eye1 *.eye2 *.eye3 *.eye4 *.eye5 *.eye6 *.eye7 *.eye8 *.eye9 add add add add add add add add dup div 1 sub dup mult *.shdn *.shdx *.shsx add add dup div 1 sub dup mult mult 5 mult store
*.refxpos *.refypos angle 19 *.robage sgn mult *.refeye *.myeye sub dup div mult *.refxpos *.refypos angle *.aim sub dup div mult *.shdn *.shdx *.shsx add add dup div 1 sub dup mult mult *.eye5 sgn mult store
*.shang 314 add 5 *.shdn *.shdx *.shsx add add dup div mult *.refeye *.myeye sub dup div 1 sub dup div *.refeye sgn 1 sub sgn abs add mult store
100 313 *.nrg 500 sub sqr sgn mult 500 *.body sub sqr sgn mult store
*.body 0 floor 312 *.body sgn mult 100 *.nrg sub sqr sgn mult store
*.body 50 sub 0 floor 100 ceil 312 *.body 50 sub sqr sgn mult 800 *.nrg sub sqr dup div mult store
60 300 30 *.eye4 *.eye5 *.eye6 add add 3 div sub sqr sgn mult *.nrg 600 sub sgn mult store
100 *.shell sub 0 floor 100 ceil 100 *.shell sub sgn abs 822 mult store
*.waste 8 *.waste 10 sub sgn mult store
-4 7 *.waste 10 sub sgn mult store
-6 7 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
4 8 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
*.refvelup 1 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
*.refveldx 4 *.eye5 40 sub sqr dup div *.refeye 0 sub dup div 1 sub abs mult mult store
-6 7 *.refshell 20 sub sqr sgn mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
4 8 20 *.refshell 20 sub sqr sgn mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
-1 7 *0 20 sub sqr sgn 1 sub abs mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
32 8 *0 20 sub sqr sgn 1 sub abs mult *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.refvelup 1 *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
*.refveldx 4 *.eye5 40 sub sqr dup div *.refeye 0 sub sqr dup div mult *.refeye *.myeye sub dup div mult mult store
340 inc
340 inc
end
« Last Edit: December 04, 2006, 07:28:46 PM by kage »

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« Reply #9 on: December 05, 2006, 05:30:17 AM »
Wow thanks,

Two of those just had the wrong title in the bestiary.  

Well done for spotting them, and that other one in the newbie forum.
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams

Offline kage

  • Bot Neophyte
  • *
  • Posts: 49
    • View Profile
Missing bots
« Reply #10 on: December 05, 2006, 06:07:37 PM »
Thanks, I have no idea if the other ones are on the site though  , sorry.

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« Reply #11 on: December 05, 2006, 06:17:40 PM »
Quote from: kage
Thanks, I have no idea if the other ones are on the site though  , sorry.
Not your problem, as you've said before, you've done nothing wrong so no need to be sorry!  

Henk hopefully will be able to add the rest of the bots when he gets a monitor for his old pc, if not, I did a site search before for my 'pre 28.07.04' bots file , I'm sure it won't be so bad to do a newer site search...  
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams

Offline Light

  • Bot Destroyer
  • ***
  • Posts: 245
    • View Profile
Missing bots
« Reply #12 on: December 05, 2006, 06:28:07 PM »
Any you dont get I can nearer end of december/beginning january

Offline Jez

  • Bot Overlord
  • ****
  • Posts: 788
    • View Profile
Missing bots
« Reply #13 on: December 05, 2006, 06:48:07 PM »
Thanks,

I'm hoping to get a comprehensive list of all bots, which I did have before I took a break, so when you are in a position to do so any bots you find are missing (post me finishing the bestiary) would be gratefully received.

Also any bots anyone can show are predated the date I have given them. Particuarly all those labeled feb/05 when this forum opened and PY added old bots to the bestiary, would be nice. I will go back and check my records when I have finished phase 1 of the update but any help or error spotting is always good
If you try and take a cat apart to see how it works, the first thing you have in your hands is a non-working cat.
Douglas Adams