Bots and Simulations > Bot Tavern

SWARM

<< < (3/4) > >>

Numsgil:
Can you try and figure out exactly where their nrg is going that they die?  Does it look like they're doing the same behavior or do they behave screwy too?

Welwordion:
With 0 costs, mutation diasabled(used social swarm): Bots keep shrinking in size , some bots behave screwy but most are okay,
main cause of dead: bots firing at each other(mostly accidents,but they happen often) and bots trying to reproduce.
In the end only screwy shrinked bots remain(probably because they do not collect enough energy to reproduce)

Endy:
The bots are only body feeding, it's also converting all it's body into nrg whenever nrg gets too low. You also need to convert it back into nrg before reproducing.


--- Code: ---cond
*.nrg 5000 >
*.body 10 >
start
50 .repro store
*.nrg 5000 sub .strbody store
stop

cond
*.body 10 >
start
*.body 10 sub .fdbody store
stop

cond
*.nrg 100 <
*.body 100 *.nrg sub 10 div >
start
*.body 100 *.nrg sub 10 div sub .fdbody *.body sgn mult store
stop
--- End code ---

As a good rule of thumb it's best to check body levels before reproducing. It's also good to beef up whenever fighting/feeding, for a free shot strength boost. For overall general surviving, it's a balancing act between the two.

Endy:
Seems to have helped. I'm running an evosim to see how they hold up.

It's holding alright. Seems like it's helping them find food by playing a follow the leader game. It also appears to help the Canni's(perhaps more than normal bots) by helping them hunt the large groups of norms.

Neat little bot. I'll keeep going some more and see what happens.


--- Code: ---' SocialSwarmX
'
' An advancement on the SWARM concept

cond
start
.tie *.robage 1 add mult inc
.deltie inc
stop

cond
*.eye5 0 >
*.refeye *.myeye =
*.in1 0 !=
*.in2 0 !=
start
*.in1 .out1 store
*.in2 .out2 store
stop

cond
*.body 500 <
*.out1 0 !=
*.out2 0 !=
start
*.out1 *.out2 angle .setaim store
stop

cond
*.eye5 50 <
start
10 .up store
stop

cond
*.eye1 *.eye5 >
*.eye9 *.eye5 > or
start
*.eye9 *.eye1 sub 2 mult .aimdx store
stop

cond
*.eye5 35 >
*.refeye *.myeye !=
start
-6 .shoot store
8 .shootval store
stop

cond
*.eye5 0 >
*.refeye *.myeye !=
start
*.refxpos .out1 store
*.refypos .out2 store
*.refveldx .dx *.eye5 sgn mult store
stop

cond
*.eye5 50 >
*.refeye *.myeye =
start
*.refaim .setaim store
stop

cond
*.nrg 5000 >
*.body 10 >
start
50 .repro store
*.nrg 5000 sub .strbody store
stop

cond
*.body 10 >
start
*.body 10 sub .fdbody store
stop

cond
*.nrg 100 <
*.body 100 *.nrg sub 10 div >
start
*.body 100 *.nrg sub 10 div sub .fdbody *.body sgn mult store
stop

end
--- End code ---

Endy:
Good job on the bot design. Impressive features for a relativly small bot.

The improvised MB's it and FishSchool can form are very good at manuevering. Do you think one of you could try and deliberatly make a MB with the same coding?

Canni's seem to be taking the lead. Swarming traits have been adapted to hunting.

Population dipped then rose again.  Definitly a good Evosim.   I'll keep it going and see what happens.

 

Navigation

[0] Message Index

[#] Next page

[*] Previous page