Bots reach a max of about 2070, at about 2050 they start ignoring the veg.
(Bots reached 2099 this time because they carried on feeding off one veg and only stopped when the other veg reproduced)
Bot posted here so you can replicate, should take less than 2000 cycles, default conditions apply.
DB V.2.37.6
Would be interested to know if this has anything to do with Bubbles ignoring enemy at a certain population level!
'MAX POPULATION BOT
'death by baby
cond
*.paralyzed 0 !=
*.poisoned 0 !=
start
100 .repro store
*.aim 280 add .setaim store
stop
'set memval
cond
*.memloc .dnalen !=
start
.dnalen .memloc store
stop
'make tie to overwrite birth tie
cond
*.numties 0 !=
*.tiepres 0 =
start
.tie inc
stop
'deltie
cond
*.tiepres 0 !=
start
*.tiepres .deltie store
stop
'repro
cond
*.nrg 1000 >
*.body 500 >
start
25 .repro store
628 *.aim add .setaim
stop
'move toward food
cond
*.numties 0 =
*.eye5 0 >
*.memval *.dnalen !=
start
*.refxpos *.refypos dist 500 div *.maxvel mult *.refvel add *.maxvel ceil .up store
*.refxpos *.refypos angle .setaim store
*.veldx .sx store
stop
'shoot food
cond
*.eye5 30 >
*.memval *.dnalen !=
start
'*.refxpos *.refypos angle *.aim sub .aimshoot store
*.nrg 32 div .shootval store
-6 .shoot store
stop
'avoid friends
cond
*.eye5 0 >
*.memval *.dnalen =
start
*.refxpos *.refypos angle 280 add .setaim store
stop
'search for food
cond
*.eye5 0 =
start
*.aim 280 add .setaim store
stop
'make body
cond
*.nrg 1000 >
start
100 .strbody store
stop
'use body
cond
*.nrg 500 <
start
100 .fdbody store
stop
end
